Sign in to follow this  
Followers 0
soporific

Unattended and Updated Boot CD for Windows 98

48 posts in this topic

Hey there,

Some of us, for whatever reason, still have the need to re-install Windows 98. And we absolutely hate having to go through all the prompts, enter in the product keys, get the updates, etc. Wouldn't it be good to just stick the CD in and at the very end, have everything up-to-date? For Win98se this means:

1) a full upgrade of Internet Explorer to version 6 sp1

2) 26 'critical' system updates (some of them for IE6 sp1 which makes things tricky)

3) a DirectX update to 9.0c (but Microsoft doesn't officially allow silent installs for DX9)

4) install the basic programs you know you were going to install anyway, eg Office, etc.

Well, here's how you do it ...

This looks very intresting. I'll be giving it a shot soon, once I get all my updates

saved and ready for packaging. What I'd like to know is if it's possible to somehow

follow through with making 98SE2ME a part of this automation, and what the effects

of doing so would be on your updates? I mean, even if I just run the 98SE2ME

installer after installing 'normally' what effects does this have on my state of

updatednes? Do I need to start substituting the WinME versions of these updates?

More information would definately be appreciated!

--iWindoze

PS: Thanks for all the hard work you've obviously put into doing this;

then deciding to sahre it with the rest of us.

EDIT - added the missing 'thank you' PS:

to

Edited by iWindoze
0

Share this post


Link to post
Share on other sites

This is great reasearch by soporific and all of you!

Thanks for posting all the info :thumbup

0

Share this post


Link to post
Share on other sites

Hey prathapml, thanks for thanking us - we try our best ...

Thanks for redoing the first post, codeboxes rock! There's ONE thing, however:

There's an issue when using CODEBOX instead of CODE when posting code. In my autoexec.bat I've got some code that puts a bracket around C and also around R ie ( C ) and ( R ) (but without the spaces) but it gets changed to a copyright symbol (a symbol I find offensive) and the Registered (?) symbol. Is this a known issue? I would think not, as it doesn't happen when using CODE

I'll recreate the issue here to save you looking - Both code boxes should be identical, the only difference is the first code uses CODE and the second uses CODEBOX


©reate something or other
®eview the code for codebox

Edited by soporific
0

Share this post


Link to post
Share on other sites

Hi soporific,

Is there any chance you could link to a site with more information?

I know that there's a link to one such type site in your first post, but

that site seems more dedicated to the making of those 'Xin1' type

boot cds you see everywhere than on how to accomplish what you're

doing. I've tried several times to figure out what to so with your code

and there seems to be some mising information that while obvious to

you is baffling the 'eck out of me when I try to follow in your footsteps.

Could you post a directory structure? I can see from your posted code

that you expect :

<---ROOT

---------------UPDATES

-------------------------->DirectX

------------------------------------->DX9

--------IE6

--------mplayer

But where do the actual updates go, where is the WinSetup directory, ect?

As I've already asked in MGX's 98SE2ME topic, is it possible to pipe the

upgrade version (which I have) to look in a specific directory for Win3.x

and let it continue on from there? Where do the actual code files you've

provided go? With the exception of perhaps the autoexec.bat and config.sys

I'm lost!

Also, since I use Grisoft AVG Free and Firefox 1._insert number here_ myself

is it possible you could add that example of silent install back to the topic? Also,

just because I'm curious about such things, is it possible to use the MSBATCH.INF

file to selective not install IE5.x before upgrading to IE6SP1 or is it required to

be there as a dependancy?

Please, I need more information if I'm to try and follow in your footsteps here;

if its not possible to post here could you at least point me in the right directions?

--iWindoze

PS Thanks again for sharing with us as much as you have!

0

Share this post


Link to post
Share on other sites
Is there any chance you could link to a site with more information?

[snip]

Please, I need more information if I'm to try and follow in your footsteps here;

if its not possible to post here could you at least point me in the right directions?

--iWindoze

PS Thanks again for sharing with us as much as you have!

Yep OK give me a day to write some more detail - I do agree that the link to the site I posted doesn't totally help you out - I'll make sure I fill in all the gaps ...

Probably the most trouble I had was getting the boot image to work. The best solution would be for me to upload a package containing all the legally distributable files that I use. I have no idea if this board has a provision for that, or maybe someone can kindly host it for everyone ... I'll check for myself after I post, but if there's anyone that can host a file that's probably going to be under 5 MB can they speak up now (or forever hold their peace).

