[fourte3n]

OK.... I have made my own XPCD, setup all the things to be installed from bit n' pieces off this site and I try installing (within virtualPC) and it installs xp and my icons and skin but forgets the rest: applications, regtweaks and cursors.

So far it seems that it does go through the runonceex.cmd (or it wouldnt use my icons) but the apps aren't installed and regtweaks arn't either... can someone help?? I'll only post the files if asked.

[Astalavista]

y dont u start by posting your runonceEX.cmd

your winnt.sif

do you have in your winnt.sif

OemPreinstall=Yes

most commond mistake is not putting that in.
if you don't everything in $oem$ doesn't get copy to your %systemdrive% or installed from the CD.

get it

[fourte3n]

Winnt.sif

Quote

[Data]MsDosInitiated = 0
UnattendedInstall = Yes

[Unattended]
UnattendMode = FullUnattended
UnattendSwitch = Yes
OemPreinstall = Yes
OemSkipEula = Yes
FileSystem = *
WaitForReboot = No
TargetPath = "\Windows"
DriverSigningPolicy = Ignore
NonDriverSigningPolicy = Ignore
Hibernation = No

[SystemFileProtection]
SFCQuota = 0

[SystemRestore]
MaximumDataStorePercentOfDisk = 5

[GuiUnattended]
AutoLogon = Yes
AdminPassword = *
TimeZone = 255
OEMSkipRegional = 1
OemSkipWelcome = 1

[Display]
              BitsPerPel=32
              Xresolution=1024
              Yresolution=768
              Vrefresh=60


[UserData]
ProductKey = "0000-0000-0000-0000-0000"
ComputerName = "System001"
FullName = "Jon Doe"

[RegionalSettings]
Language = 0C09

[Identification]
JoinWorkgroup = MSHOME

[Shell]
            CustomDefaultThemeFile = "%WinDir%\Resources\Themes\SpaceMilk.theme"

[GuiRunOnce]
            %systemdrive%\runonceex.cmd

Runonceex.cmd

Quote

cmdow @ /HID
@echo off

SET KEY=HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\RunOnceEx

REG ADD %KEY% /V TITLE /D "Installing Applications" /f

REG ADD %KEY%\005 /VE /D "Mozilla Firefox 0.9.3" /f
REG ADD %KEY%\005 /V 1 /D "%systemdrive%\Install\firefox\Firefox_Deployment.exe /S" /f

REG ADD %KEY%\010 /VE /D "Adobe Reader 6" /f
REG ADD %KEY%\010 /V 1 /D "%systemdrive%\install\Acrobat\AdbeRdr60_enu_full.exe -p"-s /v\"/qn\"" /f

REG ADD %KEY%\015 /VE /D "LeechGet 2004" /f
REG ADD %KEY%\015 /V 1 /D "%systemdrive%\Install\LeechGet\LeechGet2004.exe /SILENT" /f
REG ADD %KEY%\015 /V 2 /D "%systemdrive%\Install\pskill\sleep.exe /5" /f
REG ADD %KEY%\015 /V 3 /D "%systemdrive%\Install\pskill\pskill LeechGet.exe" /f

REG ADD %KEY%\020 /VE /D "Windows Media Player 10" /f
REG ADD %KEY%\020 /V 1 /D "%systemdrive%\install\WMP10\mp10setup.exe /Q:A /R:N /c:"setup_wm.exe /Q /R:N /NoPID /DisallowSystemRestore" /S" /f
REG ADD %KEY%\020 /V 2 /D "REGEDIT /S %systemdrive%\install\WMP10\WMP10mods.reg" /f

REG ADD %KEY%\025 /VE /D "Sun Java 1.4.2" /f
REG ADD %KEY%\025 /V 1 /D "%systemdrive%\install\Java\j2re-1_4_2_05-windows-i586-p.exe /S /V/QN" /f
REG ADD %KEY%\025 /V 2 /D "REGEDIT /S %systemdrive%\install\Java\Javamods.reg" /f

REG ADD %KEY%\030 /VE /D "Agnitum Outpost Firewall PRO v2.1" /f
REG ADD %KEY%\030 /V 1 /D "%systemdrive%\install\Outpost\OutpostProInstall.exe /S REBOOT=REALLYSUPPRESS" /f

