Jump to content

Welcome to MSFN Forum
Register now to gain access to all of our features. Once registered and logged in, you will be able to create topics, post replies to existing threads, give reputation to your fellow members, get your own private messenger, post status updates, manage your profile and so much more. This message will be removed once you have signed in.
Login to Account Create an Account


Photo

Win7 & MSDart Combination?

- - - - -

  • Please log in to reply
4 replies to this topic

#1
Kelsenellenelvian

Kelsenellenelvian

    WPI Guru

  • Developers
  • 8,693 posts
  • OS:Windows 7 x64
  • Country: Country Flag

I have my Win7 a-i-o that I made myself.

 

I also have MSDart and would like to ask for assistance with 2 things:

 

How can I combine MSDart 86 and MSDart 64? it seems do-able.

 

Then is it possible to add msdart into my win7 all-in-one?




How to remove advertisement from MSFN

#2
jaclaz

jaclaz

    The Finder

  • Developers
  • 13,386 posts
  • OS:none specified
  • Country: Country Flag

I have my Win7 a-i-o that I made myself.

 

I also have MSDart and would like to ask for assistance with 2 things:

 

How can I combine MSDart 86 and MSDart 64? it seems do-able.

 

Then is it possible to add msdart into my win7 all-in-one?

 

Which version of MSDART?

There are quite a few, AFAICR.

 

Anyway, anyone using BOOTMGR and .wim booting should work fine as ".iso" from grub4dos.

http://www.911cd.net...showtopic=24602

 

jaclaz



#3
cdob

cdob

    Friend of MSFN

  • Members
  • PipPipPipPipPip
  • 951 posts

Then is it possible to add msdart into my win7 all-in-one?

Which files are inside msdart CD?
Does exist
\boot\
\sources\boot.wim

Bootmgr can load win7 and msdart.
Rename \sources\boot.wim from msdart x86 and copy to win7 \sources\. Configure bcd to load this *.wim file.
Repeat this to x64 *.wim file.

Example \sources\boot_7PE.wim.
Edit the 'call :add_PE' line to your needs. Add a second line for x64 .wim file.

ADD_PE.cmd
@ECHO OFF
Rem Add Windwos 7 PE to Windows 7 install

set DVD_root=%~1
if %DVD_root%.==. set DVD_root=DVD

set boot_mode=BIOS
set BCD_store=/store "%DVD_root%\boot\bcd"
call :add_BCD
BCDedit.exe %BCD_store% /enum all

set boot_mode=UEFI
set BCD_store=/store "%DVD_root%\efi\microsoft\boot\bcd"
call :add_BCD

oscdimg.exe -o -u2 -udfver102 -yo.\bootorder.txt -bootdata:2#p0,e,b"%DVD_root%\boot\etfsboot.com"#pEF,e,b"%DVD_root%\efi\microsoft\boot\efisys.bin" "%DVD_root%" AIO.ISO

goto :eof

:add_BCD ===========================================================
BCDedit.exe %BCD_store% /set {default} description "%boot_mode%: Windows Setup"
rem Unify ramdisk settings
BCDedit.exe %BCD_store% /create {ramdiskoptions}
BCDedit.exe %BCD_store% /set {ramdiskoptions} ramdisksdidevice boot
BCDedit.exe %BCD_store% /set {ramdiskoptions} ramdisksdipath \boot\boot.sdi

if %boot_mode%.==BIOS. call :add_PE \sources\b7PE_x86.wim "Windows 7 PE x86"
call :add_PE \sources\b7PE_x64.wim "Windows 7 PE x64"


goto :eof ==== create_BCD =============================================


:add_PE ==============================================================
 for /f "tokens=1-3" %%a in ('BCDedit.exe %BCD_store% /create /application OSLOADER') do set guid=%%c
 BCDedit.exe %BCD_store% /set %guid% description "%boot_mode%: %~2"
 BCDedit.exe %BCD_store% /set %guid% osdevice ramdisk=[boot]%1,{ramdiskoptions}
 BCDedit.exe %BCD_store% /set %guid% device ramdisk=[boot]%1,{ramdiskoptions}
 BCDedit.exe %BCD_store% /set %guid% systemroot \windows
 if %boot_mode%.==BIOS. set winload=winload.exe
 if %boot_mode%.==UEFI. set winload=winload.efi
 BCDedit.exe %BCD_store% /set %guid% path \windows\system32\boot\%winload%
 BCDedit.exe %BCD_store% /set %guid% detecthal Yes
 BCDedit.exe %BCD_store% /set %guid% winpe Yes
 BCDedit.exe %BCD_store% /displayorder %guid% /addlast
goto :eof ==============================================================
bootorder.txt
boot\bcd
boot\boot.sdi
boot\bootfix.bin
boot\etfsboot.com
boot\memtest.efi
boot\memtest.exe
boot\fonts\chs_boot.ttf
boot\fonts\cht_boot.ttf
boot\fonts\jpn_boot.ttf
boot\fonts\kor_boot.ttf
boot\fonts\wgl4_boot.ttf
efi\microsoft\boot\bcd
efi\microsoft\boot\efisys.bin
efi\microsoft\boot\efisys_noprompt.bin
sources\boot.wim
sources\boot_7PE.wim
sources\b7PE_x86.wim
sources\b7PE_x64.wim

Edited by cdob, 02 November 2013 - 11:24 AM.


#4
Kelsenellenelvian

Kelsenellenelvian

    WPI Guru

  • Developers
  • 8,693 posts
  • OS:Windows 7 x64
  • Country: Country Flag

Thats just what I was looking for !!!

 

Thank you so much.



#5
cdob

cdob

    Friend of MSFN

  • Members
  • PipPipPipPipPip
  • 951 posts
Sorry, approach uses winload.exe for BIOS and UEFI. It's winload.efi at UEFI mode.

And use Windows 7 x64 at UEFI mode, not x86
if %boot_mode%.==BIOS. call :add_PE \sources\b7PE_x86.wim "Windows 7 PE x86"
call :add_PE \sources\b7PE_x64.wim "Windows 7 PE x64"




0 user(s) are reading this topic

0 members, 0 guests, 0 anonymous users



How to remove advertisement from MSFN