[jehuu_za]

Hi.
My first post here

How can I delete all of the content in %temp% -path (using a dos batch file)without removing the temp path it self and mkdir it again?

I coud do it if I only knew what kind of directories it contain, but haven't managed to empty it with only one command.
Allready tried:
rmdir /S /Q %temp%\*

please help

[erik_demon]

Hey

I use this in my clean-up script:

del "%systemdrive%\Documents and Settings\Administrator\Local Settings\Temp" /q
rd "%systemdrive%\Documents and Settings\Administrator\Local Settings\Temp" /s /q
del "%systemdrive%\Documents and Settings\Administrator\Local Settings\Temporary Internet Files" /q
rd "%systemdrive%\Documents and Settings\Administrator\Local Settings\Temporary Internet Files" /s /q
del "%userprofile%\Local Settings\Temp" /q
rd "%userprofile%\Local Settings\Temp" /s /q
mkdir "%userprofile%\Local Settings\Temp"
del %systemdrive%\Recycled\?*.* /q
rd %systemdrive%\Recycled /s/q
del %systemdrive%\Recycler\?*.* /q
rd %systemdrive%\Recycler /s/q
del "%userprofile%\Local Settings\Temporary Internet Files" /q
rd "%userprofile%\Local Settings\Temporary Internet Files" /s /q

defrag.exe %systemdrive% -f

The last line in this file also auto defrag's your PC

Good luck!

[jehuu_za]

Like I said.. Without deleting/removing the actual %temp% -directory and remaking it.

If I use the "del /f /s /q %TEMP%\*" it only deletes the files, not directories.
And if I use "rd /s /q %temp%\" it deletes also the %temp% -directory and i"rd /s /q %temp%\*" doesn't work.

Can't I do it without some kind of FOR-loop?

EDIT: I coud do "dir /a:d /b > file.txt" in %temp% and then make somekind of FOR-loop for reading the names of the directories from that file and then remove them one by one. But there must be a easier way to do this! Is there??

[rog]

What is the problem with deleting the folders? They will be recreated at the next logon!

[jehuu_za]

Couse our s***ty SOE..

[Yzöwl]

This line will remove any of the directories in %temp%

for /d %g in (%temp%\*) do rd /s /q %g

This line will remove the files in %temp%

del /s /q /f %temp%\*.*

Together in a batch

@echo off
for /d %%g in (%temp%\*) do rd /s /q %%g
del /s /q /f %temp%\*.*
goto :eof

[jehuu_za]

Thanks..will try it monday..

[sixpack]

Yzöwl, on Apr 29 2005, 10:23 AM, said:

This line will remove any of the directories in %temp%

for /d %g in (%temp%\*) do rd /s /q %g

This line will remove the files in %temp%

del /s /q /f %temp%\*.*

Together in a batch

@echo off
for /d %%g in (%temp%\*) do rd /s /q %%g
del /s /q /f %temp%\*.*
goto :eof

<{POST_SNAPBACK}>

@Yzöwl
how to use this line :

for /d %g in (%temp%\*) do rd /s /q %g

if the path hase a space like this:

for /d %g in (%windir%\Downloaded Installations\*) do rd /s /q %g

or will it work like this if i dont use "

edit:
second question
if i want to keep the cookies in "Temporary Internet Files" and delete the rest
how to do this in a batch file?

edit2:
if i use

for /d %%g in (%temp%\*) do rd /s /q %%g

the system cant find the path

[Yzöwl]

After a short PM exchange with sixpack, I thought I had better explain something.

The single line commands I gave are not for use in a batch file. They are to be entered into a command prompt window. If you haven't set your command prompt options for, right click paste and /or tab completion, you can also enter them into the Start » Run box after first typing 'cmd /c '

Now if you wish to test the file for what will be deleted, instead of possibly removing directories you didn't mean to using the Start » Run box as above, you will want to keep the window open, to see your results. To do this type 'cmd /k ' first, instead of 'cmd /c '. All I have added to the commands below is '@echo ', when your through with testing remove that and revert to the 'cmd /c ' prefix.