At the very least, I'll post more info on CD structure and application switches very soon, so stay tuned !!

Edited by soporific
0

Share this post


Link to post
Share on other sites
:hello: how bout just the batch inf with the eula and product key popups hidden that be sweet cause a o instead of a 1 doesnt work and attach batch 98 inf here.plz
0

Share this post


Link to post
Share on other sites
:hello: how bout just the batch inf with the eula and product key popups hidden that be sweet

cause a o instead of a 1 doesnt work and attach batch 98 inf here.plz

It has already been posted in THIS thread. Read soporific's 1st article and have a look at the OPKInstall section ... :no:

0

Share this post


Link to post
Share on other sites
:hello: how bout just the batch inf with the eula and product key popups hidden that be sweet

cause a o instead of a 1 doesnt work and attach batch 98 inf here.plz

It has already been posted in THIS thread. Read soporific's 1st article and have a look at the OPKInstall section ... :no:

Yes, and as has been pointed out before its simply not ENOUGH information.

I'd rather he post a small zip file containing ALL his files (with edits at the points

where serial numbers would be, along with a more comprehensive directory

description than what has been provided, than the heaviliy edited listing we

have now. I have no issues with doing research or slagging through stuff to

find info; however like others I see no reason to play needle in a haysack

when someone stands by with the required information at hand. All that Timeless

has said is that (like others) he's not been able to get these instructions to work

and he included the obligatory no warez\serialz being asked for disclaimer.

I've no doubt that soporific will get around to posting more info once he's had a

chance, but don't see any point in putting people down just for asking for updates.

--iWindoze (who waits patiently despite checking in with this topic whenever

he's online...on the two and a half days a week he has internet access.)

0

Share this post


Link to post
Share on other sites
:hello: hey windose what i really want is the batch inf with just the eula and popup elimated i can do the rest i did a batch but the eula and prompt 4 key comes up if u could included the code into batch nothing else maybe no msn icon it would be great.thz in advance. Edited by timeless
0

Share this post


Link to post
Share on other sites

Welcome to version 2 of this project. I've only just finished it and I would normally take my time to compile a post due to the complexity of providing a lot of information, but it seems there's a few people hanging out for the solution, so here you go ... this post is a bit over the place, I'll fix it up tomorrow after some sleep - its the middle of the morning and quite freezing ---- most of you are going 'huh?'

What's different (briefly for now, more detail after some sleep):

* The installation files now get copied to the hard drive and are then used to perform the installation. The 2 reasons are: * to allow for unlimited choices of installation components and applications, * the bug in Windows 98 where the CD drive is unaccessible while a hardware installation is occurring thus preventing access to Windows setup files. This only happens rarely but it p***es me off when it happens and the way around it is to have the setup files on the hard disk.

- the downside of this is that for some reason, windows setup can't see the CD drive when MSBATCH.INF is running the application installs that are listed in the RUNONCESETUP section. So the workaround is to copy those files to the hard disk first as well. Does anyone know about this issue?

* I've included the core of the 98 to Me update. The files updated are: USER32.DLL, USER.EXE, and Explorer.exe

* My CD boot menu now offers the choice to install the updated Lite version with only the very basic extra apps (like the must must must have Firefox browser) or the full super duper version with all the apps. To achieve this easily, during the execution of AUTOEXEC.BAT I change the version I want to select (in my case @batch-a.inf or @batch-u.inf) and rename it to MSBATCH.INF. I have only provided the link for one of the boot images so you'll need to make your own 98ue.ima. You do this by duplicating 98ae.ima, extracting the autoexec.bat, and editing it at all instances of @batch-a.inf (change it to @batch-u.inf). If you don't want to do this, change your cdshell.ini file accordingly.

The rest of the differences are minor (I think, things are getting a bit hazY)

instructions:

1) Make sure you have or do all of the following:

* Windows 98 second edition operating system files with a product key that works. I don't know if this will work for the original edition.

* All the windows updates from Microsoft's Downloads page.

* These (A & B) downloads courtesy of mdgx which are the core of the 98 2 Me update

* SUFFICIENT drive space (2+ GB to be safe)

* Enable "Show Hidden Files & Folders", Disable "Hide extensions for known file types", Disable "Hide protected operating system files (Recommended)"