REG ADD %KEY%\035 /VE /D "IZArc 3.4.1.6" /f
REG ADD %KEY%\035 /V 1 /D "%systemdrive%\install\IZArc\izarc.exe /qb" /f
REG ADD %KEY%\035 /V 2 /D "REGEDIT /S %systemdrive%\install\IZArc\IZArcskin.reg" /f

REG ADD %KEY%\040 /VE /D "Nero Burning ROM 6.3" /f
REG ADD %KEY%\040 /V 2 /D "%systemdrive%\install\Nero\Nero63120.exe /SILENT /NOREBOOT /SN=0000-0000-0000-0000-0000 /WRITE_SN" /f

REG ADD %KEY%\045 /VE /D "TweakUI Powertoy" /f
REG ADD %KEY%\045 /V 1 /D "REGEDIT /S %systemdrive%\install\TweakUI\tweakui.reg" /f

REG ADD %KEY%\050 /VE /D "Kaspersky Anti Virus 5" /f
REG ADD %KEY%\050 /V 1 /D "%systemdrive%\install\KAV5\KAV5.exe /S" /f
REG ADD %KEY%\050 /V 2 /D "REGEDIT /S %systemdrive%\install\KAV5\register.reg" /f

REG ADD %KEY%\055 /VE /D "Ad-Aware SE Personal Edition" /f
REG ADD %KEY%\055 /V 1 /D "%systemdrive%\install\AdAware\aawsepersonal.exe /S" /f
REG ADD %KEY%\055 /V 2 /D "%systemdrive%\Install\pskill\sleep.exe /5" /f
REG ADD %KEY%\055 /V 3 /D "%systemdrive%\Install\pskill\pskill hh.exe" /f
REG ADD %KEY%\055 /V 4 /D "%systemdrive%\Install\pskill\pskill Ad-Aware.exe" /f

REG ADD %KEY%\060 /VE /D "QuickTime Alternative" /f
REG ADD %KEY%\060 /V 1 /D "%systemdrive%\install\QuickTime\quicktimealt134.exe /VERYSILENT /SP-" /f

REG ADD %KEY%\065 /VE /D "Open Office 1.1.2" /f
REG ADD %KEY%\065 /V 1 /D "%systemdrive%\install\OpenOffice\setup.exe -r %systemdrive%\install\OpenOffice\response.txt" /f
REG ADD %KEY%\065 /V 2 /D "REGEDIT /S %systemdrive%\install\OpenOffice\OOorg.reg" /f
REG ADD %KEY%\065 /V 3 /D "REGEDIT /S %systemdrive%\install\OpenOffice\OOorgUninstall.reg" /f

REG ADD %KEY%\075 /VE /D "Importing Registry Tweaks" /f
REG ADD %KEY%\075 /V 1 /D "REGEDIT /S %systemdrive%\install\regtweaks.reg" /f

REG ADD %KEY%\080 /VE /D "Importing Icon Settings" /f
REG ADD %KEY%\080 /V 1 /D "REGEDIT /S %systemdrive%\install\icons.reg" /f

REG ADD %KEY%\085 /VE /D "Importing Fonts" /f
REG ADD %KEY%\085 /V 1 /D "REGEDIT /S %systemdrive%\install\fonts.reg" /f

REG ADD %KEY%\090 /VE /D "Cleaning Up and Rebooting" /f
REG ADD %KEY%\090 /V 1 /D "%systemdrive%\install\cleanup.cmd" /f

EXIT

I did have the runonceex.cmd in the $OEM$ dir but that didn't work so it's now in the $1 dir....

Also you posted: oempreinstall=yes I have oempreinstall = yes is that an issue?

Quote

get it

huh?

[Aaron]

12. Very often we see meaningless subjects in topic title. They give no clue of what the posts are all about. For example:

- Oh no!
- Help
- I'm mad
- Please help
- Question
- I need your help
- Hmmmm ....

This should be avoided. Users should enter something more specific in topic title so that it is easier for others to help.

A few good examples:

- Strange problem with DirectX9b redist
- RunOnceEx install problem (double installation)
- Change Internet Explorer's Icon back to default

http://www.msfn.org/...showtopic=18408

