Welcome to MSFN

Register now to gain access to all of our features. Once registered and logged in, you will be able to contribute to this site by submitting your own content or replying to existing content. You'll be able to customize your profile, receive reputation points as a reward for submitting content, while also communicating with other members via your own private inbox, plus much more! This message will be removed once you have signed in.


geitonaki

Automatically create multi-boot folders and files

31 posts in this topic

Edit: New version.

You can automatically create the multi-boot folders and files using my batch file for any version of Windows 2000, XP, 2003. Everything needed is included in the file I have uploaded.

File attached so people don't need to wait for RapidShare's download ticket ~ Alanoll

Here I will post only the main batch file:

create_boot_folder.cmd


@echo off
if [%1] == [] goto :usage
if [%2] == [] goto :usage
if [%3] == [] goto :usage
if [%4] == [] goto :usage
if [%5] == [] goto :usage
if not [%6] == [] goto :usage
if not exist "%~f1" (
echo Directory "%~f1" does not exist.
goto :usage
)
if not exist "%~f2" (
echo Directory "%~f2" does not exist.
goto :usage
)
if exist "%~f2\%3" (
echo "%~f2\%3" already exists so nothing to do, please delete it manually
goto :end
)

set pth=%~f1
set aio=%~f2
call set pth=%%pth:%aio%=%%
if "%pth%" == "%~f1" (
echo "%~f1" must be under "%~f2".
goto :end
)

if exist "%1\I386\TXTSETUP.SIF" (
set src_dir=%1\I386
set dest_dir=%2\%3
set archit=I386
) else if exist "%1\AMD64\TXTSETUP.SIF" (
set src_dir=%1\AMD64
set dest_dir=%2\%4
set archit=AMD64
) else (
echo Cannot find TXTSETUP.SIF in I386 or AMD64 in %1
)

type "%src_dir%\TXTSETUP.SIF" | findstr /r ",_[1-9] ,[1-9]_" | sed -e s/"=.*"/""/g -e s/" .*"/""/g > out.txt
type out.txt | sed -e s/".$"/"_"/g > out_.txt

mkdir "%dest_dir%"

for /f %%i in ('type out.txt') do copy "%src_dir%\%%i" "%dest_dir%" > nul 2>&1
for /f %%i in ('type out_.txt') do copy "%src_dir%\%%i" "%dest_dir%" > nul 2>&1

copy "%src_dir%\BOOTFONT.BIN" "%dest_dir%" > nul 2>&1
copy "%src_dir%\BOOTFONT.BIN" "%2" > nul 2>&1

mkdir "%dest_dir%\SYSTEM32"
copy "%src_dir%\system32\*.*" "%dest_dir%\SYSTEM32" > nul 2>&1

set pth=%pth:\=\\%
type "%src_dir%\TXTSETUP.SIF" | sed -e s/"SetupSourcePath = \""/"SetupSourcePath = \"%pth%"/g > "%dest_dir%\TXTSETUP.SIF"
unix2dos "%dest_dir%\TXTSETUP.SIF"

del "%dest_dir%\NTDLL.DLL" > nul 2>&1

if "%archit%" == "AMD64" (
mkdir "%2\%3"
copy "%1\I386\NTDETECT.COM" "%2\%3" > nul 2>&1
)

if "%5" == "1" (
copy SETUPLDR.BIN "%2\%3" > nul 2>&1
) else (
copy "%1\I386\SETUPLDR.BIN" "%2\%3" > nul 2>&1
)
start /w xvi32.exe "%2\%3\SETUPLDR.BIN" /S=replaceI386.xsc "%3"
if "%archit%" == "AMD64" (
start /w xvi32.exe "%2\%3\SETUPLDR.BIN" /S=replaceAMD64.xsc "%4"
)

copy BOOT.BIN "%2\%3.bin" > nul 2>&1
start /w xvi32.exe "%2\%3.bin" /S=universalrepl.xsc "I386" "%3"

del OUT.txt > nul 2>&1
del OUT_.txt > nul 2>&1

copy "%1\CDROM*.*" "%2"\ > nul 2>&1
copy "%1\WIN51*.*" "%2"\ > nul 2>&1

goto :end

:usage
echo Usage: %~n0 setup_dir aio_dir boot_dir1 boot_dir2 flag_for_using_cracked_setupldr
goto :end

:end

Edit: New version so that you don't need to subst your aio-dvd dir anymore.

File attached ~ Alanoll

Create_MultiBoot_Folders_And_Files.zip

Edited by Alanoll
0

Share this post


Link to post
Share on other sites

how does it work? do we just put it in the root of the installation folder?

0

Share this post


Link to post
Share on other sites