* WinImage 6.10

* Hex Workshop 4.23

* CDIMAGE 2.47

* CD Shell 2.0.16

* My boot image file

* My directory structure

* Highly recommended (but optional): - Daemon Tools 3.47 (virtual cd/dvd-rom emulator)

* Highly recommended (but optional): - VMware Workstation 4.0.5 or Virtual PC 2004

* A CD burning program like Nero.

2) Create the following directory structure starting at 98BootCD (the root folder):

SShot01.jpg

3)

* Install WinImage and your hex editor.

* Extract the CD Shell files into your structure as thus:

SShot04.jpg

This is my cdshell.ini


boot:
cls
print "\n"
print "\n"
print "Press Enter to boot from CD ... \n"
getkey 5 boot 0x80
if $lastKey == key[enter]; then goto menu
if $lastKey == key[esc]; then boot 0x80
# When no key found...
goto boot

# Printing the Interface
menu:
set textColor= color[grey on black]
set boldColor= color[cyan on black]
cls
print c "\ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ \n"
print c "\ Windows 98 Fully Updated & Unattended Installation Boot CD v1.0\n\n"
print c "\ by soporific <a_good_soporific@hotmail.com> \n"
print c "\ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ \n"
set textColor= color[cyan on black]
print "1) Basic version of Windows 98 Fully Updated Edition \n"
print "2) Lite version of Windows 98 Fully Updated Edition \n"
print "3) Full version of Windows 98 Fully Updated Edition \n"
print "\n"
print "P) Partition Magic 8 \n"
set textColor= color[grey on black]
print "Q) Quit to Command Prompt \n"
print "R) Reboot \n"
print "ESC) Boot 1st Harddisk \n"
print c "\n"
set textColor= color[cyan on black]
print "The hard disk will automatically boot in 30 seconds ... \n"

MainKey:
getkey 30 boot 0x80
if $lastKey == key[1]; then memdisk /98se.IMA
if $lastKey == key[2]; then memdisk /98ue.IMA
if $lastKey == key[3]; then memdisk /98ae.IMA
if $lastKey == key[p]; then memdisk /pmagic8.IMA
if $lastKey == key[q]; then end
if $lastKey == key[r]; then reboot
if $lastKey == key[F1]; then goto Help
if $lastKey == key[esc]; then boot 0x80
end

As for where the rest of the stuff goes, the code is actually VERY explicit about this. Really, is a simple method of deductive reasoning to match up where to put which file into what directory. But, because I know its hard enough keeping sane from all the lies on TV ... here's a break from extra thinking:

SShot02.jpg

and

SShot03.jpg

4) Explanations for all the new code and method and everything else under the sun will be added when I've had some sleep. I'll write a short bit now, but more in depth reasoning in about 6 hours.

5) Here's some of the code ... I can't finish it all tonight, so here's what I've done so far, just grab this zip file for all the code files I use.

Config.sys


[menu]
menucolor=7,0
menuitem=G_DISK,Enter the GDISK Menu to partition your drives
menuitem=FOR_MAT,Auto format drive C: then Auto install Windows 98 second edition
menuitem=SETUP_CD,Auto Install Windows 98 superduper fully updated edition
menudefault=SETUP_CD,37

[CD_ONLY]
device=himem.sys /testmem:off
device=oakcdrom.sys /D:mscd001
device=btdosm.sys
device=flashpt.sys
device=btcdrom.sys /D:mscd001
device=aspi2dos.sys
device=aspi8dos.sys
device=aspi4dos.sys
device=aspi8u2.sys
device=aspicd.sys /D:mscd001

[G_DISK]
device=himem.sys /testmem:off
device=oakcdrom.sys /D:mscd001
device=btdosm.sys
device=flashpt.sys
device=btcdrom.sys /D:mscd001
device=aspi2dos.sys
device=aspi8dos.sys
device=aspi4dos.sys
device=aspi8u2.sys
device=aspicd.sys /D:mscd001

[SETUP_CD]
device=himem.sys /testmem:off
device=oakcdrom.sys /D:mscd001
device=btdosm.sys
device=flashpt.sys
device=btcdrom.sys /D:mscd001
device=aspi2dos.sys
device=aspi8dos.sys
device=aspi4dos.sys
device=aspi8u2.sys
device=aspicd.sys /D:mscd001

