MSFN Forum: cfosspeed - MSFN Forum

Jump to content



Unattended CD/DVD Guide Homepage · MSFN Forum Rules

Welcome to the Applications Installs forum. Make sure you read the forum rules before you start posting.

Links/Requests to warez and/or any illegal material (porn, cracks, serials, etc..) will not be tolerated. Discussion of circumventing WGA/activation/timebombs/keygens or any other illegal activity will also not be tolerated.

We try our best to keep this forum clean of illegal content. If you see any illegal activity use the "report" button you find in every post to report the specific post to the moderators. If you ignore any of the rules you will be banned without notice.

Read Forum Rules
Page 1 of 1
  • You cannot start a new topic
  • You cannot reply to this topic

cfosspeed Rate Topic: -----

#1 User is offline   alperefe 

  • Newbie
  • Group: Members
  • Posts: 24
  • Joined: 06-September 05

  Posted 15 January 2006 - 04:18 AM

is there anyone knowing how to install cfosspeed in unattended way? :unsure: ı searched the forum but ı couldnt find!
it seems unpacked already but there is a setup file! sfx may be?? :} thanx alot!

This post has been edited by alperefe: 15 January 2006 - 04:19 AM


#2 User is offline   Sonic 

  • Sonic
  • Group: Patrons
  • Posts: 1,600
  • Joined: 04-December 03

Posted 15 January 2006 - 05:33 PM

extract content (already done)
look in setup.ini (or similar)
and replace 0 by 1 for skip_welcome , skip_other ...
and you can just run setup to install silently ...

#3 User is offline   alperefe 

  • Newbie
  • Group: Members
  • Posts: 24
  • Joined: 06-September 05

Posted 17 January 2006 - 07:37 AM

yeah ı found it and did what you said but it didnt work. when ı changed the parameters it says "some of the files are corrupted" but when ı edit it like before, it is ok! :} ı think ı ll try sfx. thanx anyway!

#4 User is offline   Sonic 

  • Sonic
  • Group: Patrons
  • Posts: 1,600
  • Joined: 04-December 03

Posted 17 January 2006 - 01:42 PM

yes try to find a solution , because I havn't this , I have just downloaded and fast studied .. goodluck and post your solution ... Goodbye.

#5 User is offline   Halfwalker 

  • Junior
  • Pip
  • Group: Members
  • Posts: 86
  • Joined: 12-October 05

Posted 18 January 2006 - 11:52 PM

I have an AutoIT script that works fine. A little tricky in that some of the controls don't click correctly, so you have to send keys (alt-N for next for example). I've verified that it installs the downloaded 212 version cleanly on a real system and in a VMware VM.

; ----------------------------------------------------------------------------
;
; AutoIt Version: 3.1.0
; Author:		 A.N.Other <myemail@nowhere.com>
;
; Script Function:
;	Template AutoIt script.
;
; ----------------------------------------------------------------------------

AutoITSetOption ("SendKeyDelay", 20)
AutoItSetOption("WinDetectHiddenText", 1)
AutoItSetOption("TrayIconDebug", 1)

Run (@WindowsDir & "\Temp\cfosspeed\setup.exe")
WinActivate ("cFosSpeed Installation Wizard")
WinWaitActive ("cFosSpeed Installation Wizard")
;ControlClick ("cFosSpeed Installation Wizard", "", "&Next")
Send ("!N")

ControlClick ("cFosSpeed Installation Wizard", "If you accept", "Button1")
Send ("!N")

WinWaitActive ("cFosSpeed Installation Wizard", "Set system restore")
ControlClick ("cFosSpeed Installation Wizard", "Set system restore", "Button1")
Send ("!N")

WinWaitActive ("cFosSpeed Installation Wizard", "installation directory")
Send ("!N")