cmd /k for /d %g in (%temp%\*) do @echo rd /s /q "%g"

cmd /k for /d %g in ("%windir%\Downloaded Installations\*") do @echo rd /s /q "%g"

I hope this helps!

Additional note
I have also added something which I had omitted in my earlier examples, the quotes around the %g at the end, this will be necessary for any directories with spaces anywhere in their path names

[sixpack]

got it all to work now, thanks for your time Yzöwl

[gunsmokingman]

Here A Vbs That Will Clean Out Your Temp Files

Quote

On Error Resume Next
Dim ACTION : Set ACTION = CreateObject("WScript.Shell")
RmTmp = ACTION.ExpandEnvironmentStrings("%UserProfile%\Local Settings\Temp")
  Fso.Deletefile (RmTmp & "\*.*")
  Fso.deleteFolder (RmTmp & "\*")
  Fso.deletefolder ( RmTmp & "\*.tmp")

[bledd]

was about to post the list I created, but Erik Demon already has

[Yzöwl]

That as the questioner has already stated removes the Temp directory, which was a non requirement.
It seems like it's longer than it needs to be, for example

del "%systemdrive%\Documents and Settings\Administrator\Local Settings\Temp" /q

would remove only the files which aren't read only /hidden etc. and none of the subdirectories or their contents

rd "%systemdrive%\Documents and Settings\Administrator\Local Settings\Temp" /s /q

would remove the temp directory plus all its files subdirectories and contents. Surely just the second command would have done it all!
Don't get me wrong I am not criticizing your coding, it's just a little overcoded.

[staples]

Over coded

rd %temp%\. /q/s

on windows 2k forward this works.

[jehuu_za]

Quote

rd %temp%\. /q/s

Does remove the %temp% dir also, or did I use it wrong?

[Yzöwl]

The code I gave was more a step by step, learning thing, especially with the @echo additions to prevent accidental deletions.

I do not know when the questioner actually Edited their post either, otherwise I would have added this also

for /f "tokens=*" %A in ('dir /b/s/a:d "%Temp%"') do @echo rd /s/q "%~A"

That will also remove all the directories within your temp folder, without removing the Temp itself

<Edit>
Yes you are correct jehuu_za that does delete the %Temp% directory too!
</Edit>

This post has been edited by Yzöwl: 02 May 2005 - 09:32 AM

[staples]

Ok I found out "rd %temp%\. /q/s" on some windows xp it deletes %temp%.

to make it work you can fake it out by putting a log file in the location so the directory cannot be deleted.

Try this:

rd %temp%\. /q/s >%temp%\1.log

[Yzöwl]

@ staples
Whilst this is a very good idea, and one which would suffice in most cases, I still think it must be deleting and recreating the %Temp% directory. The reason I say this is that RD does not delete files, therefore the only way for those files to be deleted with that command is for the Temp directory to be removed and then remade for the log file to go inside. You would also of course now not have an empty Temp folder, meaning that in order to achieve the required result you would now have to issue a DEL command on the log file

Another method you could also use within your batch is pushd %Temp%, that'll put you inside the Temp folder, leaving it safe, then issue both the RD and DEL commands, (since as you can see from above, RD doesn't delete files), finally popd.

Incidentally, jehuu_za, why have you not commented on the method I originally gave as a working solution, or the vbs from gunsmokingman?
Here is a tidied version of my original response!

@echo off
for /d %%g in (%temp%\*) do rd /s/q "%%g"
del /f/q/a %temp%\*.*
goto :eof

[jehuu_za]

Quote

Incidentally, jehuu_za, why have you not commented on the method I originally gave as a working solution, or the vbs from gunsmokingman?
Here is a tidied version of my original response!

Sorry..I forgot to test it But now I have tested it and it works like a charm. Big thanks...I havent tested the .vbs couse the batch works fine.