[FOR_MAT]
device=himem.sys /testmem:off
device=oakcdrom.sys /D:mscd001
device=btdosm.sys
device=flashpt.sys
device=btcdrom.sys /D:mscd001
device=aspi2dos.sys
device=aspi8dos.sys
device=aspi4dos.sys
device=aspi8u2.sys
device=aspicd.sys /D:mscd001

[COMMON]
switches=/F
break=on
files=40
buffers=20
dos=high,umb
stacks=9,256
lastdrive=z

autoexec.bat


@ECHO OFF
set EXPAND=YES
SET DIRCMD=/O:N
cls
set temp=c:\
set tmp=c:\
path=%CDROM%:\;a:\

IF "%config%"=="G_DISK" goto GDISKMENU
IF "%config%"=="SETUP_CD" goto AUTOSETUP
IF "%config%"=="FOR_MAT" goto AUTOFORMAT
echo. Well that was weird. You shouldn't see this ... (error 1)
goto QUIT

:AUTOFORMAT
LH MSCDEX.EXE /D:mscd001 /L:%CDROM%
set CDROM=FOO23
FINDCD.EXE
if "%CDROM%"=="FOO23" goto NOCDROM
%CDROM%:
echo.
echo (Q)uick format, (F)ull format, or (S)top everything
echo.
echo Quick format will default in 5 seconds ...
echo.
choice /c:qfs /n /t:q,5 > NUL

if errorlevel 4 goto ERROR
if errorlevel 3 goto QUITDOS
if errorlevel 2 goto FFORMAT
if errorlevel 1 goto QFORMAT
echo. Well that was weird. You shouldn't see this ... (error 2)

:QFORMAT
echo QUICK formating drive C: ...
echo.
%CDROM%:
choice /c:d /n /t:d,1 > NUL
format c: /q /autotest /u
goto CFORMAT

:FFORMAT
echo FULL formating drive C: ...
echo.
%CDROM%:
choice /c:d /n /t:d,1 > NUL
format c: /autotest /u

:CFORMAT
echo.
echo format complete.
goto STARTSETUP

:AUTOSETUP
LH MSCDEX.EXE /D:mscd001 /L:%CDROM%
set CDROM=FOO23
FINDCD.EXE
if "%CDROM%"=="FOO23" goto NOCDROM
%CDROM%:
IF EXIST c:\setuptip.txt goto NODRIVE >NUL
IF NOT ERRORLEVEL 0 goto ERROR

:STARTSETUP
IF EXIST c:\Win98 goto KOPYFILES
choice /c:d /n /t:d,2 > NUL
echo.
echo Now creating setup files directory ...
echo.
choice /c:d /n /t:d,3 > NUL
IF NOT EXIST C:\Win98\nul MD C:\Win98
echo C:\Win98 has been created
choice /c:d /n /t:d,1 > NUL
IF NOT EXIST C:\TempFile\nul MD C:\TempFile
echo.
echo C:\TempFile has been created
choice /c:d /n /t:d,1 > NUL
echo.
echo ... All done.
choice /c:d /n /t:d,3 > NUL

:KOPYFILES
echo.
IF EXIST C:\TempFile\ACROBAT\ACROBAT5.EXE goto KGOING
echo.Now copying installation files to the hard drive ...
echo.
IF EXIST D:\setuptip.txt XCOPY32 D:\files c:\TempFile /E /Y
IF EXIST E:\setuptip.txt XCOPY32 E:\files c:\TempFile /E /Y
IF EXIST F:\setuptip.txt XCOPY32 F:\files c:\TempFile /E /Y
IF EXIST G:\setuptip.txt XCOPY32 G:\files c:\TempFile /E /Y
IF EXIST H:\setuptip.txt XCOPY32 H:\files c:\TempFile /E /Y
IF NOT EXIST C:\TempFile\ACROBAT\ACROBAT5.EXE goto NOFILES
echo.
echo All files under C:\TempFile will be automatically deleted at the very end of setup.
echo.
echo They can all be easily found on the CD if needed.
choice /c:d /n /t:d,3 > NUL

