MSFN Forums > Daemon Tools 4.08 (AutoIt Launcher)

Help - Search - Members - Calendar

Full Version: Daemon Tools 4.08 (AutoIt Launcher)

MSFN Forums > Unattended Windows Discussion & Support > Application Installs

Pages: 1, 2

radix

Feb 22 2008, 09:05 AM

QUOTE (squizo @ Feb 22 2008, 04:39 PM)

The question is: if i erase this part

CODE

SetOutPath $INSTDIR
File SRSAI.exe
Execute 49043 0 0
StrCpy $[43] "1"
Return
SetFlag 13 47631
StrCpy $[41] "1"
Return
SetFlag 13 162
UpdateSatusText Installing Desktop Shortcut... 0
SetFlag 13 47631

and repack all without SRSAI.exe daemon tools work corrctly?

Another question is : what program must use to repack it? HM NIS Edit for example'

The last question

Radix - How execute your last script in an active windows ?

QUOTE

Opt("TrayIconDebug", 1)

; Disable the default internet browser (in order to prevent SRSAI.exe to open it)
$DefBrowser = RegRead("HKCR\HTTP\shell\open\command\", "")
RegDelete("HKCR\HTTP\shell\open\command\", "")... ...

Is php code? must i create an archive with .php extension and execute it?

when execute it? before install daemons tools?

Can i create a registry entry for to avoid the install or execution of SRSAI?

Is most easy install daemons complete and after remove the spyware?

I hope you understand me. Sorry for my english again.

Thanks.

Hi
The file [NSIS].nsi extracted with Universal Extractor is corrupt. If you are a master in coding Null Soft ya you can repack Daemon Tools.
My code is AutoIt.

squizo

Feb 22 2008, 09:45 AM

Thanks for the answer.

I am not a master in nothing. I am a stupid. Now i know.

Always scan the files for virus before install with nod 32. This time was a false alarm.

I make a restore point and try install daemontools to see what happen.

This time the solution is easy: when install daemon tools unmark two options and goodbye spyware.

Sorry for your spend time.

And 1000 thanks for help me.

radix

Mar 17 2008, 09:30 AM

New script for new DAEMON Tools Lite 4.12.2 with SPTD 1.56 (works in 32 and 64 bit environment)

CODE

Opt("TrayIconDebug", 1)
Opt("SendKeyDelay", 200)
; Executable file name
$EXECUTABLE = "daemon4122-lite.exe"
; Run Daemon Tools on Windows startup
$autostart = 0
; Detect the Operating System type (32 bit or 64 bit)
$OS = _OSBit()

If $OS = 32 Then
; Installation folder
    $INSTALLLOCATION = @ProgramFilesDir & "\DAEMON Tools Lite"

If FileExists($INSTALLLOCATION & "\daemon.exe") Then
     MsgBox(0x40010, @ScriptName, "Please uninstall previous version of DAEMON Tools before using this script", 4)
     Exit
    EndIf

   ; Disable the default internet browser (to prevent daemon.exe to open it)
    $DefBrowser = RegRead("HKCR\HTTP\shell\open\command\", "")
    RegDelete("HKCR\HTTP\shell\open\command\", "")

   ; Read from registry which is the home page of Internet Explorer (to restore it after the installation of DAEMON Tools Lite)
    $HomePage = RegRead("HKCU\Software\Microsoft\Internet Explorer\Main", "Start Page")

   ; Run the installer
    Run($EXECUTABLE & " /S")

; Start checking for a window with "Please select a language." text inside
    AdlibEnable('_Adlib')

ProcessWaitClose($EXECUTABLE)

    Sleep(2000)

   ; Restore the default internet browser
    RegWrite("HKCR\HTTP\shell\open\command\", "", "REG_SZ", $DefBrowser)

   ; Restore the home page of Internet Explorer
    RegWrite("HKCU\Software\Microsoft\Internet Explorer\Main", "", "REG_SZ", $HomePage)

; Block daemon.exe to run on Windows startup
If $autostart = 0 Then
  RegDelete("HKCU\SOFTWARE\Microsoft\Windows\CurrentVersion\Run", "DAEMON Tools Lite")
EndIf

   ; Add uninstall entries
    RegWrite("HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\DAEMON Tools Lite", "DisplayName", "REG_SZ", "DAEMON Tools Lite 4.12.2")
    RegWrite("HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\DAEMON Tools Lite", "UninstallString", "REG_SZ", $INSTALLLOCATION & "\uninst.exe")
    RegWrite("HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\DAEMON Tools Lite", "InstallLocation", "REG_SZ", $INSTALLLOCATION)
    RegWrite("HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\DAEMON Tools Lite", "DisplayIcon", "REG_SZ", $INSTALLLOCATION & "\daemon.exe")

; Stop checking for a window with "Please select a language." text inside
    AdlibDisable()
EndIf

If $OS = 64 Then
; Installation folder
    $INSTALLLOCATION = @HomeDrive & "\Program Files (x86)\DAEMON Tools Lite"

If FileExists($INSTALLLOCATION & "\daemon.exe") Then
     MsgBox(0x40010, @ScriptName, "Please uninstall previous version of DAEMON Tools before using this script", 4)
     Exit
    EndIf

   ; Disable the default internet browser (to prevent daemon.exe to open it)
    $DefBrowser = RegRead("HKCR\HTTP\shell\open\command\", "")
    RegDelete("HKCR\HTTP\shell\open\command\", "")

   ; Read from registry which is the home page of Internet Explorer (to restore it after the installation of DAEMON Tools Lite)
    $HomePage = RegRead("HKCU\Software\Microsoft\Internet Explorer\Main", "Start Page")

   ; Run the installer
    Run($EXECUTABLE & " /S")

; Start checking for a window with "Please select a language." text inside
    AdlibEnable('_Adlib')

ProcessWaitClose($EXECUTABLE)

    Sleep(2000)

   ; Restore the default internet browser
    RegWrite("HKCR\HTTP\shell\open\command\", "", "REG_SZ", $DefBrowser)

   ; Restore the home page of Internet Explorer
    RegWrite("HKCU\Software\Microsoft\Internet Explorer\Main", "", "REG_SZ", $HomePage)

; Block daemon.exe to run on Windows startup
If $autostart = 0 Then
  RegDelete("HKCU\SOFTWARE\Microsoft\Windows\CurrentVersion\Run", "DAEMON Tools Lite")
EndIf

   ; Add uninstall entries
    RegWrite("HKLM\SOFTWARE\Wow6432Node\Microsoft\Windows\CurrentVersion\Uninstall\DAEMON Tools Lite", "DisplayName", "REG_SZ", "DAEMON Tools Lite 4.12.2")
    RegWrite("HKLM\SOFTWARE\Wow6432Node\Microsoft\Windows\CurrentVersion\Uninstall\DAEMON Tools Lite", "UninstallString", "REG_SZ", $INSTALLLOCATION & "\uninst.exe")
    RegWrite("HKLM\SOFTWARE\Wow6432Node\Microsoft\Windows\CurrentVersion\Uninstall\DAEMON Tools Lite", "InstallLocation", "REG_SZ", $INSTALLLOCATION)
    RegWrite("HKLM\SOFTWARE\Wow6432Node\Microsoft\Windows\CurrentVersion\Uninstall\DAEMON Tools Lite", "DisplayIcon", "REG_SZ", $INSTALLLOCATION & "\daemon.exe")

; Stop checking for a window with "Please select a language." text inside
    AdlibDisable()
EndIf

Func _Adlib()
   ; Please select a language.
If WinExists("DAEMON Tools Lite 4.12.2", "Please select a language.") Then
        ControlClick("DAEMON Tools Lite 4.12.2", "Please select a language.", "Button1")
EndIf
EndFunc

Func _OSBit()
Local $tOS = DllStructCreate("char[256]")
Local $aGSWD = DllCall("Kernel32.dll", "int", "GetSystemWow64Directory", "ptr", DllStructGetPtr($tOS), "int", 256)
If IsArray($aGSWD) And DllStructGetData($tOS, 1) Then Return 64
Return 32
EndFunc

Note: Close Internet connection before running the setup (to avoid firewall prompt for downloading
of SRSAI.exe bonus).

Edit

radix

Apr 3 2008, 07:01 AM

DAEMON Tools Lite 4.12.3 with SPTD 1.56 (works in 32 and 64 bit environment)

Note: Close Internet connection before running the setup (to avoid firewall prompt and add-on download).

Acheron

Apr 3 2008, 01:18 PM

Radix, what's all that 64-bit translation stuff doing in your script? As long as you compile AutoIt as a 32-bit exe you don't have to do any path translations, as long as you don't hardcode paths.

radix

Apr 3 2008, 02:42 PM

QUOTE (Acheron @ Apr 3 2008, 09:18 PM)

Radix, what's all that 64-bit translation stuff doing in your script? As long as you compile AutoIt as a 32-bit exe you don't have to do any path translations, as long as you don't hardcode paths.

CODE

If FileExists($INSTALLLOCATION & "\daemon.exe") Then
        MsgBox(0x40010, @ScriptName, "Please uninstall previous version of DAEMON Tools before using this script", 4)
        Exit
    EndIf

For the above code the script will check only in Program Files folder. But in 64 bit Windows, Daemon Tools is installed in Program Files (x86) and if you have allready installed Daemon Tools, FileExists will see nothing.
The uninstall entries for 64 bit Windows will go to

CODE

HKLM\SOFTWARE\Wow6432Node\Microsoft\Windows\CurrentVersion\Uninstall\DAEMON Tools Lite

.
These are the reasons for 64-bit translation stuff.

Acheron

Apr 4 2008, 03:32 AM

So @ProgramFilesDir is automaticly converted to Program Files (x86) and HKLM\Software\Windows\CurrentVersion\Uninstall should also automaticly get converted to the Wow6432node path.
If this is not correct you should report this as a bug to the AutoIt team.

radix

Apr 4 2008, 05:30 AM

QUOTE (Acheron @ Apr 4 2008, 11:32 AM)

Generally, the path isn't automaticaly converted. I have a script for an application which type the path with ControlSetText command. Application is 32 bit native, but the script doesn't detect
this and type C:\Program Files\blabla\ instead of C:\Program Files (x86)\blabla\ and install into Program Files. On other applications it works right. So is a bug, but is normally because is the first version with
64 bit suport.

Acheron

May 2 2008, 04:24 PM

The Daemon Tools installer is not very friendly to install unattendly. Since all kernel stuff is put into the SPTD driver anyway I'm going to create my own installer for it. I'll also try to improve the AutoIt script to set Daemon Tools options.

When I'm done I'll post a link here.

microbion

May 3 2008, 08:17 AM

to make it more flexible for further DT versions change the window title to a variable and replace the titles below (in line 66, 113, 124 and 125) with that variable.

CODE

; Script Start - Add your code below here

Opt("TrayIconDebug", 1)
Opt("SendKeyDelay", 200)
; Executable file name
$EXECUTABLE = "daemon4123-lite.exe"
$WINDOWTITLEVERSION = "DAEMON Tools Lite 4.12.3"

; Run Daemon Tools on Windows startup
$autostart = 0
; Detect the Operating System type (32 bit or 64 bit)
$OS = _OSBit()

PS: salutari din germania

Acheron

May 5 2008, 10:39 AM

Its a bit weird, but with latest Daemon Tools I no longer have to turn off Daemon Tools security mode. This simplifies the installation process a bit.
Other options like automounting, disabling toolbar can be set in a ini-file. Only thing that can't be set is the Online update check, but I'm happy that Daemon Tools at least get some options to be set manually.

Here's an updated ArniWorx installer:

ArniWorX 1.0.60 Shell Extension installer

This one is multilangual, sets automaticly Daemon Tools language, Automount options and disables the Daemon Tools panel.

radix

May 5 2008, 02:42 PM

QUOTE (Acheron @ May 5 2008, 07:39 PM)

Its a bit weird, but with latest Daemon Tools I no longer have to turn off Daemon Tools security mode. This simplifies the installation process a bit.

So we don't need that right click on D.T. tray icon. arniworx installer need some modifications to
install the files in DAEMON Tools Lite folder (not DAEMON Tools). Very simple task.

cool400

May 12 2008, 01:35 PM

@radix,Acheron

Is there a new DT-version available? How can the settings be made via an INI-file? And how can I install DT with this INI-file unattended?

The Arniworks-installer isn't unattended, right? Or am I doing something wrong?

Best regards

cool400

radix

May 12 2008, 02:00 PM

QUOTE (cool400 @ May 12 2008, 10:35 PM)

The Arniworks-installer isn't unattended, right? Or am I doing something wrong?

Maybe need some switches. Like /verysilent.

bbrian

May 14 2008, 05:35 AM

QUOTE (radix @ Apr 3 2008, 01:01 PM)

DAEMON Tools Lite 4.12.3 with SPTD 1.56 (works in 32 and 64 bit environment)

Note: Close Internet connection before running the setup (to avoid firewall prompt and add-on download).

I used WIWW2 to create an msi to install SPTD 1.56 and force a reboot after install. Silent switch was "add /q". I called the msi sptd156.

Then I wrapped your AutoIt script into an MSI and put a WMI filter on the GPO so it would only install after STPD was in add/remove:

CODE

SELECT * FROM Win32_Product WHERE Caption ='sptd156'

I also added some code into your script to move about the shortcuts, though I haven't tested it yet. This bit at the top so it's easy to find:

CODE

; Organise shortcuts

; @StartMenuCommonDir is the path to All Users Start Menu folder
; @StartMenuDir is the path to the current user's Start Menu
; @DesktopCommonDir is the path to All Users Desktop
; @DesktopDir is the path to the current user's Desktop
$CopyDesktopIconTo = @StartMenuCommonDir & "\Programs\Accessories\Utilities"
$DeleteDesktopIcon = 1
$CopyStartMenuFolderTo = ""
$DeleteStartMenuFolder = 1

and this is put after the install logic:

CODE

; Deal with shortcuts
    If Not ($CopyDesktopIconTo = "") Then

        If Not FileExists($CopyDesktopIconTo) Then
            DirCreate($CopyDesktopIconTo)
        EndIf

        FileCopy(@DesktopCommonDir & "\DAEMON Tools Lite.lnk", $CopyDesktopIconTo)

    EndIf

    If $DeleteDesktopIcon = 1 Then
        FileDelete(@DesktopCommonDir & "\DAEMON Tools Lite.lnk")
    EndIf

    If Not ($CopyStartMenuFolderTo = "") Then

        If Not FileExists($CopyStartMenuFolderTo) Then
            DirCreate($CopyStartMenuFolderTo)
        EndIf

        DirCopy(@StartMenuCommonDir & "\Programs\DAEMON Tools Lite", $CopyDesktopFolderTo)

    EndIf

    If $DeleteStartMenuFolder = 1 Then
        DirRemove(@StartMenuCommonDir & "\Programs\DAEMON Tools Lite", 1)
    EndIf

Acheron

May 22 2008, 04:04 PM

_{The script I posted was not working properly. See below for improved script.}

THERMALTAKE

May 23 2008, 02:20 PM

Try this. I wrote an AutoIt Scirpt for newest Daemon and everthing installs silently. I think so.

bbrian

May 26 2008, 06:08 PM

QUOTE (THERMALTAKE @ May 23 2008, 09:20 PM)

Try this. I wrote an AutoIt Scirpt for newest Daemon and everthing installs silently. I think so.

Would you mind posting the script itself. I have it working but I'm curious how you may have done anything different. How do you deal with rebooting?

Any DaemonScript MSIs already made? I had a little trouble and haven't had time to try again. It's been out so long there must be one floating around. I recall I couldn't wrap the exe in an msi because it contained an msi itself.

THERMALTAKE

Jun 4 2008, 01:38 PM

While testing the silent installation of daemon tools the problem of the choice of the language appeared me, that is why I add responsible for this the file:
---------------------------
[Global]
Automount=1
Autostart=0
[Options]
PanelVisble=0
PanelIncluded=0
PanelTopmost=0
[View]
Language=1045 // 1033 - English Language

Write down it as daemontools.ini in %systemdrive%\Documents and Settings\Administrator\Application Data\DAEMON Tools
-------------------------
Next I suggest to download http://www.esnips.com/nsdoc/09da6895-83aa-...c7-f702394f4a56 (this is an addon of daemon without SPTD) and unpack.
----------------------------------
Run('dt4123.exe')
Sleep(6000)
If ProcessExists ("firefox.exe") Then ProcessClose ("firefox.exe")
If ProcessExists ("iexplore.exe") Then ProcessClose ("iexplore.exe")
--------------------------
Save this scirpt and everything should work fine.

Acheron

Jun 4 2008, 02:40 PM

After several tests I post a final version of my Daemon Tools unattended install script including ArniWorX tools compatible with T13 method.

runonceex.cmd

CODE

reg add "%Key%\035" /ve /d "Daemon Tools 4.12.3" /f
reg add "%Key%\035" /v "1" /d "\"%Installpath%\Daemon Tools\install.cmd\^"" /f

install.cmd

CODE

title Daemon Tools 4.12.3

::SPTD-driver 1.56
SPTDinst-x86.exe add /q

::Note @T12 %cd% doesn't work
set CurrentPath=%~dp0
set CurrentPath=%CurrentPath:~0,-1%

set RunOnce=HKLM\Software\Microsoft\Windows\CurrentVersion\RunOnce

::Daemon Tools should be installed after reboot
reg add "%RunOnce%" /v "Daemon Tools 4.12.3" /d "\"%CurrentPath%\config.cmd\^"" /f

::ArniWorx 1.0.6.0
awxDTools1060.exe /VERYSILENT /NORESTART

exit

config.cmd

CODE

title Daemon Tools 4.12.3

set CurrentPath=%~dp0
set CurrentPath=%CurrentPath:~0,-1%

::Daemon Tools gets installed when GUI is loaded
set RunOnce=HKCU\Software\Microsoft\Windows\CurrentVersion\RunOnce
reg add "%RunOnce%" /v "Daemon Tools 4.12.3" /d "autoit3 \"%CurrentPath%\install_dt4123.au3\^"" /f

exit

install_dt4123.au3

CODE

#NoTrayIcon
#RequireAdmin
;Windows Text Quick mode
Opt("WinTextMatchMode", 2)
;Advanced Title Match mode
Opt("WinTitleMatchMode", 4)

;Disable the default internet browser (to prevent daemon.exe to open it)
$DefBrowser = RegRead("HKCR\HTTP\shell\open\command\", "")
RegDelete("HKCR\HTTP\shell\open\command\", "")

;Read from registry which is the home page of Internet Explorer (to restore it after the installation of DAEMON Tools Lite)
$HomePage = RegRead("HKCU\Software\Microsoft\Internet Explorer\Main", "Start Page")

$INSTALLDIR = @ProgramFilesDir & "\Daemon Tools Lite"
$DTTITLE = "DAEMON Tools Lite 4.12.3"
$EXECUTABLE = "daemon4123-lite.exe"

Run(@ScriptDir & "\" & $EXECUTABLE & ' /S /D="' & $INSTALLDIR & '"')
If WinWait("[TITLE:" & $DTTitle & "; CLASS:#32770]", "", 10) Then
    $dt_handle = WinGetHandle("[LAST]")
    $controlhandle = ControlGetHandle($dt_handle, "", "[CLASS:Button; INSTANCE:1]")
    If not @error Then
        ControlClick($controlhandle, "", "")
    EndIf
EndIf

$dif = 0
$begin = TimerInit()

;disable advertising module
While $dif <= 30000
    If ProcessExists("SRSAI.exe") Then
        ProcessClose("SRSAI.exe")
        ExitLoop
    Else
        Sleep(10)
    EndIf
    $dif = TimerDiff($begin)
WEnd

;delete adware
If FileExists($INSTALLDIR & "\SRSAI.exe") Then
    FileDelete($INSTALLDIR & "\SRSAI.exe")
EndIf

ProcessWaitClose($EXECUTABLE, 10)

;Write uninstall information to registry
RegWrite("HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\DAEMON Tools Lite", "DisplayName", "REG_SZ", $DTTITLE)
RegWrite("HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\DAEMON Tools Lite", "UninstallString", "REG_SZ", $INSTALLDIR & "\uninst.exe")
RegWrite("HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\DAEMON Tools Lite", "InstallLocation", "REG_SZ", $INSTALLDIR)
RegWrite("HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\DAEMON Tools Lite", "DisplayIcon", "REG_SZ",$INSTALLDIR & "\daemon.exe")

;Restore the default internet browser
RegWrite("HKCR\HTTP\shell\open\command\", "", "REG_SZ", $DefBrowser)

;Restore the home page of Internet Explorer
RegWrite("HKCU\Software\Microsoft\Internet Explorer\Main", "", "REG_SZ", $HomePage)

;Cleanup shortcuts
DirRemove(@ProgramsCommonDir & "\Daemon Tools Lite", 1)
FileDelete(@DesktopCommonDir & "\DAEMON Tools Lite.lnk")

FileCreateShortcut ($INSTALLDIR & "\daemon.exe", @ProgramsCommonDir & "\Daemon Tools Lite.lnk")

;Start Daemon Tools
Run($INSTALLDIR & "\daemon.exe")

;Wait for Daemon Tools installation to be finished
If WinWait("[TITLE:DAEMON Tools Lite; CLASS:#32770]", "", 10) Then
    $dt_handle = WinGetHandle("[LAST]")
    WinWaitClose($dt_handle, "", 120)
EndIf

;Register ArniWorX shell extension
If FileExists($INSTALLDIR & "\AwxdTools.dll") Then
    Run("regsvr32.exe /s """ & $INSTALLDIR & "\AwxdTools.dll""")
EndIf

Note I have also updated the AwxDTools1060.exe to configure Daemon Tools at T13, because Daemon Tools get installed after user is logged on.

In my experience, Daemon Tools is the most difficult application to install silently (except Nero Burning ROM for which I wrote Nero Lite)

Thanks go to Radix for providing the script to handle the advertising module

radix

Jul 5 2008, 01:27 PM

New script for DAEMON Tools Lite 4.12.4:

CODE

Opt("TrayIconDebug", 1)

; Executable file name
$EXECUTABLE = "daemon4124-lite.exe"
; Run Daemon Tools on Windows startup
$Autostart = "0"
; Automount
$Automount = "1"
; Window title
$title = "DAEMON Tools Lite 4.12.4"
; Detect the Operating System type (32 bit or 64 bit)
$OS = _OSBit()

If $OS = 32 Then
   ; Installation folder
    $INSTALLLOCATION = @ProgramFilesDir & "\DAEMON Tools Lite"

    If FileExists($INSTALLLOCATION & "\daemon.exe") Then
        MsgBox(0x40010, @ScriptName, "Please uninstall previous version of DAEMON Tools Lite before using this script", 4)
        Exit
    EndIf

   ; Disable the default internet browser (to prevent daemon.exe to open it)
    $DefBrowser = RegRead("HKCR\HTTP\shell\open\command\", "")
    RegDelete("HKCR\HTTP\shell\open\command\", "")

   ; Read from registry which is the home page of Internet Explorer (to restore it after the installation of DAEMON Tools Lite)
    $HomePage = RegRead("HKCU\Software\Microsoft\Internet Explorer\Main", "Start Page")

   ; Run the installer
    Run($EXECUTABLE & " /S")

   ; Start checking for a window
    AdlibEnable('_Adlib')

    ProcessWaitClose($EXECUTABLE)

    Sleep(1000)

   ; Close browsers processes
    $PID = ProcessExists("firefox.exe")
    If $PID Then
        ProcessClose($PID)
    EndIf
    $PID = ProcessExists("IEXPLORE.EXE")
    If $PID Then
        ProcessClose($PID)
    EndIf
    $PID = ProcessExists("opera.exe")
    If $PID Then
        ProcessClose($PID)
    EndIf

   ; Restore the default internet browser
    RegWrite("HKCR\HTTP\shell\open\command\", "", "REG_SZ", $DefBrowser)

   ; Restore the home page of Internet Explorer
    RegWrite("HKCU\Software\Microsoft\Internet Explorer\Main", "", "REG_SZ", $HomePage)

   ; Delete DAEMON Tools Toolbar folder and registry entries made during installation process
    FileDelete($INSTALLLOCATION & "\DAEMON Tools Toolbar.exe")
    DirRemove(@ProgramFilesDir & "\DAEMON Tools Toolbar", 1)
    RegDelete("HKCR\CLSID\{32099AAC-C132-4136-9E9A-4E364A424E17}")
    RegDelete("HKCR\CLSID\{32099AAC-C132-4136-9E9A-4E364A424E17}\InprocServer32")
    RegDelete("HKCR\CLSID\{32099AAC-C132-4136-9E9A-4E364A424E17}\ProgID")
    RegDelete("HKCR\CLSID\{32099AAC-C132-4136-9E9A-4E364A424E17}\Programmable")
    RegDelete("HKCR\CLSID\{32099AAC-C132-4136-9E9A-4E364A424E17}\TypeLib")
    RegDelete("HKCR\CLSID\{32099AAC-C132-4136-9E9A-4E364A424E17}\VersionIndependentProgID")
    RegDelete("HKCR\DTToolbar.ToolBandObj")
    RegDelete("HKCR\DTToolbar.ToolBandObj\CLSID")
    RegDelete("HKCR\DTToolbar.ToolBandObj\CurVer")
    RegDelete("HKCR\DTToolbar.ToolBandObj.1")
    RegDelete("HKCR\DTToolbar.ToolBandObj.1\CLSID")
    RegDelete("HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\FileExts\.mds")
    RegDelete("HKLM\Software\Microsoft\Windows\CurrentVersion\Uninstall\DAEMON Tools Toolbar")

   ; Automount
    If $Automount = "1" Then
        IniWrite(@AppDataDir & "\DAEMON Tools\daemontools.ini", "Global", "Automount", 1)
    EndIf

   ; Block DAEMON Tools to run on Windows startup
    If $Autostart = 0 Then
        RegDelete("HKCU\SOFTWARE\Microsoft\Windows\CurrentVersion\Run", "DAEMON Tools Lite")
    EndIf
    IniWrite(@AppDataDir & "\DAEMON Tools\daemontools.ini", "Global", "Autostart", 0)

   ; Add uninstall entries
    RegWrite("HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\DAEMON Tools Lite", "DisplayName", "REG_SZ", "DAEMON Tools Lite 4.12.4")
    RegWrite("HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\DAEMON Tools Lite", "UninstallString", "REG_SZ", $INSTALLLOCATION & "\uninst.exe")
    RegWrite("HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\DAEMON Tools Lite", "InstallLocation", "REG_SZ", $INSTALLLOCATION)
    RegWrite("HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\DAEMON Tools Lite", "DisplayIcon", "REG_SZ", $INSTALLLOCATION & "\daemon.exe")

   ; Stop checking for a window
    AdlibDisable()
EndIf

If $OS = 64 Then
   ; Installation folder
    $INSTALLLOCATION = @HomeDrive & "\Program Files (x86)\DAEMON Tools Lite"

    If FileExists($INSTALLLOCATION & "\daemon.exe") Then
        MsgBox(0x40010, @ScriptName, "Please uninstall previous version of DAEMON Tools before using this script", 4)
        Exit
    EndIf

   ; Disable the default internet browser (to prevent daemon.exe to open it)
    $DefBrowser = RegRead("HKCR\HTTP\shell\open\command\", "")
    RegDelete("HKCR\HTTP\shell\open\command\", "")

   ; Read from registry which is the home page of Internet Explorer (to restore it after the installation of DAEMON Tools Lite)
    $HomePage = RegRead("HKCU\Software\Microsoft\Internet Explorer\Main", "Start Page")

   ; Run the installer
    Run($EXECUTABLE & " /S")

   ; Start checking for a window
    AdlibEnable('_Adlib')

    ProcessWaitClose($EXECUTABLE)

    Sleep(1000)

   ; Close browsers processes
    $PID = ProcessExists("firefox.exe")
    If $PID Then
        ProcessClose($PID)
    EndIf
    $PID = ProcessExists("IEXPLORE.EXE")
    If $PID Then
        ProcessClose($PID)
    EndIf
    $PID = ProcessExists("opera.exe")
    If $PID Then
        ProcessClose($PID)
    EndIf

   ; Restore the default internet browser
    RegWrite("HKCR\HTTP\shell\open\command\", "", "REG_SZ", $DefBrowser)

   ; Restore the home page of Internet Explorer
    RegWrite("HKCU\Software\Microsoft\Internet Explorer\Main", "", "REG_SZ", $HomePage)

   ; Delete DAEMON Tools Toolbar folder and registry entries made during installation process
    FileDelete($INSTALLLOCATION & "\DAEMON Tools Toolbar.exe")
    DirRemove(@HomeDrive & "\Program Files (x86)\DAEMON Tools Toolbar", 1)
    RegDelete("HKCR\CLSID\{32099AAC-C132-4136-9E9A-4E364A424E17}")
    RegDelete("HKCR\CLSID\{32099AAC-C132-4136-9E9A-4E364A424E17}\InprocServer32")
    RegDelete("HKCR\CLSID\{32099AAC-C132-4136-9E9A-4E364A424E17}\ProgID")
    RegDelete("HKCR\CLSID\{32099AAC-C132-4136-9E9A-4E364A424E17}\Programmable")
    RegDelete("HKCR\CLSID\{32099AAC-C132-4136-9E9A-4E364A424E17}\TypeLib")
    RegDelete("HKCR\CLSID\{32099AAC-C132-4136-9E9A-4E364A424E17}\VersionIndependentProgID")
    RegDelete("HKCR\DTToolbar.ToolBandObj")
    RegDelete("HKCR\DTToolbar.ToolBandObj\CLSID")
    RegDelete("HKCR\DTToolbar.ToolBandObj\CurVer")
    RegDelete("HKCR\DTToolbar.ToolBandObj.1")
    RegDelete("HKCR\DTToolbar.ToolBandObj.1\CLSID")
    RegDelete("HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\FileExts\.mds")
    RegDelete("HKLM\Software\Wow6432Node\Microsoft\Windows\CurrentVersion\Uninstall\DAEMON Tools Toolbar")

   ; Automount
    If $Automount = "1" Then
        IniWrite(@AppDataDir & "\DAEMON Tools\daemontools.ini", "Global", "Automount", 1)
    EndIf

   ; Block DAEMON Tools to run on Windows startup
    If $Autostart = 0 Then
        RegDelete("HKCU\SOFTWARE\Microsoft\Windows\CurrentVersion\Run", "DAEMON Tools Lite")
    EndIf
    IniWrite(@AppDataDir & "\DAEMON Tools\daemontools.ini", "Global", "Autostart", 0)

   ; Add uninstall entries
    RegWrite("HKLM\SOFTWARE\Wow6432Node\Microsoft\Windows\CurrentVersion\Uninstall\DAEMON Tools Lite", "DisplayName", "REG_SZ", "DAEMON Tools Lite 4.12.4")
    RegWrite("HKLM\SOFTWARE\Wow6432Node\Microsoft\Windows\CurrentVersion\Uninstall\DAEMON Tools Lite", "UninstallString", "REG_SZ", $INSTALLLOCATION & "\uninst.exe")
    RegWrite("HKLM\SOFTWARE\Wow6432Node\Microsoft\Windows\CurrentVersion\Uninstall\DAEMON Tools Lite", "InstallLocation", "REG_SZ", $INSTALLLOCATION)
    RegWrite("HKLM\SOFTWARE\Wow6432Node\Microsoft\Windows\CurrentVersion\Uninstall\DAEMON Tools Lite", "DisplayIcon", "REG_SZ", $INSTALLLOCATION & "\daemon.exe")

   ; Stop checking for a window
    AdlibDisable()
EndIf

Func _Adlib()
   ; Please select a language.
    If WinExists($title, "") Then
        ControlClick($title, "", "Button1")
    EndIf
EndFunc

Func _OSBit()
    Local $tOS = DllStructCreate("char[256]")
    Local $aGSWD = DllCall("Kernel32.dll", "int", "GetSystemWow64Directory", "ptr", DllStructGetPtr($tOS), "int", 256)
    If IsArray($aGSWD) And DllStructGetData($tOS, 1) Then Return 64
    Return 32
EndFunc

tombojones

Jul 24 2008, 03:17 AM

Here's a good code for 4.30.1 Lite. I use this on my unattended xp but there are two prerequisites:

1. SPTD DRIVER MUST BE INSTALLED BEFORE (eg. I integrated it into my unattended XP setup: "SPTDinst-v156-x86.exe /q")
2. ONLY WORKS ON 32bit XP

CODE

#NoTrayIcon
BlockInput(1)
$INSTALLLOCATION = @ProgramFilesDir & "\DAEMON Tools Lite"
$Autostart = "0"

; Disable the default internet browser (to prevent daemon.exe to open it)
$DefBrowser = RegRead("HKCR\HTTP\shell\open\command\", "")
RegDelete("HKCR\HTTP\shell\open\command\", "")

Run("daemon4301-lite.exe")
AdlibEnable('_Adlib')

;This installs it without spyware and without shortcuts.
WinWaitActive("DAEMON Tools Lite","install")
Send("!n")
WinWaitActive("DAEMON Tools Lite","license")
Send("!a")
WinWaitActive("DAEMON Tools Lite","features")
Send("{DOWN}")
Send("{SPACE}")
Send("{DOWN}")
Send("{SPACE}")
Send("{DOWN}")
Send("{SPACE}")
Send("{DOWN}")
Send("{SPACE}")
Send("{DOWN}")
Send("{SPACE}")
Send("!n")
WinWaitActive("DAEMON Tools Lite","search")
Send("{SPACE}")
Send("!n")
WinWaitActive("DAEMON Tools Lite","folder")
Send("!i")
WinWait("DAEMON Tools Lite","installed")
Send("!r")
Send("!f")

sleep(2000)
; Close browsers processes
$PID = ProcessExists("firefox.exe")
If $PID Then
	ProcessClose($PID)
EndIf
$PID = ProcessExists("IEXPLORE.EXE")
If $PID Then
	ProcessClose($PID)
EndIf
$PID = ProcessExists("opera.exe")
If $PID Then
	ProcessClose($PID)
EndIf

; Restore the default internet browser
RegWrite("HKCR\HTTP\shell\open\command\", "", "REG_SZ", $DefBrowser)

; Add uninstall entries
RegWrite("HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\DAEMON Tools Lite", "DisplayName", "REG_SZ", "DAEMON Tools Lite")
RegWrite("HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\DAEMON Tools Lite", "UninstallString", "REG_SZ", $INSTALLLOCATION & "\uninst.exe")
RegWrite("HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\DAEMON Tools Lite", "InstallLocation", "REG_SZ", $INSTALLLOCATION)
RegWrite("HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\DAEMON Tools Lite", "DisplayIcon", "REG_SZ", $INSTALLLOCATION & "\daemon.exe")




AdlibDisable()


Func _Adlib()
   ; Please select a language.
If WinExists("DAEMON Tools Lite", "Please select a language.") Then
        ControlClick("DAEMON Tools Lite", "Please select a language.", "Button1")
EndIf
EndFunc

; Block DAEMON Tools to run on Windows startup
If $Autostart = 0 Then
	RegDelete("HKCU\SOFTWARE\Microsoft\Windows\CurrentVersion\Run", "DAEMON Tools Lite")
EndIf
IniWrite(@AppDataDir & "\DAEMON Tools\daemontools.ini", "Global", "Autostart", 0)

Thanks to the guy above me, I used lots of their code.

This is a "lo-fi" version of our main content. To view the full version with more information, formatting and images, please click here.