Jump to content
Strawberry Orange Banana Lime Leaf Slate Sky Blueberry Grape Watermelon Chocolate Marble
Strawberry Orange Banana Lime Leaf Slate Sky Blueberry Grape Watermelon Chocolate Marble

MSFN is made available via donations, subscriptions and advertising revenue. The use of ad-blocking software hurts the site. Please disable ad-blocking software or set an exception for MSFN. Alternatively, register and become a site sponsor/subscriber and ads will be disabled automatically. 



djseppie

Add VMware Network drivers Failed

Recommended Posts

djseppie    0

Hello, im having this strange problem. I added drivers to boot.wim and i want to deploy an image to vmware workstation 6.02.

When i add the driver it goed without errors. I close the boot.wim (or course with the /commit switch).

Now i receive the error (which i ca't read of course. Anyone solved this?? I really need to the correct way to add nic drivers to my boot.wim.

Any help is welcome :-)

post-25853-1205357735_thumb.jpg

Share this post


Link to post
Share on other sites

djseppie    0

I solved this myself.. Just give your virtual machine 512mb memory and everything works fine..

Please use this script for adding drivers, it's a time-saver!

@echo off
:: Set Machine Architecture
:: Machine type can be x86, amd64, or ia64.
set mType=x86

:: Set Default WinPE Working Path
set PEwork=C:\WinPE_%mType%

:: Set location of WAIK Tools
set WAIKtools=C:\Program Files\Windows AIK\Tools

:: Set drivers path
set vDrivers=C:\Drivers

:: No real need to change anything beyond this point unless you know what you are doing.

:: Set mounted location
set mLocal=%PEwork%\mount

:: Set Source Path
set sPath=%PEwork%\ISO\sources

:: Set location of Source WIM
set oSource=%sPath%\boot.wim

:: ---------------------------------------------------------------------------------------
:: Install WinPE of not installed on local machine
if exist "%PEwork%" goto doit
call "%WAIKtools%\PETools\copype.cmd" %mType% "%PEwork%"
:doit
cls
:: Mount the WIM image
"%WAIKtools%\%mType%\imagex" /mountrw "%oSource%" 1 "%mLocal%"

echo Adding VMWare Networking Drivers...
echo.
"%WAIKtools%\PETools\peimg" /inf="%vDrivers%\vmxnet\win2k\vmware-nic.inf" "%mLocal%\windows"
"%WAIKtools%\PETools\peimg" /inf="%vDrivers%\vmxnet\win2k\vmxnet.inf" "%mLocal%"
echo.
cls
echo Adding VMWare Video Drivers...
echo.
"%WAIKtools%\PETools\peimg" /inf="%vDrivers%\video\winnt2k\32Bit\vmx_svga.inf" "%mLocal%\windows"
cls
echo.
echo Adding VMWare SCSI Drivers...
echo.
"%WAIKtools%\PETools\peimg" /inf="%vDrivers%\scsi\win2k\vmscsi.inf" "%mLocal%\windows"
cls
echo.
echo Adding VMWare Mouse Drivers...
echo.
"%WAIKtools%\PETools\peimg" /inf="%vDrivers%\mouse\win2k\32Bit\vmmouse.inf" "%mLocal%\windows"
cls
echo.
echo Adding VMWare System Drivers...
echo.
"%WAIKtools%\PETools\peimg" /inf="%vDrivers%\memctl\win2k\32Bit\vmmemctl.inf" "%mLocal%\windows"
"%WAIKtools%\PETools\peimg" /install=*SRT* "%mLocal%\windows"
cls
"%WAIKtools%\PETools\peimg" /list "%mLocal%\windows"
pause
cls
echo.
echo Copying System Tools to image...
echo.
xcopy "%WAIKtools%\%mType%" "%mLocal%\windows\system32\" /S /Q /R /Y
set fn="%mLocal%\windows\system32\Wimscript.ini"
> %fn% echo [ExclusionList]
>> %fn% echo ntfs.log
>> %fn% echo hiberfil.sys
>> %fn% echo pagefile.sys
>> %fn% echo "System Volume Information"
>> %fn% echo RECYCLER
>> %fn% echo Windows\CSC
>> %fn% echo.
>> %fn% echo [CompressionExclusionList]
>> %fn% echo *.mp3
>> %fn% echo *.zip
>> %fn% echo *.cab
>> %fn% echo \WINDOWS\inf\*.pnf
cls
echo.
echo Apply the changes to WIM and build ISO...
echo.
"%WAIKtools%\%mType%\imagex" /unmount "%mLocal%" /commit
"%WAIKtools%\PETools\oscdimg" -n -b%PEwork%\etfsboot.com -h -lCustom_WinPE "%PEwork%\ISO" "%PEwork%\winpe_%mType%.iso"
cls
echo.
echo Everything is finished!
echo.
echo You have now successfully created a new ISO image ("%PEwork%\winpe_%mType%.iso")
echo of Windows PE 2.x including VMWare Drivers.
echo.
pause
:EXIT

Share this post


Link to post
Share on other sites
dim    0

Nice little script

If you want it to be a little more dynamic use CMD inputs like

scriptname.cmd %arch% %location% %mountpoint% %driverlocation%

blah.. Build that out and then let the scripts dynamically add the variable

Or, switch to vbscript

Share this post


Link to post
Share on other sites

Create an account or sign in to comment

You need to be a member in order to leave a comment

Create an account

Sign up for a new account in our community. It's easy!

Register a new account

Sign in

Already have an account? Sign in here.

Sign In Now


  • Recently Browsing   0 members

    No registered users viewing this page.

×