:KGOING
IF EXIST C:\Win98\Setup.exe goto RSTART
echo Now copying installation files to the hard drive ...
echo.
choice /c:d /n /t:d,3 > NUL
IF EXIST D:\setuptip.txt COPY D:\win98\*.* c:\Win98
IF EXIST E:\setuptip.txt COPY E:\win98\*.* c:\Win98
IF EXIST F:\setuptip.txt COPY F:\win98\*.* c:\Win98
IF EXIST G:\setuptip.txt COPY G:\win98\*.* c:\Win98
IF EXIST H:\setuptip.txt COPY H:\win98\*.* c:\Win98
IF EXIST C:\Win98\Setup.exe goto RSTART
echo.
echo uh oh, something went wrong again ... can't find the setup files. This means ...
echo.
choice /c:d /n /t:d,3 > NUL
echo Sorry, can't continue ... quitting to DOS. Good luck!!
GOTO QUIT

:RSTART
echo Setup files now exist on the hard drive in C:\Win98
choice /c:d /n /t:d,1 > NUL
echo.
echo Please keep them there for future application installations
choice /c:d /n /t:d,3 > NUL
echo.
echo Renaming @batch-u.inf to msbatch.inf
choice /c:d /n /t:d,3 > NUL
REN C:\Win98\@batch-u.inf msbatch.inf
echo.
echo ...Done.
choice /c:d /n /t:d,3 > NUL
IF NOT EXIST C:\Win98\msbatch.inf goto NOINF
echo.
echo.Now installing Windows 98 fully updated edition ...
echo.
C:\Win98\SETUP.EXE /ie /is /nf /nm /nr
goto QUIT

:NOINF
echo The rename didn't work
goto QUIT

:NOFILES
echo The extra application setup files didn't seem to copy ... wanna continue with Windows setup anyway?
echo.
echo. Y or N? (No will default in 10 seconds)
choice /c:ny /n /t:n,10 > NUL

if errorlevel 3 goto ERROR
if errorlevel 2 goto KGOING
if errorlevel 1 goto QUITDOS
echo. Well that was weird. You shouldn't see this ... (error 2)
goto QUIT

:NOCDROM
echo.
echo The Windows 98 Setup files were not found.
echo The CD or CD Drive may be damaged or an unforseen issue has occurred - try rebooting at least once
echo You may be able to access the CD drive ...
echo If so, run setup.exe X:\msbatch.inf (where 'X' is the letter of your cd drive)
GOTO QUIT

:NODRIVE
echo.
echo No disk partitions were found.
echo.
echo Either your hard drive(s) are not connected properly, or not yet partitioned.
echo.
goto MENUONLY

:GDISKMENU
LH MSCDEX.EXE /D:mscd001 /L:%CDROM%
set CDROM=FOO23
FINDCD.EXE
if "%CDROM%"=="FOO23" goto NOCDROM
%CDROM%:

:MENUONLY
echo.
echo Please choose one of the following:
echo.
echo. ©reate & activate a primary partition using the entire 1st hard drive ... C
echo. - this will reboot the computer afterwards
echo.
echo. (D)isplay the computer's current physical hard drive(s) status .............D
echo. - only the first disk information will display. Use FDISK for others
echo.
echo. (Q)uit to DOS with CD-ROM support ......................................... Q
echo.
echo. ®eboot the computer ..................................................... R
echo.
choice /c:qrdc /n " Please choose: " >NUL

if errorlevel 4 goto CREATE
if errorlevel 3 goto DISPLAY
if errorlevel 2 goto REEBOOT
if errorlevel 1 goto QUITDOS
echo. Well that was weird. You shouldn't see this ... (error 3)
goto QUIT

:CREATE
echo.
Choice /c:yn " Are you sure you want to continue? "
if errorlevel 2 goto MENUONLY
gdisk 1 /cre /pri /for /y
echo.
echo ... partition created and set active.
choice /c:delay /n /t:d,5 > NUL
goto REEBOOT

:DISPLAY
%CDROM%:
echo.
gdisk 1
echo.
PAUSE
cls
goto MENUONLY

:REEBOOT
reboot.com
goto QUIT

:QUITDOS
%CDROM%:

:QUIT
Set CDROM=

** UPDATE **** UPDATE **** UPDATE **** UPDATE **** UPDATE **** UPDATE **

The @Update1.bat file included in the zip file is wrong - here is the correct code:


@echo off

:INITIALISE
SET SC=Update Pack 1
SET SN=Update Pack 2
SET SD=@DoUpd2.reg
SET SE=@Update2.bat
SET TA=30
SET TC=10
SET WD=c:\win98
FOR %%Z IN (D E F G H I J) DO IF EXIST %%Z:\setuptip.txt SET CDROM=%%Z:

