Daemon Tools 4.08 (AutoIt Launcher)

Unattended CD/DVD Guide Homepage · MSFN Forum Rules

Welcome to the Applications Installs forum. Make sure you read the forum rules before you start posting.

Links/Requests to warez and/or any illegal material (porn, cracks, serials, etc..) will not be tolerated. Discussion of circumventing WGA/activation/timebombs/keygens or any other illegal activity will also not be tolerated.

We try our best to keep this forum clean of illegal content. If you see any illegal activity use the "report" button you find in every post to report the specific post to the moderators. If you ignore any of the rules you will be banned without notice.

Read Forum Rules

4 Pages
« First
←
2
3
4

You cannot start a new topic
You cannot reply to this topic

Daemon Tools 4.08 (AutoIt Launcher) Silent Installer Rate Topic:

#61 Acheron

Friend of MSFN

Group: Members
Posts: 915
Joined: 28-June 04

Posted 05 May 2008 - 10:39 AM

Its a bit weird, but with latest Daemon Tools I no longer have to turn off Daemon Tools security mode. This simplifies the installation process a bit.
Other options like automounting, disabling toolbar can be set in a ini-file. Only thing that can't be set is the Online update check, but I'm happy that Daemon Tools at least get some options to be set manually.

Here's an updated ArniWorx installer:

ArniWorX 1.0.60 Shell Extension installer

This one is multilangual, sets automaticly Daemon Tools language, Automount options and disables the Daemon Tools panel.

This post has been edited by Acheron: 05 May 2008 - 03:20 PM

#62 radix

Friend of MSFN

Group: Members
Posts: 702
Joined: 08-February 07

Posted 05 May 2008 - 02:42 PM

Acheron, on May 5 2008, 07:39 PM, said:

Its a bit weird, but with latest Daemon Tools I no longer have to turn off Daemon Tools security mode. This simplifies the installation process a bit.

So we don't need that right click on D.T. tray icon. arniworx installer need some modifications to
install the files in DAEMON Tools Lite folder (not DAEMON Tools). Very simple task.

#63 cool400

Junior

Group: Members
Posts: 72
Joined: 08-November 05

Posted 12 May 2008 - 01:35 PM

@radix,Acheron

Is there a new DT-version available? How can the settings be made via an INI-file? And how can I install DT with this INI-file unattended?

The Arniworks-installer isn't unattended, right? Or am I doing something wrong?

Best regards

cool400 :ph34r:

#64 radix

Friend of MSFN

Group: Members
Posts: 702
Joined: 08-February 07

Posted 12 May 2008 - 02:00 PM

cool400, on May 12 2008, 10:35 PM, said:

The Arniworks-installer isn't unattended, right? Or am I doing something wrong?

Maybe need some switches. Like /verysilent.

#65 bbrian

Newbie

Group: Members
Posts: 20
Joined: 25-September 07

Posted 14 May 2008 - 05:35 AM

radix, on Apr 3 2008, 01:01 PM, said:

DAEMON Tools Lite 4.12.3 with SPTD 1.56 (works in 32 and 64 bit environment)

Note: Close Internet connection before running the setup (to avoid firewall prompt and add-on download).

I used WIWW2 to create an msi to install SPTD 1.56 and force a reboot after install. Silent switch was "add /q". I called the msi sptd156.

Then I wrapped your AutoIt script into an MSI and put a WMI filter on the GPO so it would only install after STPD was in add/remove:

SELECT * FROM Win32_Product WHERE Caption ='sptd156'

I also added some code into your script to move about the shortcuts, though I haven't tested it yet. This bit at the top so it's easy to find:

; Organise shortcuts

; @StartMenuCommonDir is the path to All Users Start Menu folder
; @StartMenuDir is the path to the current user's Start Menu
; @DesktopCommonDir is the path to All Users Desktop
; @DesktopDir is the path to the current user's Desktop
$CopyDesktopIconTo = @StartMenuCommonDir & "\Programs\Accessories\Utilities"
$DeleteDesktopIcon = 1
$CopyStartMenuFolderTo = ""
$DeleteStartMenuFolder = 1

and this is put after the install logic:

		
; Deal with shortcuts
	If Not ($CopyDesktopIconTo = "") Then
		
		If Not FileExists($CopyDesktopIconTo) Then 
			DirCreate($CopyDesktopIconTo)
		EndIf

		FileCopy(@DesktopCommonDir & "\DAEMON Tools Lite.lnk", $CopyDesktopIconTo)

	EndIf

	If $DeleteDesktopIcon = 1 Then 
		FileDelete(@DesktopCommonDir & "\DAEMON Tools Lite.lnk")
	EndIf

	If Not ($CopyStartMenuFolderTo = "") Then
		
		If Not FileExists($CopyStartMenuFolderTo) Then 
			DirCreate($CopyStartMenuFolderTo)
		EndIf

		DirCopy(@StartMenuCommonDir & "\Programs\DAEMON Tools Lite", $CopyDesktopFolderTo)

	EndIf

	If $DeleteStartMenuFolder = 1 Then 
		DirRemove(@StartMenuCommonDir & "\Programs\DAEMON Tools Lite", 1)
	EndIf

#66 Acheron

Friend of MSFN

Group: Members
Posts: 915
Joined: 28-June 04

Posted 22 May 2008 - 04:04 PM

_{The script I posted was not working properly. See below for improved script.}

This post has been edited by Acheron: 04 June 2008 - 02:25 PM

#67 THERMALTAKE

Newbie

Group: Members
Posts: 17
Joined: 01-August 07

Posted 23 May 2008 - 02:20 PM

Try this. I wrote an AutoIt Scirpt for newest Daemon and everthing installs silently. I think so. :rolleyes:

Attached File(s)

Daemon_Tools.rar (197.12K)
Number of downloads: 67

#68 bbrian

Newbie

Group: Members
Posts: 20
Joined: 25-September 07

Posted 26 May 2008 - 06:08 PM

THERMALTAKE, on May 23 2008, 09:20 PM, said:

Try this. I wrote an AutoIt Scirpt for newest Daemon and everthing installs silently. I think so. :rolleyes:

Would you mind posting the script itself. I have it working but I'm curious how you may have done anything different. How do you deal with rebooting?

Any DaemonScript MSIs already made? I had a little trouble and haven't had time to try again. It's been out so long there must be one floating around. I recall I couldn't wrap the exe in an msi because it contained an msi itself.