No capitals in topic title either!

[Astalavista]

show me your cleanup.cmd

and your prepare.cmd

[bonedaddy]

you might try putting RunOnceEx back in $OEM$ and paste this to notepad

[COMMANDS]
"RunOnceEx.cmd"

and call it cmdlines.txt, then copy to $OEM$ as well

instead of using GuiRunOnce

works for me and is suggested in MSFN guide

[fourte3n]

cleanup.cmd

Quote

cmdow @ /HID
shutdown.exe -r -f -t 60 -c "Windows XP will now restart in 1 minute..."
net user aspnet /delete

COPY /Y "%systemdrive%\install\**filere moved**" "%systemdrive%\Program Files\Agnitum\Outpost Firewall\"
COPY /Y "%systemdrive%\install\LeechGet\**file removed**" "%systemdrive%\Program Files\LeechGet 2004\"

RD /S /Q "%AllUsersProfile%\Start Menu\Programs\PrintMe Internet Printing"
RD /S /Q "%AllUsersProfile%\Start Menu\Programs\Java Web Start"

DEL "%systemroot%\*.bmp"
DEL "%systemroot%\system32\dllcache\*.scr"
DEL "%systemroot%\system32\*.scr"

DEL "%AllUsersProfile%\Start Menu\Windows Update.lnk"
DEL "%AllUsersProfile%\Start Menu\Set Program Access and Defaults.lnk"
DEL "%AllUsersProfile%\Start Menu\Windows Catalog.lnk"
DEL "%AllUsersProfile%\Start Menu\Programs\Windows Movie Maker.lnk"
DEL "%AllUsersProfile%\Start Menu\Programs\Adobe Reader 6.0.lnk"

DEL "%AllUsersProfile%\Desktop\Java Web Start.lnk"
DEL "%AllUsersProfile%\Desktop\Adobe Reader 6.0.lnk"
DEL "%AllUsersProfile%\Desktop\Alcohol 120%.lnk"

RD /S /Q %systemdrive%\Firefox
RD /S /Q "%systemroot%\Cache\Adobe Reader 6\"
RD /S /Q %systemdrive%\drivers\
RD /S /Q %systemdrive%\install\

EXIT

prepare..... i dont have. :/ i'll look into that. didn't see it in the list.


Astalavist.... sorry about the title. wont do that again. just PM me about these things as many threads also get clogged up with admin corrections too


** Edit ** I just ran the runonceex.cmd and the only issues were the "too many paramaters on acrobat and mp10. help here will also be great.

[Astalavista]

for the adobe acrobat u can download RyanVm's compressed Adobe Acrobat. do a search. he also gives instructions on how to use it.

same with mp10 there is a thread on it already do a search

[fourte3n]

thanks asta... i have searched and thats how i got the info i have... which aren't working. if there is wronf ways on the site maybe they should be deleted.

[Alanoll]

IF you haven't figured out what's wrong. Restart the virtual Machine again. THat should start the RunOnceEX. If you have and all that's wrong is switches.....

REG ADD %KEY%\010 /V 1 /D "%systemdrive%\install\Acrobat\AdbeRdr60_enu_full.exe -p"-s /v\"/qn\"" /f

should be

REG ADD %KEY%\010 /V 1 /D "%systemdrive%\install\Acrobat\AdbeRdr60_enu_full.exe -p\"-s /v\"/qn\"\"" /f

You had nested quotes without escaping them.

REG ADD %KEY%\020 /V 1 /D "%systemdrive%\install\WMP10\mp10setup.exe /Q:A /R:N /c:"setup_wm.exe /Q /R:N /NoPID /DisallowSystemRestore" /S" /f

should be

REG ADD %KEY%\020 /V 1 /D "%systemdrive%\install\WMP10\mp10setup.exe /Q:A /R:N /c:\"setup_wm.exe /Q /R:N /NoPID /DisallowSystemRestore\" /S" /f

I believe. Again, nested quotes not escaped.




FYI- It was Aaron who told you about the title Not Astalavista. Also, it is better to post the problem on the board rather then PM, simply because obviously people don't read ALL the rules, and the posts serve as little helpful reminders.

[Astalavista]

hehheheheh......

[fourte3n]

thankyou...