:PRESETUP
echo.
echo. %SC% will automatically start in %TA% seconds
REM | choice /c:delay /n /s /T:c,2 >NUL
echo.
echo. As as July 24 2005 there are 26 critical and security updates to install ...
echo.
echo. These will be installed in 3 stages with the computer
echo. rebooting after each one has finished. Please be patient ...
REM | choice /c:delay /n /s /t:d,2 >NUL
echo.
echo.
echo. C to Continue now and start %SC%
echo. Q to stop everything
echo.
Choice /c:qc /n /t:c,%TC% >NUL
echo.
IF ERRORLEVEL 3 GOTO ERROR
IF ERRORLEVEL 2 GOTO SETUP
IF ERRORLEVEL 1 GOTO CLEANUP
goto ERROR

:SETUP
echo. Now installing %SC% ...
REM | Choice /c:c /n /t:c,2 >NUL
echo.
for %%P in (KB811630 KB896358 KB888113 KB891711 KB891781 KB823559 q329115 q323172 q323255 q259728 q245729 q313829 q256015 q238453) DO START /W %WD%\@Install.bat %%P
IF NOT ERRORLEVEL 0 GOTO ERROR
echo.
echo. ... all done.
REM | Choice /c:c /n /t:c,2 >NUL
echo.

:QUITMENU
echo. %SC% has ended. The system will automatically reboot in %TC% seconds
echo.
echo. C to Continue now
echo. Q to Quit rebooting and stop everything
echo.
Choice /c:qcb /n /t:c,%TC% >NUL
IF ERRORLEVEL 4 GOTO ERROR
IF ERRORLEVEL 3 GOTO RBOOT
IF ERRORLEVEL 2 GOTO CONTINUE
IF ERRORLEVEL 1 GOTO CLEANUP
goto ERROR

:CONTINUE
echo.
echo. Now adding %SD% to the registry ...
REGEDIT /S %WD%\%SD%
IF NOT ERRORLEVEL 0 GOTO ERROR
echo.
echo. ... done.
REM | Choice /c:c /n /t:c,2 >NUL
echo.
echo. %SE% will run on next boot ...
echo.
REM | Choice /c:c /n /t:c,2 >NUL
goto RBOOT

:BYPASS
echo.
echo. Now starting %SE% ...
echo.
SET SC=
SET SN=
SET SD=
SET TA=
SET TC=
SET CDROM=
START %WD%\%SE%
SET SE=
SET WD=
cls
exit
goto END

:ERROR
echo. An unexpected error has occurred ... aborting automatic installation.
PAUSE

:CLEANUP
SET SC=
SET SN=
SET SD=
SET SE=
SET TA=
SET TC=
SET WD=
SET CDROM=

:QUIT
cls
exit
goto END

:RBOOT
SET SC=
SET SN=
SET SD=
SET SE=
SET TA=
SET TC=
SET CDROM=
START %WD%\@Reboot.bat
SET WD=
cls
exit

:END

Edited by soporific
0

Share this post


Link to post
Share on other sites

Soporific:

Excellent work. Keep it up. B)

Most important ["interesting"] SYSTEM.INI settings with explanations:

http://www.mdgx.com/lastweek.htm#SYSINI

That's where lines above were [probably] taken from anyway. ;)

Text=xxx does not exist, [probably] copied + pasted from a misspelled web page/text file.

VGAMonoText=OFF / ON proper spelling is without any spaces.