This post has been edited by bbrian: 26 May 2008 - 06:08 PM

#69 THERMALTAKE

Newbie

Group: Members
Posts: 17
Joined: 01-August 07

Posted 04 June 2008 - 01:38 PM

While testing the silent installation of daemon tools the problem of the choice of the language appeared me, that is why I add responsible for this the file:
---------------------------
[Global]
Automount=1
Autostart=0
[Options]
PanelVisble=0
PanelIncluded=0
PanelTopmost=0
[View]
Language=1045 // 1033 - English Language

Write down it as daemontools.ini in %systemdrive%\Documents and Settings\Administrator\Application Data\DAEMON Tools
-------------------------
Next I suggest to download http://www.esnips.com/nsdoc/09da6895-83aa-...c7-f702394f4a56 (this is an addon of daemon without SPTD) and unpack.
----------------------------------
Run('dt4123.exe')
Sleep(6000)
If ProcessExists ("firefox.exe") Then ProcessClose ("firefox.exe")
If ProcessExists ("iexplore.exe") Then ProcessClose ("iexplore.exe")
--------------------------
Save this scirpt and everything should work fine.

This post has been edited by THERMALTAKE: 04 June 2008 - 01:38 PM

#70 Acheron

Friend of MSFN

Group: Members
Posts: 915
Joined: 28-June 04

Posted 04 June 2008 - 02:40 PM

After several tests I post a final version of my Daemon Tools unattended install script including ArniWorX tools compatible with T13 method.

runonceex.cmd

reg add "%Key%\035" /ve /d "Daemon Tools 4.12.3" /f
reg add "%Key%\035" /v "1" /d "\"%Installpath%\Daemon Tools\install.cmd\^"" /f

install.cmd

title Daemon Tools 4.12.3

::SPTD-driver 1.56
SPTDinst-x86.exe add /q

::Note @T12 %cd% doesn't work
set CurrentPath=%~dp0
set CurrentPath=%CurrentPath:~0,-1%

set RunOnce=HKLM\Software\Microsoft\Windows\CurrentVersion\RunOnce

::Daemon Tools should be installed after reboot
reg add "%RunOnce%" /v "Daemon Tools 4.12.3" /d "\"%CurrentPath%\config.cmd\^"" /f

::ArniWorx 1.0.6.0
awxDTools1060.exe /VERYSILENT /NORESTART

exit

config.cmd

title Daemon Tools 4.12.3

set CurrentPath=%~dp0
set CurrentPath=%CurrentPath:~0,-1%

::Daemon Tools gets installed when GUI is loaded
set RunOnce=HKCU\Software\Microsoft\Windows\CurrentVersion\RunOnce
reg add "%RunOnce%" /v "Daemon Tools 4.12.3" /d "autoit3 \"%CurrentPath%\install_dt4123.au3\^"" /f

exit

install_dt4123.au3

#NoTrayIcon
#RequireAdmin
;Windows Text Quick mode
Opt("WinTextMatchMode", 2)
;Advanced Title Match mode
Opt("WinTitleMatchMode", 4)