$ret = 0
While $ret == 0
  $ret = WinWaitActive ("cFosSpeed Installation Wizard", "TCP receiver window", 5)
  if $ret == 0 then WinActivate ("cFosSpeed Installation Wizard", "TCP receiver window")
Wend
Send ("!N")

$ret = 0
While $ret == 0
  $ret = WinWaitActive ("cFosSpeed Installation Wizard", "Installation successful", 5)
  if $ret == 0 then WinActivate ("cFosSpeed Installation Wizard", "Installation successful")
Wend
ControlClick ("cFosSpeed Installation Wizard", "", "Finish")

; Now close the **** Explorer window it opens
$ret = 0
While $ret == 0
  $ret = WinWaitActive ("cFos Traffic Shaping", "", 5)
  if $ret == 0 then WinActivate ("cFos Traffic Shaping")
Wend
WinClose ("cFos Traffic Shaping")

; Move the desktop icons and move the start menu
FileMove (@DesktopDir & "\cFos Traffic Shaping.lnk", @ProgramsCommonDir & "\cFosSpeed Traffic Shaping\cFos Traffic Shaping.lnk")
FileMove (@DesktopDir & "\cFosSpeed Features.lnk",   @ProgramsCommonDir & "\cFosSpeed Traffic Shaping\cFosSpeed Features.lnk")
DirMove (@ProgramsCommonDir & "\cFosSpeed Traffic Shaping", @ProgramsCommonDir & "\Network Utilities\cFosSpeed Traffic Shaping")

Exit

It expects to see the unpacked installer in c:\windows\temp\cfospeed - just unpack it with winrar or whatever. The last section moves the desktop icons and the program group to where I want them - change to suit yourself.

D.

#6 User is offline   chaox 

  • Newbie
  • Group: Members
  • Posts: 42
  • Joined: 28-April 07

Posted 23 March 2008 - 01:32 AM

this script for cfosspeed 4.21

Quote

Opt("SendKeyDelay",20)
Opt("WinWaitDelay",100)
Opt("WinTitleMatchMode",4)
Opt("WinDetectHiddenText",1)
Opt("MouseCoordMode",0)
Run('cfosspeed-v421-build1400.exe')
WinActivate ("cFosSpeed Installation Wizard")
WinWaitActive ("cFosSpeed Installation Wizard")
Send("{ALTDOWN}n{ALTUP}")
WinWaitActive ("cFosSpeed Installation Wizard")
ControlClick ("cFosSpeed Installation Wizard", "If you accept", "Button1")
Send("{ALTDOWN}n{ALTUP}")
WinWaitActive ("cFosSpeed Installation Wizard")
Send("{ALTDOWN}n{ALTUP}")
$ret = 0
While $ret == 0
$ret = WinWaitActive ("cFosSpeed Installation Wizard", "", 5)
if $ret == 0 then WinActivate ("cFosSpeed Installation Wizard", "")
Wend
Send("{ALTDOWN}n{ALTUP}")

$ret = 0
While $ret == 0
$ret = WinWaitActive ("cFosSpeed Installation Wizard", "TCP receiver window", 5)
if $ret == 0 then WinActivate ("cFosSpeed Installation Wizard", "TCP receiver window")
Wend
Send("{ALTDOWN}n{ALTUP}")

$ret = 0
While $ret == 0
$ret = WinWaitActive ("cFosSpeed Installation Wizard", "Installation successful", 5)
if $ret == 0 then WinActivate ("cFosSpeed Installation Wizard", "Installation successful")
Wend
ControlClick ("cFosSpeed Installation Wizard", "", "Finish")
$SF_1 = "cfosspeed-v421-build1400.exe"

If WinExists ( $SF_1 ) Then Exit
AutoItWinSetTitle ( $SF_1)


little modification from Halfwalker script :)

#7 User is offline   radix 

  • Friend of MSFN
  • PipPipPipPipPip
  • Group: Members
  • Posts: 715
  • Joined: 08-February 07

