[andrewpayne]

Has anyone tried silently installing Windows Media Connect?

/Q is for silent - but it halts when it detects System Restore is disabled. I have tried the WMP10 /DisallowSystemRestore switch as a custom command (/C:) to no avail.

Anyone?

[Frank_Sechrist]

There's a thread in the Unattended Windows section that I started. I have the exact same problem.

So far, no one seems to know of a solution.

[erik_demon]

Use /Q:A /R:N
This one works for me.
Be sure to install WMP10 before you install this program

EDIT:
Don't install this program in your svcpack.inf, that won't work.

I installed it with my RunOnceEx.cmd

REG ADD %KEY%\010 /VE /D "Windows-Updates" /f
REG ADD %KEY%\010 /V 1 /D "%systemdrive%\install\Applications\Framework_upgrade\NDP1.1sp1-KB867460-X86.exe /Q" /f
REG ADD %KEY%\010 /V 2 /D "%systemdrive%\install\Applications\Framework_NL\langpack.msi /qb" /f
REG ADD %KEY%\010 /V 3 /D "%systemdrive%\install\Applications\High-mat\HMTCDWizard.msi /qb" /f
REG ADD %KEY%\010 /V 4 /D "%systemdrive%\install\applications\WMP10\MP10Setup.exe /q:A /c:\"setup_wm.exe /Q /R:N /DisallowSystemRestore\"" /f
REG ADD %KEY%\010 /V 5 /D "%systemdrive%\install\applications\WMP10\wmcsetup.exe /Q:A /R:N" /f

[andrewpayne]

Great thanks! Tested this morning and it works a treat!

EDIT - My System Restore is disabled AFTER the first reboot and RunOnceEx is run. I've posted how to later in this topic.

[Frank_Sechrist]

It sure doesn't work for me. I'm running it from RunOnceEx.cmd, but turning system restore off first from cmdlines.txt via registry tweaks.

If system restore is turned off, wmconnect generates the System Restore warning message.

There's got to be a switch to stop it, but I'm not smart enough to figure it out.

[leungda]

I have the following but the Media Connect didn't install

REG ADD %KEY%\021 /VE /D "Windows Media Player v10" /f
REG ADD %KEY%\021 /V 1 /D "%systemdrive%\install\MP10Setup.exe /Q:A /R:N /C:\"setup_wm.exe /DisallowSystemRestore /Q:A /R:N\"" /f
REG ADD %KEY%\021 /V 2 /D "%systemdrive%\install\wmcsetup.exe /Q:A /R:N" /f

[argon007]

Yeah, what is the switch for it?

[andrewpayne]

I have disabled the System Restore service at the end of RUNONCEX.CMD by adding REGEDIT /S DISREST.REG (below) to CLEANUP.CMD

Windows Registry Editor Version 5.00 

;----- Disable System Restore
;----- Value: (0 = disabled, 1 = enabled)
;-----
[HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows NT\CurrentVersion\SystemRestore]
"DisableSR"=dword:00000001

This reg file is saved alongside CLEANUP.CMD in the root of the INSTALL directory.

cmdow @ /HID

REGEDIT /S %systemdrive%\install\disrest.reg
shutdown.exe -r -f -t 60 -c "Windows XP will now restart in 1 minute..."
net user aspnet /delete
RD /S /Q %systemdrive%\drivers\
RD /S /Q %systemdrive%\install\
EXIT

It is then one of the last things to be applied before the auto shutdown after the apps (including WMP10 and Media Connect) are installed and the shell is loading.

I hope this makes sense! I have tested this and it works for me.
BTW I do not use NLITE - just the methods described in MDFN's Unattended Guide using RUNONCEX.CMD

EDIT - Note that the full path MUST be included for the successful import of the registry file

[Sanjay]

.PLEASE IGNORE THIS POST. IT SEEMS THE SWITCHES I MENTIONED EARLIER, DO NOT WORK.
SORRY FOR THE INCONVENIENCE.

[andrewpayne]

I am going to keep to my method (above) just in case any future MS hotfixes/patches insist on the System Restore service, as it simply disables the System Restore after all the apps/hotfixes and patches have loaded from RunOnceEx.cmd

[argon007]

It does not work..
oh man... can you help me again?

[CoffeeFiend]

I can tell you that, no switches or msi editing is gonna fix this. Sorry. The nag isn't even coming from the installer. The only workaround I can imagine for now is re-enabling system restore temporarily.

[big poppa pump]

crahak, on Oct 16 2004, 05:16 PM, said:

I can tell you that, no switches or msi editing is gonna fix this. Sorry. The nag isn't even coming from the installer. The only workaround I can imagine for now is re-enabling system restore temporarily.

Yes I agree with you.

This program installs 2 services that require systemrestore to be enabled and you are always going to get that nag if systemrestore is disabled. The only option is to use a batch file to enable systemrestore temporarily, then install the program and then disable systemrestore again.

[andrewpayne]

Don't you guys read the previous posts?

My method keeps the System Restore on until the last possible moment - ie just before Shutdown after RunOnceEx.cmd completes.

[CoffeeFiend]

andrewpayne, on Oct 16 2004, 06:03 PM, said:

Don't you guys read the previous posts?