;Disable the default internet browser (to prevent daemon.exe to open it)
$DefBrowser = RegRead("HKCR\HTTP\shell\open\command\", "")
RegDelete("HKCR\HTTP\shell\open\command\", "")

;Read from registry which is the home page of Internet Explorer (to restore it after the installation of DAEMON Tools Lite)
$HomePage = RegRead("HKCU\Software\Microsoft\Internet Explorer\Main", "Start Page")

$INSTALLDIR = @ProgramFilesDir & "\Daemon Tools Lite"
$DTTITLE = "DAEMON Tools Lite 4.12.3"
$EXECUTABLE = "daemon4123-lite.exe"

Run(@ScriptDir & "\" & $EXECUTABLE & ' /S /D="' & $INSTALLDIR & '"')
If WinWait("[TITLE:" & $DTTitle & "; CLASS:#32770]", "", 10) Then
	$dt_handle = WinGetHandle("[LAST]")
	$controlhandle = ControlGetHandle($dt_handle, "", "[CLASS:Button; INSTANCE:1]")
	If not @error Then
		ControlClick($controlhandle, "", "")
	EndIf
EndIf

$dif = 0
$begin = TimerInit()

;disable advertising module
While $dif <= 30000
	If ProcessExists("SRSAI.exe") Then
		ProcessClose("SRSAI.exe")
		ExitLoop
	Else
		Sleep(10)
	EndIf
	$dif = TimerDiff($begin)
WEnd

;delete adware
If FileExists($INSTALLDIR & "\SRSAI.exe") Then
	FileDelete($INSTALLDIR & "\SRSAI.exe")
EndIf

ProcessWaitClose($EXECUTABLE, 10)

;Write uninstall information to registry 
RegWrite("HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\DAEMON Tools Lite", "DisplayName", "REG_SZ", $DTTITLE)
RegWrite("HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\DAEMON Tools Lite", "UninstallString", "REG_SZ", $INSTALLDIR & "\uninst.exe")
RegWrite("HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\DAEMON Tools Lite", "InstallLocation", "REG_SZ", $INSTALLDIR)
RegWrite("HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\DAEMON Tools Lite", "DisplayIcon", "REG_SZ",$INSTALLDIR & "\daemon.exe")

;Restore the default internet browser
RegWrite("HKCR\HTTP\shell\open\command\", "", "REG_SZ", $DefBrowser)

;Restore the home page of Internet Explorer
RegWrite("HKCU\Software\Microsoft\Internet Explorer\Main", "", "REG_SZ", $HomePage)

;Cleanup shortcuts
DirRemove(@ProgramsCommonDir & "\Daemon Tools Lite", 1)
FileDelete(@DesktopCommonDir & "\DAEMON Tools Lite.lnk")

FileCreateShortcut ($INSTALLDIR & "\daemon.exe", @ProgramsCommonDir & "\Daemon Tools Lite.lnk")

;Start Daemon Tools
Run($INSTALLDIR & "\daemon.exe")

;Wait for Daemon Tools installation to be finished
If WinWait("[TITLE:DAEMON Tools Lite; CLASS:#32770]", "", 10) Then
	$dt_handle = WinGetHandle("[LAST]")
	WinWaitClose($dt_handle, "", 120)
EndIf

;Register ArniWorX shell extension
If FileExists($INSTALLDIR & "\AwxdTools.dll") Then
	Run("regsvr32.exe /s """ & $INSTALLDIR & "\AwxdTools.dll""")
EndIf

Note I have also updated the AwxDTools1060.exe to configure Daemon Tools at T13, because Daemon Tools get installed after user is logged on.

In my experience, Daemon Tools is the most difficult application to install silently (except Nero Burning ROM for which I wrote Nero Lite)

Thanks go to Radix for providing the script to handle the advertising module :thumbup

This post has been edited by Acheron: 07 June 2008 - 11:47 AM

#71 radix

Friend of MSFN

Group: Members
Posts: 702
Joined: 08-February 07

Posted 05 July 2008 - 01:27 PM

New script for DAEMON Tools Lite 4.12.4:

 
Opt("TrayIconDebug", 1)

; Executable file name
$EXECUTABLE = "daemon4124-lite.exe"
; Run Daemon Tools on Windows startup
$Autostart = "0"
; Automount
$Automount = "1"
; Window title
$title = "DAEMON Tools Lite 4.12.4"
; Detect the Operating System type (32 bit or 64 bit)
$OS = _OSBit()

If $OS = 32 Then
   ; Installation folder
    $INSTALLLOCATION = @ProgramFilesDir & "\DAEMON Tools Lite"
    
    If FileExists($INSTALLLOCATION & "\daemon.exe") Then
        MsgBox(0x40010, @ScriptName, "Please uninstall previous version of DAEMON Tools Lite before using this script", 4)
        Exit
    EndIf
    
   ; Disable the default internet browser (to prevent daemon.exe to open it)
    $DefBrowser = RegRead("HKCR\HTTP\shell\open\command\", "")
    RegDelete("HKCR\HTTP\shell\open\command\", "")

   ; Read from registry which is the home page of Internet Explorer (to restore it after the installation of DAEMON Tools Lite)
    $HomePage = RegRead("HKCU\Software\Microsoft\Internet Explorer\Main", "Start Page")

   ; Run the installer
    Run($EXECUTABLE & " /S")
    
   ; Start checking for a window
    AdlibEnable('_Adlib')
    
    ProcessWaitClose($EXECUTABLE)

    Sleep(1000)
    
   ; Close browsers processes
    $PID = ProcessExists("firefox.exe")
    If $PID Then
        ProcessClose($PID)
    EndIf
    $PID = ProcessExists("IEXPLORE.EXE")
    If $PID Then
        ProcessClose($PID)
    EndIf
    $PID = ProcessExists("opera.exe")
    If $PID Then
        ProcessClose($PID)
    EndIf

   ; Restore the default internet browser
    RegWrite("HKCR\HTTP\shell\open\command\", "", "REG_SZ", $DefBrowser)

   ; Restore the home page of Internet Explorer
    RegWrite("HKCU\Software\Microsoft\Internet Explorer\Main", "", "REG_SZ", $HomePage)
    
   ; Delete DAEMON Tools Toolbar folder and registry entries made during installation process
    FileDelete($INSTALLLOCATION & "\DAEMON Tools Toolbar.exe")
    DirRemove(@ProgramFilesDir & "\DAEMON Tools Toolbar", 1)
    RegDelete("HKCR\CLSID\{32099AAC-C132-4136-9E9A-4E364A424E17}")
    RegDelete("HKCR\CLSID\{32099AAC-C132-4136-9E9A-4E364A424E17}\InprocServer32")
    RegDelete("HKCR\CLSID\{32099AAC-C132-4136-9E9A-4E364A424E17}\ProgID")
    RegDelete("HKCR\CLSID\{32099AAC-C132-4136-9E9A-4E364A424E17}\Programmable")
    RegDelete("HKCR\CLSID\{32099AAC-C132-4136-9E9A-4E364A424E17}\TypeLib")
    RegDelete("HKCR\CLSID\{32099AAC-C132-4136-9E9A-4E364A424E17}\VersionIndependentProgID")
    RegDelete("HKCR\DTToolbar.ToolBandObj")
    RegDelete("HKCR\DTToolbar.ToolBandObj\CLSID")
    RegDelete("HKCR\DTToolbar.ToolBandObj\CurVer")
    RegDelete("HKCR\DTToolbar.ToolBandObj.1")
    RegDelete("HKCR\DTToolbar.ToolBandObj.1\CLSID")
    RegDelete("HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\FileExts\.mds")
    RegDelete("HKLM\Software\Microsoft\Windows\CurrentVersion\Uninstall\DAEMON Tools Toolbar")
    
   ; Automount
    If $Automount = "1" Then
        IniWrite(@AppDataDir & "\DAEMON Tools\daemontools.ini", "Global", "Automount", 1)
    EndIf
    
   ; Block DAEMON Tools to run on Windows startup
    If $Autostart = 0 Then
        RegDelete("HKCU\SOFTWARE\Microsoft\Windows\CurrentVersion\Run", "DAEMON Tools Lite")
    EndIf
    IniWrite(@AppDataDir & "\DAEMON Tools\daemontools.ini", "Global", "Autostart", 0)
    
   ; Add uninstall entries
    RegWrite("HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\DAEMON Tools Lite", "DisplayName", "REG_SZ", "DAEMON Tools Lite 4.12.4")
    RegWrite("HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\DAEMON Tools Lite", "UninstallString", "REG_SZ", $INSTALLLOCATION & "\uninst.exe")
    RegWrite("HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\DAEMON Tools Lite", "InstallLocation", "REG_SZ", $INSTALLLOCATION)
    RegWrite("HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\DAEMON Tools Lite", "DisplayIcon", "REG_SZ", $INSTALLLOCATION & "\daemon.exe")
    
   ; Stop checking for a window
    AdlibDisable()
EndIf

If $OS = 64 Then
   ; Installation folder
    $INSTALLLOCATION = @HomeDrive & "\Program Files (x86)\DAEMON Tools Lite"
    
    If FileExists($INSTALLLOCATION & "\daemon.exe") Then
        MsgBox(0x40010, @ScriptName, "Please uninstall previous version of DAEMON Tools before using this script", 4)
        Exit
    EndIf
    
   ; Disable the default internet browser (to prevent daemon.exe to open it)
    $DefBrowser = RegRead("HKCR\HTTP\shell\open\command\", "")
    RegDelete("HKCR\HTTP\shell\open\command\", "")

   ; Read from registry which is the home page of Internet Explorer (to restore it after the installation of DAEMON Tools Lite)
    $HomePage = RegRead("HKCU\Software\Microsoft\Internet Explorer\Main", "Start Page")

   ; Run the installer
    Run($EXECUTABLE & " /S")
    
   ; Start checking for a window
    AdlibEnable('_Adlib')
    
    ProcessWaitClose($EXECUTABLE)

    Sleep(1000)

   ; Close browsers processes
    $PID = ProcessExists("firefox.exe")
    If $PID Then
        ProcessClose($PID)
    EndIf
    $PID = ProcessExists("IEXPLORE.EXE")
    If $PID Then
        ProcessClose($PID)
    EndIf
    $PID = ProcessExists("opera.exe")
    If $PID Then
        ProcessClose($PID)
    EndIf
    
   ; Restore the default internet browser
    RegWrite("HKCR\HTTP\shell\open\command\", "", "REG_SZ", $DefBrowser)

   ; Restore the home page of Internet Explorer
    RegWrite("HKCU\Software\Microsoft\Internet Explorer\Main", "", "REG_SZ", $HomePage)

   ; Delete DAEMON Tools Toolbar folder and registry entries made during installation process
    FileDelete($INSTALLLOCATION & "\DAEMON Tools Toolbar.exe")
    DirRemove(@HomeDrive & "\Program Files (x86)\DAEMON Tools Toolbar", 1)
    RegDelete("HKCR\CLSID\{32099AAC-C132-4136-9E9A-4E364A424E17}")
    RegDelete("HKCR\CLSID\{32099AAC-C132-4136-9E9A-4E364A424E17}\InprocServer32")
    RegDelete("HKCR\CLSID\{32099AAC-C132-4136-9E9A-4E364A424E17}\ProgID")
    RegDelete("HKCR\CLSID\{32099AAC-C132-4136-9E9A-4E364A424E17}\Programmable")
    RegDelete("HKCR\CLSID\{32099AAC-C132-4136-9E9A-4E364A424E17}\TypeLib")
    RegDelete("HKCR\CLSID\{32099AAC-C132-4136-9E9A-4E364A424E17}\VersionIndependentProgID")
    RegDelete("HKCR\DTToolbar.ToolBandObj")
    RegDelete("HKCR\DTToolbar.ToolBandObj\CLSID")
    RegDelete("HKCR\DTToolbar.ToolBandObj\CurVer")
    RegDelete("HKCR\DTToolbar.ToolBandObj.1")
    RegDelete("HKCR\DTToolbar.ToolBandObj.1\CLSID")
    RegDelete("HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\FileExts\.mds")
    RegDelete("HKLM\Software\Wow6432Node\Microsoft\Windows\CurrentVersion\Uninstall\DAEMON Tools Toolbar")
    
   ; Automount
    If $Automount = "1" Then
        IniWrite(@AppDataDir & "\DAEMON Tools\daemontools.ini", "Global", "Automount", 1)
    EndIf
    
   ; Block DAEMON Tools to run on Windows startup
    If $Autostart = 0 Then
        RegDelete("HKCU\SOFTWARE\Microsoft\Windows\CurrentVersion\Run", "DAEMON Tools Lite")
    EndIf
    IniWrite(@AppDataDir & "\DAEMON Tools\daemontools.ini", "Global", "Autostart", 0)
    
   ; Add uninstall entries
    RegWrite("HKLM\SOFTWARE\Wow6432Node\Microsoft\Windows\CurrentVersion\Uninstall\DAEMON Tools Lite", "DisplayName", "REG_SZ", "DAEMON Tools Lite 4.12.4")
    RegWrite("HKLM\SOFTWARE\Wow6432Node\Microsoft\Windows\CurrentVersion\Uninstall\DAEMON Tools Lite", "UninstallString", "REG_SZ", $INSTALLLOCATION & "\uninst.exe")
    RegWrite("HKLM\SOFTWARE\Wow6432Node\Microsoft\Windows\CurrentVersion\Uninstall\DAEMON Tools Lite", "InstallLocation", "REG_SZ", $INSTALLLOCATION)
    RegWrite("HKLM\SOFTWARE\Wow6432Node\Microsoft\Windows\CurrentVersion\Uninstall\DAEMON Tools Lite", "DisplayIcon", "REG_SZ", $INSTALLLOCATION & "\daemon.exe")
    
   ; Stop checking for a window
    AdlibDisable()
EndIf

Func _Adlib()
   ; Please select a language.
    If WinExists($title, "") Then
        ControlClick($title, "", "Button1")
    EndIf
EndFunc

Func _OSBit()
    Local $tOS = DllStructCreate("char[256]")
    Local $aGSWD = DllCall("Kernel32.dll", "int", "GetSystemWow64Directory", "ptr", DllStructGetPtr($tOS), "int", 256)
    If IsArray($aGSWD) And DllStructGetData($tOS, 1) Then Return 64
    Return 32
EndFunc

This post has been edited by radix: 22 December 2008 - 05:30 PM

#72 tombojones

Group: Members
Posts: 1
Joined: 24-July 08

Posted 24 July 2008 - 03:17 AM

Here's a good code for 4.30.1 Lite. I use this on my unattended xp but there are two prerequisites:

1. SPTD DRIVER MUST BE INSTALLED BEFORE (eg. I integrated it into my unattended XP setup: "SPTDinst-v156-x86.exe /q")
2. ONLY WORKS ON 32bit XP

 
#NoTrayIcon
BlockInput(1)
$INSTALLLOCATION = @ProgramFilesDir & "\DAEMON Tools Lite"
$Autostart = "0"

; Disable the default internet browser (to prevent daemon.exe to open it)
$DefBrowser = RegRead("HKCR\HTTP\shell\open\command\", "")
RegDelete("HKCR\HTTP\shell\open\command\", "")

Run("daemon4301-lite.exe")
AdlibEnable('_Adlib')

;This installs it without spyware and without shortcuts.
WinWaitActive("DAEMON Tools Lite","install")
Send("!n")
WinWaitActive("DAEMON Tools Lite","license")
Send("!a")
WinWaitActive("DAEMON Tools Lite","features")
Send("{DOWN}")
Send("{SPACE}")
Send("{DOWN}")
Send("{SPACE}")
Send("{DOWN}")
Send("{SPACE}")
Send("{DOWN}")
Send("{SPACE}")
Send("{DOWN}")
Send("{SPACE}")
Send("!n")
WinWaitActive("DAEMON Tools Lite","search")
Send("{SPACE}")
Send("!n")
WinWaitActive("DAEMON Tools Lite","folder")
Send("!i")
WinWait("DAEMON Tools Lite","installed")
Send("!r")
Send("!f")

sleep(2000)
; Close browsers processes
$PID = ProcessExists("firefox.exe")
If $PID Then
	ProcessClose($PID)
EndIf
$PID = ProcessExists("IEXPLORE.EXE")
If $PID Then
	ProcessClose($PID)
EndIf
$PID = ProcessExists("opera.exe")
If $PID Then
	ProcessClose($PID)
EndIf

; Restore the default internet browser
RegWrite("HKCR\HTTP\shell\open\command\", "", "REG_SZ", $DefBrowser)

; Add uninstall entries
RegWrite("HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\DAEMON Tools Lite", "DisplayName", "REG_SZ", "DAEMON Tools Lite")
RegWrite("HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\DAEMON Tools Lite", "UninstallString", "REG_SZ", $INSTALLLOCATION & "\uninst.exe")
RegWrite("HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\DAEMON Tools Lite", "InstallLocation", "REG_SZ", $INSTALLLOCATION)
RegWrite("HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\DAEMON Tools Lite", "DisplayIcon", "REG_SZ", $INSTALLLOCATION & "\daemon.exe")




AdlibDisable()


Func _Adlib()
   ; Please select a language.
If WinExists("DAEMON Tools Lite", "Please select a language.") Then
        ControlClick("DAEMON Tools Lite", "Please select a language.", "Button1")
EndIf
EndFunc

; Block DAEMON Tools to run on Windows startup
If $Autostart = 0 Then
	RegDelete("HKCU\SOFTWARE\Microsoft\Windows\CurrentVersion\Run", "DAEMON Tools Lite")
EndIf
IniWrite(@AppDataDir & "\DAEMON Tools\daemontools.ini", "Global", "Autostart", 0)

Thanks to the guy above me, I used lots of their code.

This post has been edited by tombojones: 25 July 2008 - 06:27 PM

#73 radix

Friend of MSFN

Group: Members
Posts: 702
Joined: 08-February 07

Posted 22 December 2008 - 05:27 PM

AutoIt script for DAEMON Tools Lite 4.30.3 (x86 or x64)

 
#cs ----------------------------------------------------------------------------

 AutoIt Version: 3.3.0.0
 Author:         myName
 
 DAEMON Tools Lite 4.30.3 with SPTD 1.56 x86 & x64
 Application site: [url="http://www.daemon-tools.cc/dtcc/announcements.php"]http://www.daemon-tools.cc/dtcc/announcements.php[/url]

 Script Function:
    Template AutoIt script.

#ce ----------------------------------------------------------------------------

; Script Start - Add your code below here

Opt("TrayIconDebug", 1)

; Intaller file name
$Installer = "daemon4303-lite.exe"
; Automount
$Automount = 1
; Check for updates monthly
$Checkforupdatesmonthly = 0
; Disable DAEMON Tools Panel
$DTPanel = 0
; Add uninstall entri to Control Panel->Add or Remove Programs
$UninstallEntri = 1
; DAEMON Tools Lite title in Control Panel->Add or Remove Programs
$DTLTitle = "DAEMON Tools Lite 4.30.3"
; Keeps the Start Menu folder
$StartMenuFolder = 1
; Create a new icon in Start Menu (set this variable = 1 only if you chosen to delete the folder created by installer in
; Start Menu folder (above) and you really need it; otherwise let it be = 0)
$NewStartMenuIcon = 0
; Keeps the Desktop icon
$DesktopIcon = 1
; Program language (Arabic = 1025; Bulgarian = 1026; Catalan = 1027; Chinese Simplified = 2052; Chinese Traditional = 1028;
  ; Croatian = 1050; Czech = 1029; Danish = 1030; Dutch = 1043; English = 1033; Finnish = 1035; French = 1036; Georgian = 1079;
  ; German = 1031; Greek = 1032; Hebrew = 1037; Hungarian = 1038; Italian = 1040; Japanese = 1041; Korean = 1042; Latvian = 1062;
  ; Lithuanian = 1063; Norwegian = 1044; Polish = 1045; Portuguese = 1044; ROMANIAN = 1048; Russian = 1049; Serbian = 2074;
  ; Slovak = 1051; Slovenian = 1060; Spanish = 3082; Swedish = 1053; Turkish = 1055; Ukrainian = 1058)
$ProgramLanguage = 1033
; Run DAEMON Tools Lite after installation is done (useful if you want to install arniWORX)
$RunDAEMONToolsLite = 1
; Run Daemon Tools for All Users (on Windows startup)
$Autostart = 0

If @OSArch = "X86" Then
    ; Installation folder
    $InstallDir = @ProgramFilesDir & "\DAEMON Tools Lite"; Do not edit this variable!
    
    If FileExists($InstallDir & "\daemon.exe") Then
        MsgBox(0x40010, @ScriptName, "Please uninstall previous version of DAEMON Tools Lite before using this script", 4)
        Exit
    EndIf
    
    ; Start checking for DAEMON Tools Lite Toolbar, Internet Explorer and New Connection Wizard processes
    AdlibEnable('_Adlib')

    ; Set installation language (to avoid window pop-up at the begining of installation)
    RegWrite("HKCU\Software\DT Soft\DAEMON Tools Lite\View", "Language", "REG_DWORD", 1033)
    
    ; Save the default internet browser (to restore it after the installation of DAEMON Tools Lite)
    $DefaultHttpBrowser = RegRead("HKCR\http\shell\open\command\", "")
    $DefaultHttpsBrowser = RegRead("HKCR\https\shell\open\command\", "")

    ; Make Internet Explorer the default Internet browser (to deal only with this browser later)
    RegWrite("HKCR\http\shell\open\command", "", "REG_SZ", '"' & @ProgramFilesDir & "\Internet Explorer\iexplore.exe" & '" -nohome')
    RegWrite("HKCR\https\shell\open\command", "", "REG_SZ", '"' & @ProgramFilesDir & "\Internet Explorer\iexplore.exe" & '" -nohome')
    
    ; Save the home page of Internet Explorer (to restore it after the installation of DAEMON Tools Lite)
    $IEHomePage = RegRead("HKCU\Software\Microsoft\Internet Explorer\Main", "Start Page")
    
    ; Save the default search engine of IE7 or IE8 (to restore it after the installation of DAEMON Tools Lite)
    ; Check if Internet Explorer version is 7 or higher
    $IEVersion = FileGetVersion(@ProgramFilesDir & "\Internet Explorer\iexplore.exe")
    $IEVersion = StringLeft($IEVersion, 1)
    If $IEVersion >= 7 Then
        $IE7orIE8DefaultSearchEngine = RegRead("HKCU\Software\Microsoft\Internet Explorer\SearchScopes", "DefaultScope")
    EndIf
    
    ; Save .mds file association (to restore it after the installation of DAEMON Tools Lite)
    $mdsfileassociation = RegRead("HKCR\.mds", "")
    
    ; Run the installer
    Run($Installer & " /S")
    
    ; Wait to finish installation
    ProcessWaitClose($Installer)
    
    Sleep(1000)
    
    ; Restore the default internet browser
    RegWrite("HKCR\http\shell\open\command\", "", "REG_SZ", $DefaultHttpBrowser)
    RegWrite("HKCR\https\shell\open\command\", "", "REG_SZ", $DefaultHttpsBrowser)
    
    ; Restore the home page of Internet Explorer
    RegDelete("HKCU\Software\Microsoft\Internet Explorer\Main", "Start Page")
    RegWrite("HKCU\Software\Microsoft\Internet Explorer\Main", "Start Page", "REG_SZ", $IEHomePage)
    
    ; Restore the default search engine of IE7 or IE8
    If $IEVersion >= 7 Then
        RegDelete("HKCU\Software\Microsoft\Internet Explorer\SearchScopes\{AD22EBAF-0D18-4fc7-90CC-5EA0ABBE9EB9}")
        RegWrite("HKCU\Software\Microsoft\Internet Explorer\SearchScopes", "DefaultScope", "REG_SZ", $IE7orIE8DefaultSearchEngine)
    EndIf
    
    ; Restore .mds file association
    RegDelete("HKCR\.mds", "")
    RegWrite("HKCR\.mds", "", "REG_SZ", $mdsfileassociation)
        
    ; Settings
    If $Automount = 1 Then
        RegWrite("HKCU\Software\DT Soft\DAEMON Tools Lite\Config", "Automount", "REG_DWORD", 1)
    EndIf
    If $Checkforupdatesmonthly = 0 Then
        RegWrite("HKCU\Software\DT Soft\DAEMON Tools Lite\Config", "CheckForUpdate", "REG_DWORD", 0)
    EndIf
    If $DTPanel = 0 Then
        RegWrite("HKCU\Software\DT Soft\DAEMON Tools Lite\Options", "PanelIncluded", "REG_DWORD", 0)
    EndIf
    
    ; Delete the Start Menu folder
    If $StartMenuFolder = 0 Then
        DirRemove(@StartMenuCommonDir & "\Programs\DAEMON Tools Lite", 1)
    EndIf
    
    ; Create a new icon in Start Menu
    If $NewStartMenuIcon = 1 Then
        FileCreateShortcut($InstallDir & "\daemon.exe", @StartMenuCommonDir & "\Programs\DAEMON Tools Lite.lnk", $InstallDir)
    EndIf

    ; Delete the Desktop icon
    If $DesktopIcon = 0 Then
        FileDelete(@DesktopCommonDir & "\DAEMON Tools Lite.lnk")
    EndIf
    
    ; Add uninstall entri to Control Panel->Add or Remove Programs
    If $UninstallEntri = 1 Then
        RegWrite("HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\DAEMON Tools Lite", "DisplayName", "REG_SZ", $DTLTitle)
        RegWrite("HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\DAEMON Tools Lite", "UninstallString", "REG_SZ", $InstallDir & "\uninst.exe")
        RegWrite("HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\DAEMON Tools Lite", "InstallLocation", "REG_SZ", $InstallDir)
        RegWrite("HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\DAEMON Tools Lite", "DisplayIcon", "REG_SZ", $InstallDir & "\daemon.exe")
    EndIf
    
    ; Delete DAEMON Tools Toolbar
    FileDelete($InstallDir & "\DAEMON Tools Toolbar.exe")
    
    ; Set the program language
    RegWrite("HKCU\Software\DT Soft\DAEMON Tools Lite\View", "Language", "REG_DWORD", $ProgramLanguage)
    
    ; Run DAEMON Tools Lite
    If $RunDAEMONToolsLite = 1 Then
        If $Autostart = 0 Then
            RegWrite("HKCU\Software\DT Soft\DAEMON Tools Lite\Config", "Autostart", "REG_DWORD", 0)
            RegDelete("HKCU\Software\Microsoft\Windows\CurrentVersion\Run", "DAEMON Tools Lite")
            Run($InstallDir & "\daemon.exe")
            WinWait("Updating virtual devices", "Updating virtual devices")
            WinWaitClose("Updating virtual devices", "Updating virtual devices")
        ElseIf $Autostart = 1 Then
            Run($InstallDir & "\daemon.exe -autorun")
            WinWait("Updating virtual devices", "Updating virtual devices")
            WinWaitClose("Updating virtual devices", "Updating virtual devices")
        EndIf
    ElseIf $RunDAEMONToolsLite = 0 Then
        If $Autostart = 0 Then
            RegWrite("HKCU\Software\DT Soft\DAEMON Tools Lite\Config", "Autostart", "REG_DWORD", 0)
            RegDelete("HKCU\Software\Microsoft\Windows\CurrentVersion\Run", "DAEMON Tools Lite")
        EndIf
    EndIf

    Sleep(1000)
    
    ; Close DAEMON Tools Lite process
    $PID = ProcessExists("daemon.exe")
    If $PID Then
        ProcessClose($PID)
    EndIf
    
    ; Remove obsolete registry keys
    RegDelete("HKLM\SOFTWARE\19659239224e364682fa4baf72c53ea4")
    RegDelete("HKLM\SOFTWARE\DT Soft")
    
    ; Stop checking for DAEMON Tools Lite Toolbar, Internet Explorer and New Connection Wizard processes
    AdlibDisable()
EndIf

If @OSArch = "X64" Then
    ; Installation folder
    $InstallDir = @HomeDrive & "\Program Files (x86)\DAEMON Tools Lite"; Do not edit this variable!
    
    If FileExists($InstallDir & "\daemon.exe") Then
        MsgBox(0x40010, @ScriptName, "Please uninstall previous version of DAEMON Tools Lite before using this script", 4)
        Exit
    EndIf
    
    ; Start checking for DAEMON Tools Lite Toolbar, Internet Explorer and New Connection Wizard processes
    AdlibEnable('_Adlib')

    ; Set installation language (to avoid window pop-up at the begining of installation)
    RegWrite("HKCU\Software\DT Soft\DAEMON Tools Lite\View", "Language", "REG_DWORD", 1033)
    
    ; Save the default internet browser (to restore it after the installation of DAEMON Tools Lite)
    $DefaultHttpBrowser = RegRead("HKCR\http\shell\open\command\", "")
    $DefaultHttpsBrowser = RegRead("HKCR\https\shell\open\command\", "")
    
    ; Make Internet Explorer the default Internet browser (to deal only with this browser later)
    RegWrite("HKCR\http\shell\open\command", "", "REG_SZ", '"' & @HomeDrive & "\Program Files (x86)\Internet Explorer\iexplore.exe" & '" -nohome')

    ; Save the home page of Internet Explorer (to restore it after the installation of DAEMON Tools Lite)
    $IEHomePage = RegRead("HKCU\Software\Microsoft\Internet Explorer\Main", "Start Page")
    
    ; Save the default search engine of IE7 or IE8 (to restore it after the installation of DAEMON Tools Lite)
    ; Check if Internet Explorer version is 7 or higher
    $IEVersion = FileGetVersion(@ProgramFilesDir & "\Internet Explorer\iexplore.exe")
    $IEVersion = StringLeft($IEVersion, 1)
    If $IEVersion >= 7 Then
        $IE7orIE8DefaultSearchEngine = RegRead("HKCU\Software\Microsoft\Internet Explorer\SearchScopes", "DefaultScope")
    EndIf
    
    ; Save .mds file association (to restore it after the installation of DAEMON Tools Lite)
    $mdsfileassociation = RegRead("HKCR\.mds", "")
    
    ; Run the installer
    Run($Installer & " /S")
    
    ; Wait to finish installation
    ProcessWaitClose($Installer)
    
    Sleep(1000)
    
    ; Restore the default internet browser
    RegWrite("HKCR\http\shell\open\command\", "", "REG_SZ", $DefaultHttpBrowser)
    RegWrite("HKCR\https\shell\open\command\", "", "REG_SZ", $DefaultHttpsBrowser)

    ; Restore the home page of Internet Explorer
    RegDelete("HKCU\Software\Microsoft\Internet Explorer\Main", "Start Page")
    RegWrite("HKCU\Software\Microsoft\Internet Explorer\Main", "Start Page", "REG_SZ", $IEHomePage)
    
    ; Restore the default search engine of IE7 or IE8
    If $IEVersion >= 7 Then
        RegDelete("HKCU\Software\Microsoft\Internet Explorer\SearchScopes\{AD22EBAF-0D18-4fc7-90CC-5EA0ABBE9EB9}")
        RegWrite("HKCU\Software\Microsoft\Internet Explorer\SearchScopes", "DefaultScope", "REG_SZ", $IE7orIE8DefaultSearchEngine)
    EndIf
    
    ; Restore .mds file association
    RegDelete("HKCR\.mds", "")
    RegWrite("HKCR\.mds", "", "REG_SZ", $mdsfileassociation)
        
    ; Settings
    If $Automount = 1 Then
        RegWrite("HKCU\Software\DT Soft\DAEMON Tools Lite\Config", "Automount", "REG_DWORD", 1)
    EndIf
    If $Checkforupdatesmonthly = 0 Then
        RegWrite("HKCU\Software\DT Soft\DAEMON Tools Lite\Config", "CheckForUpdate", "REG_DWORD", 0)
    EndIf
    If $DTPanel = 0 Then
        RegWrite("HKCU\Software\DT Soft\DAEMON Tools Lite\Options", "PanelIncluded", "REG_DWORD", 0)
    EndIf
    
    ; Delete the Start Menu folder
    If $StartMenuFolder = 0 Then
        DirRemove(@StartMenuCommonDir & "\Programs\DAEMON Tools Lite", 1)
    EndIf
    
    ; Create a new icon in Start Menu
    If $NewStartMenuIcon = 1 Then
        FileCreateShortcut($InstallDir & "\daemon.exe", @StartMenuCommonDir & "\Programs\DAEMON Tools Lite.lnk", $InstallDir)
    EndIf
    
    ; Delete the Desktop icon
    If $DesktopIcon = 0 Then
        FileDelete(@DesktopCommonDir & "\DAEMON Tools Lite.lnk")
    EndIf
    
    ; Add uninstall entri to Control Panel->Add or Remove Programs
    If $UninstallEntri = 1 Then
        RegWrite("HKLM\SOFTWARE\Wow6432Node\Microsoft\Windows\CurrentVersion\Uninstall\DAEMON Tools Lite", "DisplayName", "REG_SZ", $DTLTitle)
        RegWrite("HKLM\SOFTWARE\Wow6432Node\Microsoft\Windows\CurrentVersion\Uninstall\DAEMON Tools Lite", "UninstallString", "REG_SZ", $InstallDir & "\uninst.exe")
        RegWrite("HKLM\SOFTWARE\Wow6432Node\Microsoft\Windows\CurrentVersion\Uninstall\DAEMON Tools Lite", "InstallLocation", "REG_SZ", $InstallDir)
        RegWrite("HKLM\SOFTWARE\Wow6432Node\Microsoft\Windows\CurrentVersion\Uninstall\DAEMON Tools Lite", "DisplayIcon", "REG_SZ", $InstallDir & "\daemon.exe")
    EndIf
    
    ; Delete DAEMON Tools Toolbar
    FileDelete($InstallDir & "\DAEMON Tools Toolbar.exe")
    
    ; Set the program language
    RegWrite("HKCU\Software\DT Soft\DAEMON Tools Lite\View", "Language", "REG_DWORD", $ProgramLanguage)
    
    ; Run DAEMON Tools Lite
    If $RunDAEMONToolsLite = 1 Then
        If $Autostart = 0 Then
            RegWrite("HKCU\Software\DT Soft\DAEMON Tools Lite\Config", "Autostart", "REG_DWORD", 0)
            RegDelete("HKCU\Software\Microsoft\Windows\CurrentVersion\Run", "DAEMON Tools Lite")
            Run($InstallDir & "\daemon.exe")
            WinWait("Updating virtual devices", "Updating virtual devices")
            WinWaitClose("Updating virtual devices", "Updating virtual devices")
        ElseIf $Autostart = 1 Then
            Run($InstallDir & "\daemon.exe -autorun")
            WinWait("Updating virtual devices", "Updating virtual devices")
            WinWaitClose("Updating virtual devices", "Updating virtual devices")
        EndIf
    ElseIf $RunDAEMONToolsLite = 0 Then
        If $Autostart = 0 Then
            RegWrite("HKCU\Software\DT Soft\DAEMON Tools Lite\Config", "Autostart", "REG_DWORD", 0)
            RegDelete("HKCU\Software\Microsoft\Windows\CurrentVersion\Run", "DAEMON Tools Lite")
        EndIf
    EndIf
    
    Sleep(1000)
    
    ; Close DAEMON Tools Lite process
    $PID = ProcessExists("daemon.exe")
    If $PID Then
        ProcessClose($PID)
    EndIf
    
    ; Remove obsolete registry keys
    Run(@ComSpec & " /c " & 'REG DELETE "HKLM\SOFTWARE\Wow6432Node\19659239224e364682fa4baf72c53ea4" /f', "", @SW_HIDE)
    Run(@ComSpec & " /c " & 'REG DELETE "HKLM\SOFTWARE\Wow6432Node\DT Soft" /f', "", @SW_HIDE)
    
    ; Stop checking for DAEMON Tools Lite Toolbar, Internet Explorer and New Connection Wizard processes
    AdlibDisable()
EndIf

Func _Adlib()
    ; Close Internet Explorer process
    $PID = ProcessExists("iexplore.exe")
    If $PID Then
        ProcessClose($PID)
    EndIf
    ; Close New Connection Wizard process (if was started)
    $PID = ProcessExists("icwconn1.exe")
    If $PID Then
        ProcessClose($PID)
    EndIf
    ; Kill Daemon Tools Lite toolbar installation process
    $PID = ProcessExists("DAEMON Tools Toolbar.exe")
    If $PID Then
        ProcessClose($PID)
    EndIf
EndFunc

Func OnAutoItStart()
    ; One script instance only
    If WinExists(@ScriptName & '_Interpreter') Then Exit
    AutoItWinSetTitle(@ScriptName & '_Interpreter')
EndFunc

This post has been edited by radix: 07 February 2009 - 04:19 AM

#74 COOLCOMPUTERGUY

Cool.

Group: Members
Posts: 72
Joined: 27-October 08

Posted 24 December 2008 - 09:02 AM

Any one can make dtlite with auto-it but it just isn't as good if it does not install the sptd then restart the computer and continue autimatically. Silently.
Without auto-it.

#75 radix

Friend of MSFN

Group: Members
Posts: 702
Joined: 08-February 07

Posted 24 December 2008 - 03:51 PM

COOLCOMPUTERGUY, on Dec 24 2008, 05:02 PM, said:

Any one can make dtlite with auto-it but it just isn't as good if it does not install the sptd then restart the computer and continue autimatically. Silently.
Without auto-it.

Install SPTD from T13 (add /q switch) and DT after logon
Read here

This post has been edited by radix: 24 December 2008 - 04:03 PM

#76 WindoStroy

Group: Members
Posts: 1
Joined: 13-April 08

Posted 07 January 2009 - 10:50 AM

to all. my method:

;check for browser in ram

;Internet Exlorerer
If ProcessExists("iexplore.exe") Then
ProcessClose("iexplore.exe")
EndIf

;Mozilla Firefox
If ProcessExists("firefox.exe") Then
ProcessClose("firefox.exe")
EndIf

;Opera
If ProcessExists("opera.exe") Then
ProcessClose("opera.exe")
EndIf

;Internet Exlorer
If FileExists(@ProgramFilesDir & "\Internet Explorer\iexplore.exe") Then
FileMove(@ProgramFilesDir & "\Internet Explorer\iexplore.exe", @ProgramFilesDir & "\Internet Explorer\iexplore.exe.bak")
EndIf

;Mozilla Firefox
If FileExists(@ProgramFilesDir & "\Mozilla Firefox\firefox.exe") Then
FileMove(@ProgramFilesDir & "\Mozilla Firefox\firefox.exe", @ProgramFilesDir & "\Mozilla Firefox\firefox.exe.bak")
EndIf

;Opera
If FileExists(@ProgramFilesDir & "\Opera\opera.exe") Then
FileMove(@ProgramFilesDir & "\Opera\opera.exe", @ProgramFilesDir & "\Opera\opera.exe.bak")
EndIf

ProcessWaitClose($EXENAME,300)

;Internet Exlorer
If FileExists(@ProgramFilesDir & "\Internet Explorer\iexplore.exe.bak") Then
FileMove(@ProgramFilesDir & "\Internet Explorer\iexplore.exe.bak", @ProgramFilesDir & "\Internet Explorer\iexplore.exe")
EndIf

;Mozilla Firefox
If FileExists(@ProgramFilesDir & "\Mozilla Firefox\firefox.exe.bak") Then
FileMove(@ProgramFilesDir & "\Mozilla Firefox\firefox.exe.bak", @ProgramFilesDir & "\Mozilla Firefox\firefox.exe")
EndIf

;Opera
If FileExists(@ProgramFilesDir & "\Opera\opera.exe.bak") Then
FileMove(@ProgramFilesDir & "\Opera\opera.exe.bak", @ProgramFilesDir & "\Opera\opera.exe")
EndIf

#77 radix

Friend of MSFN

Group: Members
Posts: 702
Joined: 08-February 07

Posted 07 January 2009 - 02:23 PM

@WindoStroy
Have you tried your script in Windows with WFP turned on?

#78 Csimbi

Newbie

Group: Members
Posts: 44
Joined: 25-December 04

Posted 16 October 2009 - 07:33 AM

Here's my script.
I install SPTD, then reboot, then DT, then remove the crap.

REM Daemon Tools Phase 1
START /WAIT %1\!INSTALL\DAEMON\SPTDinst-v160-x86.exe add /q

REM Daemon Tools Phase 2
START /WAIT %1\!INSTALL\DAEMON\daemon4304-lite(158).exe /S /D=%ProgramFiles%\DTLS_LT\
REM Daemon Tools Phase 3 - uninstall the toolbar
for /f "tokens=3*" %%i IN ('reg query "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\DAEMON Tools Toolbar" /v "UninstallString" ^| findstr "REG_SZ"') do "%%i %%j" /S
REM Daemon Tools Phase 4 - remove leftover
DIR_LOC.CMD "%ProgramFiles%" "RD /S /Q " "_DTLite.xml"

You can find DIR_LOC.CMD here.