[qctrip]

I have my RunOnceEx.cmd installing many tools that work because I have tested the CD/DVD many times now. I added Office 2000 and Office 2000 Multilanguage pack. Usually RunOnceEx install the first item, when finished installs the next and so on. When it gets to Office, the install starts, but then the next item on the list starts up as well. I re-arranged my install order but I would like to know how to permamnently fix this.

Here is my runonce.exe
===========================================
cmdow @ /HID
@echo off
FOR %%i IN (D E F G H I J K L M N O P Q R S T U V W X Y Z) DO IF EXIST %%i:\CD.txt SET CDROM=%%i:

SET KEY=HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\RunOnceEx

REG ADD %KEY% /V TITLE /D "Installation D'Outils de Support ADS 2003" /f

;REG ADD %KEY%\005 /VE /D "Microsoft .NET Framework 1.1" /f
;REG ADD %KEY%\005 /V 1 /D "%CDROM%\Applications\NetFramework11\netfx.msi /quiet /norestart" /f

REG ADD %KEY%\010 /VE /D "Group Policy Management Console" /f
REG ADD %KEY%\010 /V 1 /D "%CDROM%\Applications\GPMCSP1\gpmc.msi /qn" /f

REG ADD %KEY%\015 /VE /D "Windows 2003 AdminPak" /f
REG ADD %KEY%\015 /V 1 /D "%CDROM%\Applications\Adminpak2003\adminpak.msi /quiet /norestart" /f

REG ADD %KEY%\020 /VE /D "XP Support Tools (KB838079)" /f
REG ADD %KEY%\020 /V 1 /D "%CDROM%\Applications\SupportTools\suptools.msi /quiet /norestart" /f

REG ADD %KEY%\025 /VE /D "Windows 2003 Resource Kit" /f
REG ADD %KEY%\025 /V 1 /D "%CDROM%\Applications\ResourceKit\rktools.msi /quiet /norestart" /f

REG ADD %KEY%\026 /VE /D "Microsoft Office 2000 SP3" /f
REG ADD %KEY%\026 /V 1 /D "%CDROM%\Applications\Office2000SP3\setuppro.exe TRANSFORMS=GPNET.MST /qb-" /f

REG ADD %KEY%\027 /VE /D "Microsoft Office 2000 MultiLangue" /f
REG ADD %KEY%\027 /V 1 /D "%CDROM%\Applications\Office2000MUI\langpack.msi TRANSFORMS=MUI.MST /qb-" /f

REG ADD %KEY%\028 /VE /D "Windows XP MultiLangue" /f
REG ADD %KEY%\028 /V 1 /D "%CDROM%\Applications\MUIXP\muisetup.exe /i 040c /d 040c /r /s" /f

REG ADD %KEY%\029 /VE /D "Adobe Acrobat Reader 5.05" /f
REG ADD %KEY%\029 /V 1 /D "%CDROM%\Applications\Acrobat505\Acrobat.msi /qn /norestart" /f

REG ADD %KEY%\035 /VE /D "Modifications de Registre" /f
REG ADD %KEY%\035 /V 1 /D "REGEDIT /S %CDROM%\Applications\tweaks.reg" /f

REG ADD %KEY%\040 /VE /D "Nettoyage et Redemarrage" /f
REG ADD %KEY%\040 /V 1 /D "%CDROM%\Applications\cleanup.cmd" /f

EXIT
=======================================

So Office 2000 and Office 2000 MultiLangue installations start, but RunOnceEx does not wait to start the install of the next item. Any help would be greatly appreciated.

Thank you

[qctrip]

I found a solution. I put sleep.exe to good use.

REG ADD %KEY%\026 /VE /D "Microsoft Office 2000 SP3" /f
REG ADD %KEY%\026 /V 1 /D "%CDROM%\Applications\Office2000SP3\setuppro.exe TRANSFORMS=GPNET.MST /qb-" /f
REG ADD %KEY%\026 /V 2 /D "C:\Windows\System32\sleep.exe 200" /f

[jondercik]

Dont have it call the exe to setup office, use the msi file. What I believe is happening is the setup program is doing its work and spawning the actual install process, then quitting, causing RunOnceEx to go to the next step.

[Dahi]

I call this batch file from runonceex, and each installer runs one after the other.
Setuppro.exe does not exit until MS-Office installation is finished.

@echo off

echo Installing Office 2003 SP1
"%~dp0Office2003\setuppro.exe" transorms=Unattended.mst /QB

echo Installing Frontpage 2003
"%~dp0Frontpage\FP11.MSI"  /QB

echo Installing OneNote 2003
"%~dp0OneNote2003sp1\ONOTE11.MSI" /QB

echo Installing Visio 2003
"%~dp0Visio2003SP1\VISPRO.MSI" /QB