My method keeps the System Restore on until the last possible moment - ie just before Shutdown after RunOnceEx.cmd completes.

Yes, I know, that's why I mentionned that. (mind you, I don't really want it to be enabled - and the system creating some system restore information, wasting some space for nothing.)

@big poppa pump: No. They don't need it. They only warn. I've already posted all the information about this one in this thread: http://www.msfn.org/...showtopic=30169 (at the end). If you could repackage it all together. You wouldn't need system restore at all...

Other than that, one could use something such as AutoIt to press the button on the system restore nag too.

[Sanjay]

Here is my solution to this whole thing. I still have 'System Restore' disabled thru the registry tweaks run via cmdlines.txt But then I have incorporated 'System Restore' Enable & Disable in my start.cmd

My start.cmd entries:

Ignore this. Nilfred's method below solves the problem

[CoffeeFiend]

@Sanjay That's a working workaround, but ideally we would rather not have to enable it... Until I get around to have a patched and properly working msi installer, I got nothing better to offer

[Nilfred]

As I learn from bitmonster here is a small guide how to create your own silent install package:

• Get the Windows Media Connect package in your native tongue and put it in some folder.
  
• Get 7-Zip and install it. Open up the folder where 7-zip has installed itself to and grab the 7za.exe and 7zS.sfx files and copy them to your folder. You can deinstall 7-Zip now if you want.
  
• Get the UPX-package (Win32 console version), unpack it and copy the upx.exe to your folder
  
• Get the StartX-package, grab the StartX.exe out of the archive (you find it in the 'Release' folder) and move it to your folder.
  
• Make a new batch-file in your folder, name it wmc.bat and paste the following text into it:

SET TmpDir=%~dp0tmp
SET BuildDir=%~dp0build\
%~d0
CD "%~p0"
MD "%BuildDir%"
COPY StartX.exe "%BuildDir%StartX.exe"

SET Target=wmcsetup
CALL :make_tmp

SET MsiName=
FOR %%I in (*.*) DO IF /I "%%~xI" == ".MSI" SET MsiName=%%I
START /wait msiexec /a "%MsiName%" TARGETDIR="%BuildDir%" /QB
CD..
RMDIR /S /Q tmp

CD "%BuildDir%"
SET RedistFile=
FOR /R %%I in (wmfdist??.exe) DO SET RedistFile=%%I
CD..
MOVE "%RedistFile%" .

SET Target=wmfdist95
CALL :make_tmp

CALL :make_7z
RMDIR /S /Q tmp

ECHO;!@Install@!UTF-8!>config.txt
ECHO RunProgram="wmsetsdk.exe /DisallowSystemRestore /WMFDIST /Quiet /R:N">>config.txt
ECHO;!@InstallEnd@!>>config.txt

CALL :make_exe
MOVE %Target%7.exe "%RedistFile%"
DEL %Target%.exe

SET Target=wmcsetup
CD "%BuildDir%"
CALL :make_7z
RMDIR /S /Q "%BuildDir%"

ECHO;!@Install@!UTF-8!>config.txt
ECHO RunProgram="StartX.exe /WAIT \"msiexec /i %MsiName% /qb\"">>config.txt
ECHO;!@InstallEnd@!>>config.txt

CALL :make_exe
GOTO:EOF

:make_tmp
MD "%TmpDir%"
START /wait %Target%.exe /Q:A /C /T:"%TmpDir%"
CD "%TmpDir%"
GOTO:EOF

:make_7z
..\7za.exe a "%~dp0%Target%.7z" -r -mx=7 -mfb=255 -md=48m *
CD..
GOTO:EOF

:make_exe
IF NOT EXIST 7zSC.sfx upx.exe 7zS.sfx -o7zSC.sfx
COPY /b 7zSC.sfx + config.txt + %Target%.7z %Target%7.exe
DEL config.txt
DEL %Target%.7z
GOTO:EOF

Now you should have the following files in your folder:

wmcsetup.exe
7za.exe
7zS.sfx
upx.exe
StartX.exe
wmc.bat

Start the wmc.bat and wait 3 minutes. At the end you should have a wmcsetup7.exe in your folder with a size of about 4.7 MB.

You can run this standalone file through svcpack.inf or any other batch without any commandline switches. But if you use a batch instead of svcpack.inf you should use the start-command:

start /wait wmcsetup7.exe

Also place care to run it after WMP10 setup, and start WMP10 before try to start WMC or errors may occur.

Attached File(s)

•  wmc.bat.txt (1.33K)
  Number of downloads: 194

[Sanjay]

crahak, on Oct 17 2004, 06:17 PM, said:

@Sanjay That's a working workaround, but ideally we would rather not have to enable it... Until I get around to have a patched and properly working msi installer, I got nothing better to offer 

Actually it turns out that this is not much of a workaround anyhow and it still brings up the silly 'System Restore' message.
I don't understand why it does not work though, when I try it in an existing Windows install it works fine, but during the unattended install it does not work for some reason.

[Sanjay]

@Nilfred
Your method seems to work just fine but won't know for sure until a real unattended install.

Thanks a ton.

Update: Works fine in a VMWare install. Now to test on a real PC.

Update 2: Works fine in a real unattended install on a real PC.