Posted 23 March 2008 - 11:37 AM

Edit

This post has been edited by radix: 24 March 2008 - 11:48 AM

#8 User is offline   johndoe74 

  • MSFN Expert
  • PipPipPipPipPipPip
  • Group: Members
  • Posts: 1,435
  • Joined: 12-March 06

Posted 23 March 2008 - 08:44 PM

radix have you turned off system restore on your windows ? because with your script the installer stops at the system restore point. please check and thanks for the help

Attached File  cfos.JPG (38.79K)
Number of downloads: 6

This post has been edited by johndoe74: 23 March 2008 - 08:50 PM

#9 User is offline   radix 

  • Friend of MSFN
  • PipPipPipPipPip
  • Group: Members
  • Posts: 715
  • Joined: 08-February 07

Posted 24 March 2008 - 01:09 AM

View Postjohndoe74, on Mar 24 2008, 04:44 AM, said:

radix have you turned off system restore on your windows ? because with your script the installer stops at the system restore point. please check and thanks for the help

It's turn off.
That window appear if System Restore is turn on (turn off is unchecked).
I will upload a new version when I come back from work.

This post has been edited by radix: 24 March 2008 - 07:00 AM

#10 User is offline   radix 

  • Friend of MSFN
  • PipPipPipPipPip
  • Group: Members
  • Posts: 715
  • Joined: 08-February 07

Posted 24 March 2008 - 06:56 AM

cfosspeed 4.20.1389 32 Bit version here

This post has been edited by radix: 24 March 2008 - 11:49 AM

#11 User is offline   johndoe74 

  • MSFN Expert
  • PipPipPipPipPipPip
  • Group: Members
  • Posts: 1,435
  • Joined: 12-March 06

Posted 24 March 2008 - 10:40 AM

hi radix, thanks for the update. installation progresses just fine but at the end, the the traffic shaping internet explorer window pops up!Attached File  shaping.JPG (99.13K)
Number of downloads: 6

#12 User is offline   radix 

  • Friend of MSFN
  • PipPipPipPipPip
  • Group: Members
  • Posts: 715
  • Joined: 08-February 07

Posted 24 March 2008 - 10:51 AM

View Postjohndoe74, on Mar 24 2008, 06:40 PM, said:

hi radix, thanks for the update. installation progresses just fine but at the end, the the traffic shaping internet explorer window pops up!Attachment shaping.JPG

That window doesn't appear to me.
But something similar pops up when I turned internet connection on and then launched Opera.

Attached File(s)


This post has been edited by radix: 24 March 2008 - 10:52 AM

#13 User is offline   radix 

  • Friend of MSFN
  • PipPipPipPipPip
  • Group: Members
  • Posts: 715
  • Joined: 08-February 07

Posted 24 March 2008 - 11:46 AM

Try again. 
cfosspeed 4.20.1389 32 Bit version:

Opt("TrayIconDebug", 1)
Opt("SendKeyDelay", 200)
; Executable file name
$EXECUTABLE = "cfosspeed-v420.exe"
; Installation folder
$INSTALLLOCATION = @ProgramFilesDir & "\cFosSpeed"
; Set system restore point
$RestorePoint = "0"
; Optimize TCP receiver window size
$Optimize = "1"
; Registration
; If you want to try cfosspeed for 30 days, let $Registration = "0". Else set $Registration = "1" and read below.
; In order to register cfosspeed silently, you need to install cfosspeed, copy key file into installation folder
; and reboot computer. After logon, when cfosspeed start, enter the password.
; Then goto this registry key: HKEY_LOCAL_MACHINE\SOFTWARE\cFos\cFosSpeed and copy the value from valuename Password2 below
; at $Password without commas and backslash. Copy your key file in the same folder with installer and compiled script and repack.
$Registration = "0"
$KeyFileName = "key.cfosspeed"
$Password = ""
; Run cfosspeed on Windows startup
$Autostart = "1"