Download the self extracting rar file in the first post, execute it and it will ask where to install. Browse to your AIO-DVD folder. When finished it will create #TOOLS in there, open create_boot_folders.cmd which calls create_boot_folder.cmd, modify it in your needs and execute it.

It will create the boot folders, modify setupldr.bin, modify txtsetup.sif, create the boot sector and copy the tag files. Everything described in http://flyakite.msfnhosting.com/ for Windows 2000/XP/2003 is made automatically B). Doesn't this topic deserve to be sticky :)?

@amd64lover

please give us feedback for 64bit version of windows since I don't have an amd64 to test, but I am pretty sure that everything should be fine.

Edited by geitonaki
0

Share this post


Link to post
Share on other sites

@geitonaki

the 64bit installed PERFECTLY!!! i used your method to disable the checksum and created XP64 & PRO64 folders and everything worked great. i will try your batch file and see how it works. thanks

Edited by amd64lover
0

Share this post


Link to post
Share on other sites

Say, I don't suppose this'll work for Redhat would it? I'm gonna try it out anyway, just wanted to ask.

0

Share this post


Link to post
Share on other sites
Say, I don't suppose this'll work for Redhat would it? I'm gonna try it out anyway, just wanted to ask.

No it won't. As I said it works for any version of Windows 2000, XP, 2003

0

Share this post


Link to post
Share on other sites

That's the second file of yours I've attached so people don't have to go to that dreadful site...

I'll try this later on...

But as for the sticky...I do believe a random suggestion in a post does nothing. Let alone one for your OWN topic. It's just not really polite in all honesty.

I'll unsticky the old thread, but there really isn't any need for this to be a sticky, or the other page. They're still on the first page of the forum, and a simple search should bring these up.

0

Share this post


Link to post
Share on other sites
That's the second file of yours I've attached so people don't have to go to that dreadful site...

Having 150kb limit for each post how could I uploaded here? My only option was to upload to rapidshare.de

0

Share this post


Link to post
Share on other sites

That's the second file of yours I've attached so people don't have to go to that dreadful site...

Having 150kb limit for each post how could I uploaded here? My only option was to upload to rapidshare.de

whoops, guess I should have adde the :P smiley so you know I wasn't trying to say you did something wrong. Next time though, if you need something attached, you could just send it to me and I'll upload and attach it to yourpost.

0

Share this post


Link to post
Share on other sites

the create_boot_folders.cmd code doesn't work for me...

return code:

Usage: create_boot_folder setup_dir boot_dir1 boot_dir2 flag_for_using_cracked_setupldr

0

Share this post


Link to post
Share on other sites

Make sure you are running create_boot_folders.cmd and not create_boot_folder.cmd

Also read carefully the included help.

0

Share this post


Link to post
Share on other sites

Just a quick question now. I have been looking through the posts and the files and had a play but i just can't seem to get my head around the coding in create_boot_folders.cmd

I just seem to get the same message as hardlocke did.

Could someone please post a working copy so i can get a better handle on it.

Much appriciated.

0

Share this post


Link to post
Share on other sites

That's the second file of yours I've attached so people don't have to go to that dreadful site...

Having 150kb limit for each post how could I uploaded here? My only option was to upload to rapidshare.de

Rapidshare.de actually changed their method of downloading, you just gotta type in the Verify code, and you get the download now. :thumbup

0

Share this post


Link to post
Share on other sites
Just a quick question now. I have been looking through the posts and the files and had a play but i just can't seem to get my head around the coding in create_boot_folders.cmd

I just seem to get the same message as hardlocke did.

Could someone please post a working copy so i can get a better handle on it.

Much appriciated.

I have uploaded a new version, check it out and post how it worked for you, the syntax is now:

Usage: create_boot_folder setup_dir aio_dir boot_dir1 boot_dir2 flag_for_using_cracked_setupldr

You have to open create_boot_folders.cmd with notepad, modify the included examples and then run it by double clicking the file

0

Share this post


Link to post
Share on other sites

All righty man. I just did a basic test of your multi-boot dvd prog. It created the the boot stuff perfectly. Since I don't have an x64 rig, I can only test out the cracked setupldr.bin via server2003. I'll post results later. So far so good man. You've done an awesome job!

0

Share this post


Link to post
Share on other sites

i addthis

copy "%src_dir%\WINNT.SIF" "%dest_dir%" > nul 2>&1

Edited by zuma
0

Share this post


Link to post
Share on other sites

First of all I'd like to say 'Great Job!' with the coding for this! :)