MSBATCH.INF, HHW SDK, IE6 SP1 IEAK, IDK, OPK + related tools + help files links [including Soporific's thread]:

http://www.mdgx.com/add.htm#DEV

Some VB scripts [*.VBS files or VBScript scripts imbedded into HTML files] can be run from a DOS box by using CSCRIPT.EXE [therefore before loading entire GUI, but after loading minimal Win32 APIs; in some cases VBS can be run from native MS-DOS mode (outside Windows) if loading DOSLFN ( http://www.geocities.com/jadoxa/doslfn/ ) as a TSR (eventually from autoexec.bat or config.sys) before running such scripts], the DOS console counterpart of Windows based WSCRIPT.EXE. WMI is not necessarily needed for some VBS scripts, especially the ones that can be run by CSCRIPT.EXE.

CSCRIPT.EXE is installed by default into %windir%\COMMAND [please note that certain 98lite options delete completely %windir%\COMMAND + all files in it].

Newest version of MS Scripting APIs:

http://www.mdgx.com/add.htm#MSE

To learn about VBScript, best place to start is MSDN:

http://msdn.microsoft.com/scripting/

Best tool that uses VBS for its plugins [XPL (plain text) files can be opened in Notepad for viewing] is X-Setup Pro [7.1 is shareware but older 6.6 is freeware]:

http://www.mdgx.com/toy.htm#SYS

Some of these DOS based memory tools may be used in batch files to tell installed memory amount [all free(ware)], without using VBS:

http://www.mdgx.com/dos.htm

http://www.mdgx.com/umb.htm

Alternatives to HexWorkShop [mostly free(ware)]:

http://www.mdgx.com/toy.htm#HEX

Try not to use c:\windows as hard-coded string in your batch/inf/etc files, because may not work on computers where user has installed it in a different folder, or even different drive/partition.

Best to use %winbootdir% variable instead, which works in both Windows GUI + native MS-DOS 7/8 [a.k.a. Win95/98/ME OS] mode.

Soporific:

If u like, I can host your files at my site, please let me know if u are interested.

E-mail

Hope this helps.

Edited by MDGx
0

Share this post


Link to post
Share on other sites
:thumbup i use the info in your code zip and finally made a unattented full cd i left out the extra appz at this time but thank you muchly sophoric excellent stuff u rock. Edited by timeless
0

Share this post


Link to post
Share on other sites

I'm going to try and create one of these, just for nostalgic value (same reason why I browse this forum). Thanks for Version 2.0, as it seems to be a LOT easier (Pictures are very helpful!)

Edit: I've got everything I wanted in the CD, and I'm currently burning an image to test in VMWare... I hope it works... if not, no worries... all the instructions aren't here yet, so I'm just winging a LOT of it. ;)

Edited by jimmsta
0

Share this post


Link to post
Share on other sites

Really strange problem - for some reason or another, the setup wouldn't take my 100% Legit key. I'm guessing some modification may have caused the install to think that it's an OEM copy of 98SE, and not a Retail copy. I pulled an OEM key off one of my old computer manuals, which worked. The key I originally tried to use is from a Retail copy of Win98SE Full - "for PCs without Windows".

Any ideas?

0

Share this post


Link to post
Share on other sites

Hey everyone, thanks to all for keeping this thread growing ... especially you, MDGx. I'll be posting the full, final version of this project (version 2.1) in a few days but there aren't any major changes just a mega clean up of the code.

Really strange problem - for some reason or another, the setup wouldn't take my 100% Legit key. I'm guessing some modification may have caused the install to think that it's an OEM copy of 98SE, and not a Retail copy. I pulled an OEM key off one of my old computer manuals, which worked. The key I originally tried to use is from a Retail copy of Win98SE Full - "for PCs without Windows".

My version IS an OEM version so that's probably significant in this case. One way around it, definitely, it to do a clean install with the retail version, and then use the batch98 utility to make a msbatch.inf file, and use THAT msbatch.inf as your base and add the extra sections to it then to make it unattended and updated.

I think I know what the problem is, though. As my intro to version 1 was saying about being able to skip the EULA stage even though its an OEM version, this hack IS FOR an oem version, so maybe its not going to work for the retail version. Maybe try this: take out the OPKInstall section from my msbatch.inf, and just click thru the EULA step and see if that at least works because it should and we would then have narrowed down the problem

I really didn't say so in my previous posts, but 99% of my initial work in this project was just surfing around for a few days, bringing all my google skills into practice searching for the answers to particular problems. What I'm saying is that I remember in my travels coming across a post (on msfn I think) that talked about this issue and is where I got my info from about the Retail vs the OEM. I'll have another look for it, but you might want to do the same. I'll post the info if I find it.

Edited by soporific
0

Share this post


Link to post
Share on other sites

Create an account or sign in to comment

You need to be a member in order to leave a comment

Create an account

Sign up for a new account in our community. It's easy!


Register a new account

Sign in

Already have an account? Sign in here.


Sign In Now
Sign in to follow this  
Followers 0

  • Recently Browsing   0 members

    No registered users viewing this page.