If FileExists($INSTALLLOCATION & "\cfosspeed.exe") Then
	MsgBox(0x40010, @ScriptName, "Please uninstall previous version of cfosspeed before using this script", 4)
	Exit
EndIf

; Read from registry if System Restore is turn on or off
$DisableSR = RegRead("HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\SystemRestore", "DisableSR")

; Run the installer
Run($EXECUTABLE)

; Welcome to cFosSpeed v4.20!
WinWait("cFosSpeed Installation Wizard", "Welcome to cFosSpeed v4.20!")
WinActivate("cFosSpeed Installation Wizard", "Welcome to cFosSpeed v4.20!")
ControlClick("cFosSpeed Installation Wizard", "", "Button2")

; cFosSpeed 4.20.1389 Nutzungslizenz und Gewährleistung
WinWait("cFosSpeed Installation Wizard", "cFosSpeed 4.20.1389 Nutzungslizenz und Gewährleistung")
WinActivate("cFosSpeed Installation Wizard", "cFosSpeed 4.20.1389 Nutzungslizenz und Gewährleistung")
ControlCommand("cFosSpeed Installation Wizard", "", "Button1", "Check", "")
ControlClick("cFosSpeed Installation Wizard", "", "Button3")

; Start checking for two windows with "Set system restore point." and "You are online with the following connection:" text inside
AdlibEnable('_Adlib')

; Specify an installation directory.
WinWait("cFosSpeed Installation Wizard", "Specify an installation directory.")
WinActivate("cFosSpeed Installation Wizard", "Specify an installation directory.")
If $DisableSR = "0" Then
	ControlClick("cFosSpeed Installation Wizard", "", "Button5")
EndIf
If $DisableSR = "1" Then
	ControlClick("cFosSpeed Installation Wizard", "", "Button4")
EndIf

; Optimize TCP receiver window size. (Recommended)
WinWait("cFosSpeed Installation Wizard", "Optimize TCP receiver window size. (Recommended)")
WinActivate("cFosSpeed Installation Wizard", "Optimize TCP receiver window size. (Recommended)")
If $Optimize = "0" Then
	ControlCommand("cFosSpeed Installation Wizard", "", "Button1", "UnCheck", "")
EndIf
If $DisableSR = "0" Then
	ControlClick("cFosSpeed Installation Wizard", "", "Button7")
EndIf
If $DisableSR = "1" Then
	ControlClick("cFosSpeed Installation Wizard", "", "Button6")
EndIf

; Installation successful.
WinWait("cFosSpeed Installation Wizard", "Installation successful.")
WinActivate("cFosSpeed Installation Wizard", "Installation successful.")
If $DisableSR = "0" Then
	ControlClick("cFosSpeed Installation Wizard", "", "Button8")
EndIf
If $DisableSR = "1" Then
	ControlClick("cFosSpeed Installation Wizard", "", "Button7")
EndIf

; Stop checking for two windows with "Set system restore point." and "You are online with the following connection:" text inside
AdlibDisable()

Sleep(2000)

; Kill browser process
$PID = ProcessExists("IEXPLORE.EXE")
If $PID Then
	ProcessClose($PID)
EndIf
$PID = ProcessExists("Opera.exe")
If $PID Then
	ProcessClose($PID)
EndIf
$PID = ProcessExists("firefox.exe")
If $PID Then
	ProcessClose($PID)
EndIf

; Registration
If $Registration = "1" Then
	FileCopy($KeyFileName, $INSTALLLOCATION, 1)
	RegWrite("HKLM\SOFTWARE\cFos\cFosSpeed", "Password2", "REG_BINARY", $Password)
EndIf

; Block cfosspeed to run on Windows startup
If $Autostart = "0" Then
	RegDelete("HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Run", "cFosSpeed")
EndIf

; Delete shortcut cFosSpeed Features from Desktop folder
FileDelete(@DesktopDir & "\cFosSpeed Features.lnk")

