MSFN Forums > Daemon Tools 4.30.1 and ArniWorx shell extension

Full Version: Daemon Tools 4.30.1 and ArniWorx shell extension

MSFN Forums > Unattended Windows Discussion & Support > Application Installs

Acheron

Jul 17 2008, 12:02 PM

Here an working version of the AutoIt scripts I use to install Daemon Tools silently. The script also kills the Daemon Tools Toolbar install process.

I use a custom installer for ArniWorx, which you can download here: awxDTools1060.exe. Note I have updated the installer to work in combination with Daemon Tools. It is not possible to use the Daemon Tools script without the AwxdTools shell extension.

All install files are copied to the hard disc during setup, as Daemon Tools is installed after logon. At this stage users might have removed the CD from the cd drive.

cmdlines.txt

CODE

rundll32.exe advpack.dll,LaunchINFSection .\Install\Daemon Tools\install.inf,,1

install.inf

CODE

[Version]
Signature = "$Windows NT$"

[DefaultInstall]
RunPreSetupCommands  = SPTD.Install:1,ArniWorX.Install:1
CopyFiles            = DaemonTools.CopySetup
AddReg               = Register.AddReg

[SPTD.Install]
;SPTD-driver 1.56
"""%01%\SPTDinst-x86.exe"" add /q"

[ArniWorX.Install]
;ArniWorx 1.0.6.0 shell extension
"""%01%\awxDTools1060.exe"" /VERYSILENT /NORESTART /SUPPRESSMSGBOXES"

[DestinationDirs]
;All users application data directory
DaemonTools.CopySetup = 16419,"DAEMON Tools"

[DaemonTools.CopySetup]
"daemon4301-lite.exe"
"install_dtools.au3"
"user_dtools.au3"

[Register.AddReg]
;Install Daemon Tools after reboot
HKLM,"SOFTWARE\Microsoft\Windows\CurrentVersion\RunOnce","Daemon Tools",0x0,"autoit3.exe ""%16419%\DAEMON Tools\install_dtools.au3"""
;Start Daemon Tools for all users
HKCU,"SOFTWARE\Microsoft\Windows\CurrentVersion\Run","DAEMON Tools Lite",0x0,"""%16422%\DAEMON Tools Lite\daemon.exe"" -autorun"

install_dtools.au3

CODE

#RequireAdmin
#NoTrayIcon

$DTTITLE = "Daemon Tools Lite 4.30.1"
$INSTALLDIR = @ProgramFilesDir & "\Daemon Tools Lite"
$EXENAME = "daemon4301-lite.exe"

;Save Internet Explorer homepage (prevent Internet Explorer to launch)
$HomePage = RegRead("HKCU\Software\Microsoft\Internet Explorer\Main", "Start Page")

;Clear default internet browser temporary
$DefBrowser = RegRead("HKCR\HTTP\shell\open\command\", "")
RegDelete("HKCR\HTTP\shell\open\command\", "")

;Save mds fileassociation
$mds_assoc = RegRead("HKCR\.mds", "")

;Launch Daemon Tools setup
$Pid = Run(@ScriptDir & "\" & $EXENAME & " /S")

;Kill Daemon Tools toolbar installation process
If ProcessWait("Daemon Tools Toolbar.exe", 300) Then
    ProcessClose("Daemon Tools Toolbar.exe")
    ProcessWaitClose("Daemon Tools Toolbar.exe")
    FileDelete($INSTALLDIR & "\DAEMON Tools Toolbar.exe")
EndIf

ProcessWaitClose($Pid)

;Restore the default internet browser
RegWrite("HKCR\HTTP\shell\open\command\", "", "REG_SZ", $DefBrowser)

;Restore the home page of Internet Explorer
RegWrite("HKCU\SOFTWARE\Microsoft\Internet Explorer\Main", "", "REG_SZ", $HomePage)

;Don't associate with any files
RegDelete("HKLM\SOFTWARE\DT Soft\DAEMON Tools Lite\FileTypesSave")

;Restore mds association
RegWrite("HKCR\.mds", "", "REG_SZ", $mds_assoc)
RegDelete("HKCR\.mds", "fastmountoldfile")

;Cleanup shortcuts
DirRemove(@ProgramsCommonDir & "\DAEMON Tools Lite", 1)
FileDelete(@DesktopCommonDir & "\DAEMON Tools Lite.lnk")

FileCreateShortcut ($INSTALLDIR & "\daemon.exe", @ProgramsCommonDir & "\Daemon Tools Lite.lnk")

;Write uninstall information to registry
RegWrite("HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\DAEMON Tools Lite", "DisplayName", "REG_SZ", $DTTITLE)
RegWrite("HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\DAEMON Tools Lite", "DisplayIcon", "REG_SZ",$INSTALLDIR & "\daemon.exe")
RegWrite("HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\DAEMON Tools Lite", "InstallLocation", "REG_SZ", $INSTALLDIR)
RegWrite("HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\DAEMON Tools Lite", "UninstallString", "REG_SZ", $INSTALLDIR & "\uninst.exe")
RegWrite("HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\DAEMON Tools Lite", "NoModify", "REG_DWORD", 1)

;Register ArniWorX shell extension after logon
RegWrite("HKCU\SOFTWARE\Microsoft\Windows\CurrentVersion\RunOnce", "Configure Daemon Tools", "REG_SZ", "autoit3.exe """ & @AppDataCommonDir & "\DAEMON Tools\user_dtools.au3""")

;Remove Daemon Tools autorun
RegDelete("HKCU\SOFTWARE\Microsoft\Windows\CurrentVersion\Run","DAEMON Tools Lite")

user_dtools.au3

CODE

#NoTrayIcon

$INSTALLDIR = @ProgramFilesDir & "\Daemon Tools Lite"

;Cleanup temp files
$search = FileFindFirstFile(@TempDir & "\*.tmp")
While 1
    $file = FileFindNextFile($search)
    If @error then ExitLoop
    DirRemove(@Tempdir & "\" & $file, 1)
    RegDelete("HKLM\SYSTEM\CurrentControlSet\Control\Session Manager", "PendingFileRenameOperations")
WEnd
FileClose($search)

;Start Daemon Tools
Run($INSTALLDIR & "\daemon.exe -autorun")

;Wait for Daemon Tools to get initialized
If WinWait("[TITLE:DAEMON Tools Lite; CLASS:#32770]", "", 300) Then
    $dt_handle = WinGetHandle("[LAST]")
    WinWaitClose($dt_handle, "", 300)
EndIf

;Register ArniWorX shell extension
If FileExists($INSTALLDIR & "\AwxdTools.dll") Then Run("regsvr32.exe /s """ & $INSTALLDIR & "\AwxdTools.dll""")

;Remove install files
DirRemove(@AppdataCommonDir & "\DAEMON Tools", 1)

Mann

Jul 18 2008, 07:49 AM

link to download is not working for awxdTools1060.exe

Acheron

Jul 18 2008, 08:33 AM

Fixed link to ArniWorx installer, also updated scripts for Daemon Tools Lite 4.30.0. Finally Daemon Tools decided to remove the adware from it.

Mann

Jul 19 2008, 11:01 AM

thanks for the fix

Acheron

Jul 29 2008, 05:28 PM

Updated script for Daemon Tools 4.30.1

digitalfrost

Aug 5 2008, 06:19 AM

Thanks alot for this. The script is really elegant, installing DAEMON Tools was never that easy

This is a "lo-fi" version of our main content. To view the full version with more information, formatting and images, please click here.