I also wanted to bring up that I have been having some issues trying to get this to work with BTS's Driver Packs. When I select my boot source after Text setup the system reboots & tries to load BTS files, but fails because it can't find the \OEM\BIN folder (not $OEM$). If I copy the entire OEM folder to the root of the AIO disk it works with no issues. The only drawback is that I am doing an AIO with each containing different files from BTS packs. (ex: 1 w/ LAN, 1 w/LAN, SATA and so on).

Ex. DIR Structure:
***non-working***
$OEM$
Setup
-English
----WINXP
--------Original
------------I386
------------OEM

***Working*** (moved OEM to root)
$OEM$
Setup
OEM
-English
----WINXP
--------Original
------------I386
------------OEM

can anyone help me to make my AIO point eich to their respective OEM folder, instead of only looking for OEM in the root of the drive?

Thanks

0

Share this post


Link to post
Share on other sites
can anyone help me to make my AIO point eich to their respective OEM folder, instead of only looking for OEM in the root of the drive?

Thanks

You need to modify all BTS scripts that use the directory OEM. (e.g. in I386\PRESETUP.CMD change OEM to anything you want)

Edited by geitonaki
0

Share this post


Link to post
Share on other sites

Hi guys.. I'm loving this batch file... If I could only figure out what this error means...

Creating multi-boot folders and files, it will take some time...
sed: -e expression #1, char 65: Unterminated `s' command
The process tried to write to a nonexistent pipe.
sed: -e expression #1, char 65: Unterminated `s' command
The process tried to write to a nonexistent pipe.
sed: -e expression #1, char 65: Unterminated `s' command
The process tried to write to a nonexistent pipe.
sed: -e expression #1, char 65: Unterminated `s' command
The process tried to write to a nonexistent pipe.
sed: -e expression #1, char 65: Unterminated `s' command
The process tried to write to a nonexistent pipe.
sed: -e expression #1, char 61: Unterminated `s' command
The process tried to write to a nonexistent pipe.
sed: -e expression #1, char 60: Unterminated `s' command
The process tried to write to a nonexistent pipe.
If you don't see any error message above then everything should be ok, but please check.
Press any key to continue . . .

Can anyone help?

here's the create_boot_folders.cmd source

@echo off


rem Change the following lines having this in mind:
rem call create_boot_folder.cmd setup_dir aio_dir boot_dir1 boot_dir2 flag_for_using_cracked_setupldr
rem
rem setup_dir: where the setup files are
rem aio_dir: where your aio folder is
rem boot_dir1: must be 4-characters long
rem boot_dir2: must be 5-characters long, needed only for 64bit versions of windows
rem (if boot_dir2 isn't needed (for 32bit versions) write anything e.g. FOO since it will be ignored)
rem flag_for_using_cracked_setupldr=1 for 64bit versions and Windows Server 2003 with SP1

rem When you have changed this file save it and run it.

echo Creating multi-boot folders and files, it will take some time...

call create_boot_folder.cmd D:\AIO_DVD\Setup\W2K3_EN\DTC\ D:\AIO_DVD iDTC FOO 0
call create_boot_folder.cmd D:\AIO_DVD\Setup\W2K3_EN\ENT\ D:\AIO_DVD iENT FOO 0
call create_boot_folder.cmd D:\AIO_DVD\Setup\W2K3_EN\SBS\ D:\AIO_DVD iSBS FOO 0
call create_boot_folder.cmd D:\AIO_DVD\Setup\W2K3_EN\STD\ D:\AIO_DVD iSTD FOO 0
call create_boot_folder.cmd D:\AIO_DVD\Setup\W2K3_EN\WEB\ D:\AIO_DVD iWEB FOO 0

call create_boot_folder.cmd D:\AIO_DVD\Setup\XPPro_EN\ D:\AIO_DVD iXPP FOO 0

call create_boot_folder.cmd D:\AIO_DVD\Setup\XPME_EN\ D:\AIO_DVD iXPM FOO 0

echo If you don't see any error message above then everything should be ok, but please check.
pause

^^ Also I'm using sp2 in 2k3 and I'm not sure if I need to use the setupldr.bin patch. Has it been tested yet?

Thanks

0

Share this post


Link to post
Share on other sites

Someone there to upload these files please :hello:

Edited by Pliek
0

Share this post


Link to post
Share on other sites

We need the download...anyway this is all for nothing????? :wacko:

0

Share this post


Link to post
Share on other sites

OMG, absolutely amazing! Worked perfectly for me :D

0

Share this post


Link to post
Share on other sites

Create an account or sign in to comment

You need to be a member in order to leave a comment

Create an account

Sign up for a new account in our community. It's easy!


Register a new account

Sign in

Already have an account? Sign in here.


Sign In Now

  • Recently Browsing   0 members

    No registered users viewing this page.