Func _Adlib()
; Set system restore point.
	If WinExists("cFosSpeed Installation Wizard", "Set system restore point.") Then
		WinActivate("cFosSpeed Installation Wizard", "Set system restore point.")
		If $RestorePoint = "0" Then
			ControlCommand("cFosSpeed Installation Wizard", "", "Button1", "UnCheck", "")
		EndIf
		ControlClick("cFosSpeed Installation Wizard", "", "Button4")
	EndIf
; You are online with the following connection:
	If WinExists("cFosSpeed Installation Wizard", "You are online with the following connection:") Then
		WinActivate("cFosSpeed Installation Wizard", "You are online with the following connection:")
		ControlClick("cFosSpeed Installation Wizard", "", "Button1")
		If $DisableSR = "0" Then
			ControlClick("cFosSpeed Installation Wizard", "", "Button6")
		EndIf
		If $DisableSR = "1" Then
			ControlClick("cFosSpeed Installation Wizard", "", "Button5")
		EndIf
	EndIf
EndFunc

This post has been edited by radix: 25 March 2008 - 12:28 PM

#14 User is offline   johndoe74 

  • MSFN Expert
  • PipPipPipPipPipPip
  • Group: Members
  • Posts: 1,435
  • Joined: 12-March 06

Posted 24 March 2008 - 12:09 PM

nope still popping up

#15 User is offline   radix 

  • Friend of MSFN
  • PipPipPipPipPip
  • Group: Members
  • Posts: 715
  • Joined: 08-February 07

Posted 24 March 2008 - 03:00 PM

View Postjohndoe74, on Mar 24 2008, 08:09 PM, said:

nope still popping up

Check again

#16 User is offline   johndoe74 

  • MSFN Expert
  • PipPipPipPipPipPip
  • Group: Members
  • Posts: 1,435
  • Joined: 12-March 06

Posted 24 March 2008 - 09:57 PM

sorry, still there :(

#17 User is offline   johndoe74 

  • MSFN Expert
  • PipPipPipPipPipPip
  • Group: Members
  • Posts: 1,435
  • Joined: 12-March 06

Posted 24 March 2008 - 09:58 PM

how about deleting the d@mn file that it loads ? 
%ProgramFiles%\cFosSpeed\traffic_shaping\calibration_e.htm

#18 User is offline   radix 

  • Friend of MSFN
  • PipPipPipPipPip
  • Group: Members
  • Posts: 715
  • Joined: 08-February 07

Posted 25 March 2008 - 01:46 AM

View Postjohndoe74, on Mar 25 2008, 05:58 AM, said:

how about deleting the d@mn file that it loads ? 
%ProgramFiles%\cFosSpeed\traffic_shaping\calibration_e.htm

That's the last solution. Better to delete the entire folder or move it somewhere (on %systemdrive%)
and after 2 seconds to move back on it place.
Try again.

This post has been edited by radix: 25 March 2008 - 02:14 AM

#19 User is offline   artbio 

  • Junior
  • Pip
  • Group: Members
  • Posts: 67
  • Joined: 11-June 04
  • OS:XP Pro x86
  • Country: Country Flag

Posted 04 May 2008 - 03:46 AM

The script posted by radix worked, but wasn't enough for me. The registration doesn't work if you install on another machine. In some situations the browser still pops up. So I took that script, edited it and this came up:

#NoTrayIcon

; Options
AutoItSetOption("TrayIconHide", 1)
AutoItSetOption("WinTitleMatchMode", 4)
AutoItSetOption("WinWaitDelay", 1)

$g_szVersion = "cFosSpeed AutoIt v3 Script 1.0"
If WinExists($g_szVersion) Then Exit; It's already running
AutoItWinSetTitle($g_szVersion)

; Executable file name
$EXECUTABLE = "cfosspeed-v420.exe"

; Set system restore point
$RestorePoint = "0"

; Optimize TCP receiver window size
$Optimize = "1"

; Registration
; If you want to try cfosspeed for 30 days, let $Registration = "0". Else set $Registration = "1".
$Registration = "1"
$KeyFileName = "key.cfosspeed"
$Password = "XXXX-XXXX-XXXX-XXXX"; Replace with you own password

; Run cfosspeed on Windows startup
$Autostart = "1"

$dirold = RegRead("HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\cFosSpeed", "InstallLocation")
If FileExists($dirold & "\cfosspeed.exe") Then
	MsgBox(0x40010, @ScriptName, "Please uninstall previous version of cfosspeed before using this script", 4)
	Exit
EndIf

; Read from registry if System Restore is turn on or off
$DisableSR = RegRead("HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\SystemRestore", "DisableSR")

; Run the installer
Run(@ScriptDir & "\" & $EXECUTABLE)

; Welcome to cFosSpeed v4.20!
WinWait("cFosSpeed Installation Wizard", "Welcome to cFosSpeed v4.20!")
WinSetState("cFosSpeed Installation Wizard", "Welcome to cFosSpeed v4.20!", @SW_SHOWMINNOACTIVE)
ControlCommand("cFosSpeed Installation Wizard", "Welcome to cFosSpeed v4.20!", "ComboBox1", "SelectString", "English")
WinWait("cFosSpeed Installation Wizard", "English")
ControlClick("cFosSpeed Installation Wizard", "", "Button2")

; cFosSpeed 4.20.1389 Nutzungslizenz und Gewährleistung
WinWait("cFosSpeed Installation Wizard", "cFosSpeed 4.20.1389 Nutzungslizenz und Gewährleistung")
WinSetState("cFosSpeed Installation Wizard", "cFosSpeed 4.20.1389 Nutzungslizenz und Gewährleistung", @SW_SHOWMINNOACTIVE)
ControlCommand("cFosSpeed Installation Wizard", "", "Button1", "Check", "")
ControlClick("cFosSpeed Installation Wizard", "", "Button3")

; Start checking for two windows with "Set system restore point." and "You are online with the following connection:" text inside
AdlibEnable('_Adlib')

; Specify an installation directory.
WinWait("cFosSpeed Installation Wizard", "Specify an installation directory.")
WinSetState("cFosSpeed Installation Wizard", "Specify an installation directory.", @SW_SHOWMINNOACTIVE)
Switch $DisableSR
Case 0
	ControlClick("cFosSpeed Installation Wizard", "", "Button5")
Case 1
	ControlClick("cFosSpeed Installation Wizard", "", "Button4")
EndSwitch

; Optimize TCP receiver window size. (Recommended)
WinWait("cFosSpeed Installation Wizard", "Optimize TCP receiver window size. (Recommended)")
WinSetState("cFosSpeed Installation Wizard", "Optimize TCP receiver window size. (Recommended)", @SW_SHOWMINNOACTIVE)
If $Optimize = "0" Then
	ControlCommand("cFosSpeed Installation Wizard", "", "Button1", "UnCheck", "")
EndIf
Switch $DisableSR
Case 0
	ControlClick("cFosSpeed Installation Wizard", "", "Button7")
Case 1
	ControlClick("cFosSpeed Installation Wizard", "", "Button6")
EndSwitch

; Installation successful.
WinWait("cFosSpeed Installation Wizard", "Installation successful.")
WinSetState("cFosSpeed Installation Wizard", "Installation successful.", @SW_SHOWMINNOACTIVE)
Switch $DisableSR
Case 0
	ControlClick("cFosSpeed Installation Wizard", "", "Button8")
Case 1
	ControlClick("cFosSpeed Installation Wizard", "", "Button7")
EndSwitch

; Stop checking for two windows with "Set system restore point." and "You are online with the following connection:" text inside
AdlibDisable()

$dir = RegRead("HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\cFosSpeed", "InstallLocation")

; Prevent browser from poping up
IniWrite($dir & "\cfosspeed.ini", "All", "ts_advice", 1)

; Registration
If $Registration = "1" Then
	
	Run($dir & "\setup.exe -brandkey " & @ScriptDir & "\" & $KeyFileName)
	
	WinWait("cFosSpeed Registration Wizard", "cFosSpeed Registration.")
	WinSetState("cFosSpeed Registration Wizard", "cFosSpeed Registration.", @SW_SHOWMINNOACTIVE)
	ControlCommand("cFosSpeed Registration Wizard", "cFosSpeed Registration.", "ComboBox1", "SelectString", "English")
	ControlClick("cFosSpeed Registration Wizard", "&Next >", "Button2")
	
	WinWait("cFosSpeed Registration Wizard", "If you accept the license agreement, check the 'I agree' field and click Next, otherwise, click Cancel.")
	WinSetState("cFosSpeed Registration Wizard", "If you accept the license agreement, check the 'I agree' field and click Next, otherwise, click Cancel.", @SW_SHOWMINNOACTIVE)
	ControlCommand ("cFosSpeed Registration Wizard", "I agree.", "Button1", "Check", "")
	ControlClick("cFosSpeed Registration Wizard", "&Next >", "Button3")
	
	WinWait("cFosSpeed Registration Wizard", "cFosSpeed will be registered to:")
	WinSetState("cFosSpeed Registration Wizard", "cFosSpeed will be registered to:", @SW_SHOWMINNOACTIVE)
	Sleep(100)
	ControlSend("cFosSpeed Registration Wizard", "Password:", "Edit1", $Password)
	ControlClick("cFosSpeed Registration Wizard", "&Next >", "Button3")
	
	WinWait("cFosSpeed Registration Wizard", "Registration complete.")
	WinSetState("cFosSpeed Registration Wizard", "Registration complete.", @SW_SHOWMINNOACTIVE)
	ControlClick("cFosSpeed Registration Wizard", "Finish", "Button4")
	
EndIf

; Block cfosspeed to run on Windows startup
If $Autostart = "0" Then
	RegDelete("HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Run", "cFosSpeed")
EndIf

; Delete shortcut "cFosSpeed Features" from Desktop folder
FileDelete(@DesktopDir & "\cFosSpeed Features.lnk")

Exit

Func _Adlib()
; Set system restore point.
	If WinExists("cFosSpeed Installation Wizard", "Set system restore point.") Then
		WinSetState("cFosSpeed Installation Wizard", "Set system restore point.", @SW_SHOWMINNOACTIVE)
		If $RestorePoint = "0" Then
			ControlCommand("cFosSpeed Installation Wizard", "", "Button1", "UnCheck", "")
		EndIf
		ControlClick("cFosSpeed Installation Wizard", "", "Button4")
	EndIf
; You are online with the following connection:
	If WinExists("cFosSpeed Installation Wizard", "You are online with the following connection:") Then
		WinSetState("cFosSpeed Installation Wizard", "You are online with the following connection:", @SW_SHOWMINNOACTIVE)
		ControlClick("cFosSpeed Installation Wizard", "", "Button1")
		Switch $DisableSR
		Case 0
			ControlClick("cFosSpeed Installation Wizard", "", "Button6")
		Case 1
			ControlClick("cFosSpeed Installation Wizard", "", "Button5")
		EndSwitch
	EndIf
EndFunc

This post has been edited by artbio: 04 May 2008 - 08:33 AM

Share this topic:


Page 1 of 1
  • You cannot start a new topic
  • You cannot reply to this topic

1 User(s) are reading this topic
0 members, 1 guests, 0 anonymous users



All trademarks mentioned on this page are the property of their respective owners
Copyright © 2001 - 2011 msfn.org
Privacy Policy